[gentoo-commits] repo/gentoo:master commit in: mail-client/trojita/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     c04c058c778515b4757693f8371ebcf801b23772
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 29 07:50:11 2016 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Fri Jan 29 08:39:26 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c04c058c

mail-client/trojita: various live ebuild updates

* Port to EAPI 6
* Drop Qt 4 support as it is being removed upstream
* Drop linguas USE flags as they only control small text iles
* Introduce dbus USE flag
* Add missing dev-qt/qtnetwork USE dependency
* Update icon and mime caches

Gentoo-bug: 572894

Package-Manager: portage-2.2.27

 mail-client/trojita/trojita-9999.ebuild | 103 ++++++++++++++------------------
 1 file changed, 45 insertions(+), 58 deletions(-)

diff --git a/mail-client/trojita/trojita-9999.ebuild b/mail-client/trojita/trojita-9999.ebuild
index e7c71ee..32da654 100644
--- a/mail-client/trojita/trojita-9999.ebuild
+++ b/mail-client/trojita/trojita-9999.ebuild
@@ -1,89 +1,76 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2016 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
+EAPI=6
 
-QT4_REQUIRED="4.8.0"
 EGIT_REPO_URI="git://anongit.kde.org/${PN}.git"
-[[ ${PV} == "9999" ]] && GIT_ECLASS="git-2"
-
-inherit cmake-utils virtualx ${GIT_ECLASS}
+inherit cmake-utils fdo-mime gnome2-utils virtualx
+[[ ${PV} == 9999 ]] && inherit git-r3
 
 DESCRIPTION="A Qt IMAP e-mail client"
 HOMEPAGE="http://trojita.flaska.net/"
-if [[ ${PV} == "9999" ]]; then
-	SRC_URI=""
-	KEYWORDS=""
-else
+if [[ ${PV} != 9999 ]]; then
 	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
-	KEYWORDS="~amd64 ~ppc ~x86"
-	MY_LANGS="ar bs ca cs da de el en_GB es et fi fr ga gl hu ia it ja lt mr nb nds nl pl pt pt_BR ro sk sv tr ug uk zh_CN zh_TW"
+	KEYWORDS="~amd64 ~x86"
 fi
 
 LICENSE="|| ( GPL-2 GPL-3 )"
 SLOT="0"
-IUSE="debug +password qt5 test +zlib"
-for MY_LANG in ${MY_LANGS} ; do
-	IUSE="${IUSE} linguas_${MY_LANG}"
-done
+IUSE="debug +dbus +password test +zlib"
 
 RDEPEND="
-	qt5? (
-		dev-qt/qtgui:5
-		dev-qt/qtnetwork:5
-		dev-qt/qtsql:5[sqlite]
-		dev-qt/qtwebkit:5
-		dev-qt/qtwidgets:5
-	)
-	!qt5? (
-		>=dev-qt/qtbearer-${QT4_REQUIRED}:4
-		>=dev-qt/qtgui-${QT4_REQUIRED}:4
-		>=dev-qt/qtsql-${QT4_REQUIRED}:4[sqlite]
-		>=dev-qt/qtwebkit-${QT4_REQUIRED}:4
-	)
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwebkit:5
+	dev-qt/qtwidgets:5
+	dbus? ( dev-qt/qtdbus:5 )
+	password? ( dev-libs/qtkeychain[qt5] )
+	zlib? ( sys-libs/zlib )
 "
 DEPEND="${RDEPEND}
-	password? (
-		qt5?	( dev-libs/qtkeychain[qt5] )
-		!qt5?	( dev-libs/qtkeychain[qt4] )
-	)
-	qt5? ( dev-qt/linguist-tools:5 )
-	test? (
-		qt5?	( dev-qt/qttest:5 )
-		!qt5?	( >=dev-qt/qttest-${QT4_REQUIRED}:4 )
-	)
-	zlib? (
-		virtual/pkgconfig
-		sys-libs/zlib
-	)
+	dev-qt/linguist-tools:5
+	test? ( dev-qt/qttest:5 )
+	zlib? ( virtual/pkgconfig )
 "
 
 DOCS="README LICENSE"
 
-src_configure() {
-	local mycmakeargs=(
-		$(cmake-utils_use_with qt5 QT5)
-		$(cmake-utils_use_with password QTKEYCHAIN_PLUGIN)
-		$(cmake-utils_use_with test TESTS)
-		$(cmake-utils_use_with zlib ZLIB)
-	)
-	if [[ ${MY_LANGS} ]]; then
-		rm po/trojita_common_x-test.po
-		for x in po/*.po; do
-			mylang=${x#po/trojita_common_}
-			mylang=${mylang%.po}
-			use linguas_$mylang || rm $x
-		done
-	fi
+src_prepare() {
+	cmake-utils_src_prepare
 
 	# the build system is taking a look at `git describe ... --dirty` and
 	# gentoo's modifications to CMakeLists.txt break these
 	sed -i "s/--dirty//" "${S}/cmake/TrojitaVersion.cmake" || die "Cannot fix the version check"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_DBUS=$(usex dbus)
+		-DWITH_QTKEYCHAINPLUGIN=$(usex password)
+		-DWITH_TESTS=$(usex test)
+		-DWITH_ZLIB=$(usex zlib)
+	)
 
 	cmake-utils_src_configure
 }
 
 src_test() {
-	VIRTUALX_COMMAND=cmake-utils_src_test virtualmake
+	virtx cmake-utils_src_test
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
 }