[gentoo-commits] repo/gentoo:master commit in: media-sound/mp3diags/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     79d667a434cbfeb260971ebbdaf08652c48f2dd7
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 16 19:28:15 2016 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Sat Jan 16 19:28:48 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=79d667a4

media-sound/mp3diags: revision bump

* Port away from qt4-r4.eclass
* Add missing license (used by icons)
* Add missing dependency
* Update icon cache

Package-Manager: portage-2.2.26

 media-sound/mp3diags/mp3diags-1.2.02-r1.ebuild | 59 ++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/media-sound/mp3diags/mp3diags-1.2.02-r1.ebuild b/media-sound/mp3diags/mp3diags-1.2.02-r1.ebuild
new file mode 100644
index 0000000..70075ba
--- /dev/null
+++ b/media-sound/mp3diags/mp3diags-1.2.02-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils gnome2-utils qmake-utils
+
+MY_PN=MP3Diags
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Qt-based MP3 diagnosis and repair tool"
+HOMEPAGE="http://mp3diags.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="LGPL-3 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-libs/boost-1.37
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}
+	dev-qt/qtsvg:4
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	eqmake4 ${PN}.pro
+}
+
+src_install() {
+	dobin bin/${MY_PN}
+	dodoc changelog.txt
+
+	local size
+	for size in 16 22 24 32 36 40 48; do
+		insinto /usr/share/icons/hicolor/${size}x${size}/apps
+		newins desktop/${MY_PN}${size}.png ${MY_PN}.png
+	done
+	domenu desktop/${MY_PN}.desktop
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}