[gentoo-commits] repo/gentoo:master commit in: dev-python/gmpy/

["Justin Lecher" <jlec@gentoo.org>]

commit:     a7bb6b467deaa71ab64ea5aee3d93a796c06a3c9
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Thu Jan  7 09:21:25 2016 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Thu Jan  7 09:21:25 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a7bb6b46

dev-python/gmpy: Version Bump

Package-Manager: portage-2.2.26
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>

 dev-python/gmpy/Manifest          |  1 +
 dev-python/gmpy/gmpy-2.0.7.ebuild | 69 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/dev-python/gmpy/Manifest b/dev-python/gmpy/Manifest
index 73a279d..4681b4f 100644
--- a/dev-python/gmpy/Manifest
+++ b/dev-python/gmpy/Manifest
@@ -1,2 +1,3 @@
 DIST gmpy2-2.0.4.zip 280459 SHA256 c2b06e75d876960adabce575f01361f96884a64401740af49e8b9ef356bbbecf SHA512 98f57a0b140bb352dc1403dc799845685d52d346e87e6402d1e10c8ef46bbe90bae598143bd2ebffedb617c0519f75590a6cc9b30d887dc08ff6d5ae4fd7ec75 WHIRLPOOL 2f9c903c91c864ef4eb7e02b4004204580af1b7ddf67c67719ab68506a95cf57af64e06bed24ef445eb7eb2de0e7ef550748ac6e8b41e10297fcc22b04cfbca9
 DIST gmpy2-2.0.6.zip 280353 SHA256 5041d0ae24407c24487106099f5bcc4abb1a5f58d90e6712cc95321975eddbd4 SHA512 fae7952e86c821d8a4ae083a54d6e7e3516459abbf9bcb16408ea0d7989f309aa27348bb51781e0f52466eaf121cb193b54f5f4453093f022ce8394d273196a0 WHIRLPOOL d9a301d5d5f0872ddb517bba815cefaf8c2a3a1fa7e3e0b38f0ea0d2ec1ef8e0526549f8a3d4713b35a878125f1a766bbd3c31e0eb27902266bf3ae8a8dc2559
+DIST gmpy2-2.0.7.zip 280400 SHA256 7ee694b8a4c3854f27890676aa8a509a2e3f8dbdd0916fa94cbed612420b9c86 SHA512 47ba58da98cc36d4eb1eaafbf3b8c0ef31fa898d85bead6bf2fccd24ce5e33a23b66c199349b85e5ae0289ca7e651ccb0a5dd2657b4419331aeeee14a17c9291 WHIRLPOOL 099fac123707851be1743ac3e23dcbfe613bc18f608369e46541b7fdc9f52b5cc61a4ab5d1233f9e88db3a058fb402f5996c33c3c2e81d47dd4adf1e12cb559a

diff --git a/dev-python/gmpy/gmpy-2.0.7.ebuild b/dev-python/gmpy/gmpy-2.0.7.ebuild
new file mode 100644
index 0000000..db21b57
--- /dev/null
+++ b/dev-python/gmpy/gmpy-2.0.7.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+MY_PN="${PN}2"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python bindings for GMP, MPC, MPFR and MPIR libraries"
+HOMEPAGE="https://github.com/aleaxit/gmpy"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc mpir"
+
+RDEPEND="
+	>=dev-libs/mpc-1.0.2
+	>=dev-libs/mpfr-3.1.2
+	!mpir? ( dev-libs/gmp:0= )
+	mpir? ( sci-libs/mpir )"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}"/${MY_P}
+
+python_prepare_all() {
+	# rm non std test file
+	rm test*/gmpy_test_thr.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	mydistutilsargs=(
+		$(usex mpir --mpir --gmp)
+		)
+}
+
+python_compile() {
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	cd test || die
+	"${PYTHON}" runtests.py || die "tests failed under ${EPYTHON}"
+	if python_is_python3; then
+		cd ../test3 || die
+	else
+		cd ../test2 || die
+	fi
+	"${PYTHON}" gmpy_test.py || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}