[gentoo-commits] repo/gentoo:master commit in: net-misc/electrum/

["Anthony G. Basile" <blueness@gentoo.org>]

commit:     a1ce304ed9a48c63bdf391c09adeffbe2f30717b
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  4 07:33:13 2016 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Mon Jan  4 07:38:21 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a1ce304e

net-misc/electrum: version bump, bug #570754.

Package-Manager: portage-2.2.24

 net-misc/electrum/Manifest              |   1 +
 net-misc/electrum/electrum-2.5.4.ebuild | 152 ++++++++++++++++++++++++++++++++
 2 files changed, 153 insertions(+)

diff --git a/net-misc/electrum/Manifest b/net-misc/electrum/Manifest
index 92bd7aa..5bfc757 100644
--- a/net-misc/electrum/Manifest
+++ b/net-misc/electrum/Manifest
@@ -1,3 +1,4 @@
 DIST Electrum-2.1.1.tar.gz 1778994 SHA256 958c7113072aa4a00a7e58a6e325d952fc35896a8678952cf6487636f74164e0 SHA512 06277a810a6533cc800c6813f874a0a6e3a7e598bdd47b73a6edb440bc5efefc56edacc44c15349e3d0c72d350700c67025f43e5478b4ae838af57acc1c91f52 WHIRLPOOL 2bf9392ebbd6e7b63e4e1e12cf72356dae1e1605a3c543c3a174229247fbb280412df5fac37a195b815018b8425d88618be54d4f3b58e37273ba40776f6b3765
 DIST Electrum-2.3.3.tar.gz 1971994 SHA256 72bac30a4d82c8fbc453fab2d1fa391af690884e1727088aa969d25891a9fc0d SHA512 26c2d3eaece738a67546168d82a89c7bd5c71a146c678d186514626027d6edac4e985f08e5d6ce34217b91cefa88be0174f5f45e8caba5da4c50911780e37f1b WHIRLPOOL e10bf9d10c64e1950dd2bb48ce1fca2950acdeefd99483825751acbbf29806494cbb629ac1d51f24978a8a6a2df2ce73de2910380f8e26e4a0884bcc1f116406
 DIST Electrum-2.5.1.tar.gz 2119809 SHA256 550d26da2a5d48c260614f87447f851ef82aff301140207d349c07eea2705872 SHA512 90ef7cbe33dda1a46f9413ec51c0453c13c6355f15bf94f3562baafc391a816722500b8a6e18c9d564cacfb7d315a9e1191791612a7489baeed22781a01a9a74 WHIRLPOOL 3fafa7756ca45c3d198dbd4c6fc71c7e7c92e27b748a9fc927b7ee6ec1ce78e3c33ed8984c4baa8c951eb6eb51f55f0148610b2dc01bc90aadc93b93e08d10bd
+DIST Electrum-2.5.4.tar.gz 2114549 SHA256 c0b00f440884fe3f087e842c44914e1c5f1139d0288ecb74ba6e1ff0b2504aa3 SHA512 52ee11aa2265fea5b6302fb85724d27e47c049f81743854aeb7c2fe517f2b68628b67e1b44f543e64671b4b40731c532d45097f1d25954a6876bc3ee43cdb847 WHIRLPOOL 7322ca5c54ca99c42e2df118e5e792e3f0fee1359d0445a430ffa016b1edb890b81664f11b9532fe403c0c057212afc0057e3af455aff79b8e40f23aa11605ad

diff --git a/net-misc/electrum/electrum-2.5.4.ebuild b/net-misc/electrum/electrum-2.5.4.ebuild
new file mode 100644
index 0000000..b2d5bb1
--- /dev/null
+++ b/net-misc/electrum/electrum-2.5.4.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="ncurses?"
+
+inherit eutils distutils-r1 gnome2-utils
+
+MY_P="Electrum-${PV}"
+DESCRIPTION="User friendly Bitcoin client"
+HOMEPAGE="https://electrum.org/"
+SRC_URI="https://download.electrum.org/${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+LINGUAS="ar_SA cs_CZ de_DE eo_UY fr_FR hy_AM it_IT ky_KG nb_NO no_NO pt_BR ro_RO sk_SK ta_IN vi_VN bg_BG da_DK el_GR es_ES hu_HU id_ID ja_JP lv_LV nl_NL pl_PL pt_PT ru_RU sl_SI th_TH zh_CN"
+
+IUSE="cli cosign email +fiat greenaddress_it gtk3 ncurses qrcode +qt4 sync trustedcoin_com vkb"
+
+for lingua in ${LINGUAS}; do
+	IUSE+=" linguas_${lingua}"
+done
+
+REQUIRED_USE="
+	|| ( cli gtk3 ncurses qt4 )
+	cosign? ( qt4 )
+	email? ( qt4 )
+	fiat? ( qt4 )
+	greenaddress_it? ( qt4 )
+	qrcode? ( qt4 )
+	sync? ( qt4 )
+	trustedcoin_com? ( qt4 )
+	vkb? ( qt4 )
+"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/ecdsa[${PYTHON_USEDEP}]
+	dev-python/pbkdf2[${PYTHON_USEDEP}]
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/slowaes[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/socksipy[${PYTHON_USEDEP}]
+	dev-python/tlslite[${PYTHON_USEDEP}]
+	dev-libs/protobuf[python,${PYTHON_USEDEP}]
+	virtual/python-dnspython[${PYTHON_USEDEP}]
+	qrcode? ( media-gfx/zbar[python,v4l,${PYTHON_USEDEP}] )
+	gtk3? (
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+	)
+	qt4? (
+		dev-python/PyQt4[${PYTHON_USEDEP}]
+	)
+	ncurses? ( dev-lang/python )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS="RELEASE-NOTES"
+
+src_prepare() {
+	# Don't advise using PIP
+	sed -i "s/On Linux, try 'sudo pip install zbar'/Re-emerge Electrum with the qrcode USE flag/" lib/qrscanner.py || die
+
+	# Prevent icon from being installed in the wrong location
+	sed -i '/icons/d' setup.py || die
+
+	validate_desktop_entries
+
+	# Remove unrequested localization files:
+	for lang in ${LINGUAS}; do
+		use "linguas_${lang}" && continue
+		rm -r "lib/locale/${lang}" || die
+	done
+
+	local wordlist=
+	for wordlist in  \
+		$(usex linguas_ja_JP '' japanese) \
+		$(usex linguas_pt_BR '' portuguese) \
+		$(usex linguas_pt_PT '' portuguese) \
+		$(usex linguas_es_ES '' spanish) \
+		$(usex linguas_zh_CN '' chinese_simplified) \
+	; do
+		rm -f "lib/wordlist/${wordlist}.txt" || die
+		sed -i "/${wordlist}\\.txt/d" lib/mnemonic.py || die
+	done
+
+	# Remove unrequested GUI implementations:
+	rm -rf gui/android*
+	rm -rf gui/jsonrpc*
+	rm -rf gui/kivy*
+	local gui
+	for gui in  \
+		$(usex cli      '' stdio)  \
+		$(usex gtk3     '' gtk  )  \
+		$(usex qt4      '' qt   )  \
+		$(usex ncurses  '' text )  \
+	; do
+		rm gui/"${gui}"* -r || die
+	done
+
+	if ! use qt4; then
+		sed -i "s/'electrum_gui\\.qt',//" setup.py || die
+		local bestgui=$(usex gtk3 gtk $(usex ncurses text stdio))
+		sed -i "s/\(config.get('gui', \?\)'classic'/\1'${bestgui}'/" electrum || die
+	fi
+
+	local plugin
+	# btchipwallet requires python btchip module (and dev-python/pyusb)
+	# trezor requires python trezorlib module
+	# keepkey requires trezor
+	for plugin in  \
+		$(usex cosign        '' cosigner_pool   )  \
+		$(usex email         '' email_requests  )  \
+		$(usex fiat          '' exchange_rate   )  \
+		$(usex greenaddress_it '' greenaddress_instant)  \
+		keepkey \
+		$(usex sync          '' labels          )  \
+		trezor  \
+		$(usex trustedcoin_com '' trustedcoin   )  \
+		$(usex vkb           '' virtualkeyboard )  \
+	; do
+		rm -r plugins/"${plugin}"* || die
+	done
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	doicon -s 128 icons/${PN}.png
+	distutils-r1_src_install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}