From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-852270-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
by finch.gentoo.org (Postfix) with ESMTP id 33B8F1384B4
for <garchives@archives.gentoo.org>; Sat, 19 Dec 2015 14:08:12 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 332AEE08F9;
Sat, 19 Dec 2015 14:08:10 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 8F6F8E08F9
for <gentoo-commits@lists.gentoo.org>; Sat, 19 Dec 2015 14:08:09 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 324FA33FEB1
for <gentoo-commits@lists.gentoo.org>; Sat, 19 Dec 2015 14:08:08 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id AD624B05
for <gentoo-commits@lists.gentoo.org>; Sat, 19 Dec 2015 14:08:06 +0000 (UTC)
From: "Chí-Thanh Christopher Nguyễn" <chithanh@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Chí-Thanh Christopher Nguyễn" <chithanh@gentoo.org>
Message-ID: <1450534061.27b90f2b6a4b31c7db66b98fd3f9fd708bfecdeb.chithanh@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-wireless/gnuradio/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-wireless/gnuradio/Manifest net-wireless/gnuradio/gnuradio-3.7.8.1.ebuild
X-VCS-Directories: net-wireless/gnuradio/
X-VCS-Committer: chithanh
X-VCS-Committer-Name: Chí-Thanh Christopher Nguyễn
X-VCS-Revision: 27b90f2b6a4b31c7db66b98fd3f9fd708bfecdeb
X-VCS-Branch: master
Date: Sat, 19 Dec 2015 14:08:06 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 278d646b-3f4a-4739-9481-16ce7a37ff00
X-Archives-Hash: 1ff49d945ddc1c0d9cec40f9a0a6a9d5
commit: 27b90f2b6a4b31c7db66b98fd3f9fd708bfecdeb
Author: Chí-Thanh Christopher Nguyễn <chithanh <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 19 14:07:41 2015 +0000
Commit: Chí-Thanh Christopher Nguyễn <chithanh <AT> gentoo <DOT> org>
CommitDate: Sat Dec 19 14:07:41 2015 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=27b90f2b
net-wireless/gnuradio: version bump to 3.7.8.1
Bug: https://bugs.gentoo.org/show_bug.cgi?id=568670
Package-Manager: portage-2.2.24
net-wireless/gnuradio/Manifest | 1 +
net-wireless/gnuradio/gnuradio-3.7.8.1.ebuild | 231 ++++++++++++++++++++++++++
2 files changed, 232 insertions(+)
diff --git a/net-wireless/gnuradio/Manifest b/net-wireless/gnuradio/Manifest
index a2ac925..401827a 100644
--- a/net-wireless/gnuradio/Manifest
+++ b/net-wireless/gnuradio/Manifest
@@ -1,4 +1,5 @@
DIST gnuradio-3.6.5.1.tar.gz 3150283 SHA256 0875d2f0a7da0f3bcc1771b528b0f98f79d9ab69aa1ef953651bbbe1f57b4621 SHA512 23a22aed482da11005b17e5197ee3ba24d442b30309522b0858e694b58f46b76cc050143d365623c7dd4241cdf8b9f988e1a4dabe2e1f98d0fd4cca71bbb82e8 WHIRLPOOL 7cf55be5fac7891a737d228d83718bbc43f9069c6275c5ac465ae11088559dca5e7fa31239e281271b529aa8b9ae1a0efe3850a16a40e53c0f1fe57e351ff2a8
DIST gnuradio-3.7.6.1.tar.gz 3588833 SHA256 39dede70eec36f430c4895900bbd7ed266aa9e846d0a362987e806b7197c4c0b SHA512 88ec30b2bd93ca032c29f4606856a8e70b0123474fd84115657804429f381dea78f97a7523c9684acad6a27b357ddf876632e957de5c6e0170045dc38d121939 WHIRLPOOL 97d70e403fe46b0afbd1e6f0812f8d9de4ea506dcb2190a23d9a0f0499662f9e2bbaa86d1b624f7c621ae1675094f92cd295bc273db0759b2647e2dfb2a49b43
DIST gnuradio-3.7.7.1.tar.gz 3845988 SHA256 2b27b13fc734ab5882e42c1661d433c0c097fd8b55b682f00626fa96c356584e SHA512 7be9568d19cbe03f3c229dbda5fc8d448a4a57d84bd9f8b91a400c65b526414539536c0a391b15d5f0e63bf22ef5675dc3ed8a6ed94ce3b1e4328948fa202ba1 WHIRLPOOL c54e26af37ecb27dd515d1ca320ccf363f6a9bbff61724f7d98f751d69a32ba21f2a631ce07caf273596f4297ff92359d2469768cd927ae9d680c8a8bbd25dbd
+DIST gnuradio-3.7.8.1.tar.gz 3962961 SHA256 8406f49d085fdc2ef5d8ea90f3e19ad8782d2a2f5154bbe4f076591ddf7ae5aa SHA512 21468335d698963ce5090b03b980ecc3714c301f3cd5d071d8a1b083c3c985479c42ee6d842b1b600ac85640ce875fb2bbfd6f51d30144cb612ac55e648c0c9a WHIRLPOOL 94d1b357539299b74b9f08659426ade1fa6ac3ae6950ec4ffe6797eadaca06785c4707ea1db3500c5b57395e6f7e8c0f14718d00c556aaf6537835ebb6969b7a
DIST gnuradio-3.7.8.tar.gz 3990172 SHA256 fe19cb54b5d77fb76dde61d5cf184c6dee7066779b45c51676bae6e6d0cd4172 SHA512 2a69101acf8b1ed8cc4791de2961b4d8a4baf50a84e5514ba8f29e300829228daa50863dda8434c1703829412ec6fb2f25560d851b4a39cc687cba0646e1a7d9 WHIRLPOOL 6682b48cde8643509629b4d45f95971260657546349b1bbcb7a4c8323feebd0d042f190824026c26d9d1aa8a91a3e10380c49dc2d4ea1128dcb73edaa903d556
diff --git a/net-wireless/gnuradio/gnuradio-3.7.8.1.ebuild b/net-wireless/gnuradio/gnuradio-3.7.8.1.ebuild
new file mode 100644
index 0000000..2933b8e
--- /dev/null
+++ b/net-wireless/gnuradio/gnuradio-3.7.8.1.ebuild
@@ -0,0 +1,231 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+CMAKE_BUILD_TYPE="None"
+inherit cmake-utils fdo-mime gnome2-utils python-single-r1 eutils
+
+DESCRIPTION="Toolkit that provides signal processing blocks to implement software radios"
+HOMEPAGE="http://gnuradio.org/"
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+
+if [[ ${PV} == "9999" ]] ; then
+ EGIT_REPO_URI="http://gnuradio.org/git/gnuradio.git"
+ inherit git-r3
+ KEYWORDS=""
+else
+ SRC_URI="http://gnuradio.org/releases/gnuradio/${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+IUSE="+audio +alsa atsc +analog +digital channels doc dtv examples fcd fec +filter grc jack log noaa oss pager performance-counters portaudio +qt4 sdl test trellis uhd vocoder +utils wavelet wxwidgets zeromq"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+ audio? ( || ( alsa oss jack portaudio ) )
+ alsa? ( audio )
+ oss? ( audio )
+ jack? ( audio )
+ portaudio? ( audio )
+ analog? ( filter )
+ digital? ( filter analog )
+ dtv? ( fec )
+ pager? ( filter analog )
+ qt4? ( filter )
+ uhd? ( filter analog )
+ fcd? ( || ( alsa oss ) )
+ wavelet? ( analog )
+ wxwidgets? ( filter analog )"
+
+# bug #348206
+# comedi? ( >=sci-electronics/comedilib-0.8 )
+# boost-1.52.0 is blacklisted, bug #461578, upstream #513, boost #7669
+RDEPEND="${PYTHON_DEPS}
+ >=dev-lang/orc-0.4.12
+ dev-libs/boost:0=[${PYTHON_USEDEP}]
+ !<=dev-libs/boost-1.52.0-r6:0/1.52
+ dev-python/numpy[${PYTHON_USEDEP}]
+ sci-libs/fftw:3.0=
+ alsa? (
+ media-libs/alsa-lib[${PYTHON_USEDEP}]
+ )
+ fcd? ( virtual/libusb:1 )
+ filter? ( sci-libs/scipy )
+ grc? (
+ dev-python/cheetah[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ >=dev-python/pygtk-2.10:2[${PYTHON_USEDEP}]
+ )
+ jack? (
+ media-sound/jack-audio-connection-kit
+ )
+ log? ( dev-libs/log4cpp )
+ portaudio? (
+ >=media-libs/portaudio-19_pre
+ )
+ qt4? (
+ >=dev-python/PyQt4-4.4[X,opengl,${PYTHON_USEDEP}]
+ >=dev-python/pyqwt-5.2:5[${PYTHON_USEDEP}]
+ >=dev-qt/qtcore-4.4:4
+ >=dev-qt/qtgui-4.4:4
+ x11-libs/qwt:6
+ )
+ sdl? ( >=media-libs/libsdl-1.2.0 )
+ uhd? ( >=net-wireless/uhd-3.4.3-r1:=[${PYTHON_USEDEP}] )
+ utils? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+ vocoder? ( media-sound/gsm )
+ wavelet? (
+ >=sci-libs/gsl-1.10
+ )
+ wxwidgets? (
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ dev-python/wxpython:2.8[${PYTHON_USEDEP}]
+ )
+ zeromq? ( >=net-libs/zeromq-2.1.11 )
+ "
+
+DEPEND="${RDEPEND}
+ >=dev-lang/swig-3.0.5
+ dev-python/cheetah[${PYTHON_USEDEP}]
+ virtual/pkgconfig
+ doc? (
+ >=app-doc/doxygen-1.5.7.1
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ )
+ grc? ( x11-misc/xdg-utils )
+ oss? ( virtual/os-headers )
+ test? ( >=dev-util/cppunit-1.9.14 )
+ zeromq? ( net-libs/cppzmq )
+"
+
+src_prepare() {
+ gnome2_environment_reset #534582
+
+ # Useless UI element would require qt3support, bug #365019
+ sed -i '/qPixmapFromMimeSource/d' "${S}"/gr-qtgui/lib/spectrumdisplayform.ui || die
+ epatch_user
+}
+
+src_configure() {
+ # SYSCONFDIR/GR_PREFSDIR default to install below CMAKE_INSTALL_PREFIX
+ #audio provider is still automagic
+ #zeromq missing deps isn't fatal
+ mycmakeargs=(
+ -DENABLE_DEFAULT=OFF
+ -DENABLE_GNURADIO_RUNTIME=ON
+ -DENABLE_VOLK=ON
+ -DENABLE_PYTHON=ON
+ -DENABLE_GR_BLOCKS=ON
+ -DENABLE_GR_FFT=ON
+ -DENABLE_GR_AUDIO=ON
+ $(cmake-utils_use_enable alsa GR_AUDIO_ALSA) \
+ $(cmake-utils_use_enable analog GR_ANALOG) \
+ $(cmake-utils_use_enable atsc GR_ATSC) \
+ $(cmake-utils_use_enable channels GR_CHANNELS) \
+ $(cmake-utils_use_enable digital GR_DIGITAL) \
+ $(cmake-utils_use_enable doc DOXYGEN) \
+ $(cmake-utils_use_enable doc SPHINX) \
+ $(cmake-utils_use_enable dtv GR_DTV) \
+ $(cmake-utils_use_enable fcd GR_FCD) \
+ $(cmake-utils_use_enable fec GR_FEC) \
+ $(cmake-utils_use_enable filter GR_FILTER) \
+ $(cmake-utils_use_enable grc GRC) \
+ $(cmake-utils_use_enable jack GR_AUDIO_JACK) \
+ $(cmake-utils_use_enable log GR_LOG) \
+ $(cmake-utils_use_enable noaa GR_NOAA) \
+ $(cmake-utils_use_enable oss GR_AUDIO_OSS) \
+ $(cmake-utils_use_enable pager GR_PAGER) \
+ $(cmake-utils_use_enable performance-counters ENABLE_PERFORMANCE_COUNTERS) \
+ $(cmake-utils_use_enable portaudio GR_AUDIO_PORTAUDIO) \
+ $(cmake-utils_use_enable test TESTING) \
+ $(cmake-utils_use_enable trellis GR_TRELLIS) \
+ $(cmake-utils_use_enable uhd GR_UHD) \
+ $(cmake-utils_use_enable utils GR_UTILS) \
+ $(cmake-utils_use_enable vocoder GR_VOCODER) \
+ $(cmake-utils_use_enable wavelet GR_WAVELET) \
+ $(cmake-utils_use_enable wxwidgets GR_WXGUI) \
+ $(cmake-utils_use_enable qt4 GR_QTGUI) \
+ $(cmake-utils_use_enable sdl GR_VIDEO_SDL) \
+ $(cmake-utils_use_enable zeromq GR_ZEROMQ) \
+ -DENABLE_GR_CORE=ON \
+ -DSYSCONFDIR="${EPREFIX}"/etc \
+ -DPYTHON_EXECUTABLE="${PYTHON}"
+ -DGR_PKG_DOC_DIR='${GR_DOC_DIR}/${CMAKE_PROJECT_NAME}'-"${PVF}"
+ )
+ use vocoder && mycmakeargs+=( -DGR_USE_SYSTEM_LIBGSM=TRUE )
+ cmake-utils_src_configure
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ if use examples ; then
+ dodir /usr/share/doc/${PF}/
+ mv "${ED}"/usr/share/${PN}/examples "${ED}"/usr/share/doc/${PF}/ || die
+ else
+ # It seems that the examples are always installed
+ rm -rf "${ED}"/usr/share/${PN}/examples || die
+ fi
+
+ # We install the mimetypes to the correct locations from the ebuild
+ rm -rf "${ED}"/usr/share/${PN}/grc/freedesktop || die
+ rm -f "${ED}"/usr/libexec/${PN}/grc_setup_freedesktop || die
+
+ # Install icons, menu items and mime-types for GRC
+ if use grc ; then
+ local fd_path="${S}/grc/freedesktop"
+ insinto /usr/share/mime/packages
+ doins "${fd_path}/${PN}-grc.xml"
+
+ domenu "${fd_path}/"*.desktop
+ doicon "${fd_path}/"*.png
+ fi
+
+ python_fix_shebang "${ED}"
+}
+
+src_test()
+{
+ ctest -E qtgui
+}
+
+pkg_postinst()
+{
+ local GRC_ICON_SIZES="32 48 64 128 256"
+
+ if use grc ; then
+ fdo-mime_desktop_database_update
+ fdo-mime_mime_database_update
+ for size in ${GRC_ICON_SIZES} ; do
+ xdg-icon-resource install --noupdate --context mimetypes --size ${size} \
+ "${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" application-gnuradio-grc \
+ || die "icon resource installation failed"
+ xdg-icon-resource install --noupdate --context apps --size ${size} \
+ "${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" gnuradio-grc \
+ || die "icon resource installation failed"
+ done
+ xdg-icon-resource forceupdate
+ fi
+}
+
+pkg_postrm()
+{
+ local GRC_ICON_SIZES="32 48 64 128 256"
+
+ if use grc ; then
+ fdo-mime_desktop_database_update
+ fdo-mime_mime_database_update
+ for size in ${GRC_ICON_SIZES} ; do
+ xdg-icon-resource uninstall --noupdate --context mimetypes --size ${size} \
+ application-gnuradio-grc || ewarn "icon uninstall failed"
+ xdg-icon-resource uninstall --noupdate --context apps --size ${size} \
+ gnuradio-grc || ewarn "icon uninstall failed"
+
+ done
+ xdg-icon-resource forceupdate
+ fi
+}