From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-850990-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	by finch.gentoo.org (Postfix) with ESMTP id B15791384B4
	for <garchives@archives.gentoo.org>; Thu, 10 Dec 2015 07:45:53 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 4E80C21C006;
	Thu, 10 Dec 2015 07:45:53 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id CBD5D21C006
	for <gentoo-commits@lists.gentoo.org>; Thu, 10 Dec 2015 07:45:52 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id BFCCB3408CB
	for <gentoo-commits@lists.gentoo.org>; Thu, 10 Dec 2015 07:45:51 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 24E16B5D
	for <gentoo-commits@lists.gentoo.org>; Thu, 10 Dec 2015 07:45:50 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1449733546.03174eb30f9d8a3ea12d058d6eee3f9023523815.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: x11-libs/cairo/
X-VCS-Repository: repo/gentoo
X-VCS-Files: x11-libs/cairo/Manifest x11-libs/cairo/cairo-1.14.6.ebuild
X-VCS-Directories: x11-libs/cairo/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: 03174eb30f9d8a3ea12d058d6eee3f9023523815
X-VCS-Branch: master
Date: Thu, 10 Dec 2015 07:45:50 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: 44ca55e2-253a-4968-a604-0e5bb7f4e727
X-Archives-Hash: bc4dc58525e919fff978ffc0cdfcc51b

commit:     03174eb30f9d8a3ea12d058d6eee3f9023523815
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 10 07:44:51 2015 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Thu Dec 10 07:45:46 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=03174eb3

x11-libs/cairo: Bump to version 1.14.6

Package-Manager: portage-2.2.26
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 x11-libs/cairo/Manifest            |   1 +
 x11-libs/cairo/cairo-1.14.6.ebuild | 160 +++++++++++++++++++++++++++++++++++++
 2 files changed, 161 insertions(+)

diff --git a/x11-libs/cairo/Manifest b/x11-libs/cairo/Manifest
index 73eb15e..7d6c531 100644
--- a/x11-libs/cairo/Manifest
+++ b/x11-libs/cairo/Manifest
@@ -1,2 +1,3 @@
 DIST cairo-1.14.2.tar.xz 35376404 SHA256 c919d999ddb1bbbecd4bbe65299ca2abd2079c7e13d224577895afa7005ecceb SHA512 74d30f3f879f097b2c3408ef9698da8f337301f971c3eba7f336d02d6b2812d2ca0bd8bbc0cc7ee11127d3574910b1b77fde3b065cfd504436b62e17c2acb200 WHIRLPOOL fd57e1f474280a1df7a641bdcbe4dc5e5a71bd53b9e46e54302c7858e3bc0081fd1145f19133152819d259611096e4cca034c9caa73a748a507de9094f81a519
 DIST cairo-1.14.4.tar.xz 36040204 SHA256 f6ec9c7c844db9ec011f0d66b57ef590c45adf55393d1fc249003512522ee716 SHA512 b0d983c89ed31a53e26af89e174bb6df3e7c83cf482cbf975c839022ea84b74bb775599d24ca50f4482bbb6d6ef5d09ebb8273d08dfc928328f880344d4e66b2 WHIRLPOOL 88d8e1b622fb6b5c4530d558cf3a4c10ea83820e3e243b9d8c9e3436e3276e9824f028ae96aafd2f4ba349ec4e4a5c84767e7ecd5a5a1de87ef3953e5c61be6e
+DIST cairo-1.14.6.tar.xz 36040596 SHA256 613cb38447b76a93ff7235e17acd55a78b52ea84a9df128c3f2257f8eaa7b252 SHA512 e2aa17a33b95b68d407b53ac321cca15b0c148eb49b8639c75b2af1e75e7b417a2168ea978dabb8581b341f0f45dc042d3b1a56b01ab525b1984015f0865316b WHIRLPOOL cf58eff36277d013225e5a76a9f0d8530012502a3f125c417085ddc9ad7997ab180468783ae6a702a15ac4a3f4c0b5406170a6e6504785bf7de3a9e3b511b48f

diff --git a/x11-libs/cairo/cairo-1.14.6.ebuild b/x11-libs/cairo/cairo-1.14.6.ebuild
new file mode 100644
index 0000000..12d34b3
--- /dev/null
+++ b/x11-libs/cairo/cairo-1.14.6.ebuild
@@ -0,0 +1,160 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils flag-o-matic autotools multilib-minimal
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
+	SRC_URI=""
+else
+	SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A vector graphics library with cross-device output support"
+HOMEPAGE="http://cairographics.org/"
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="X aqua debug directfb gles2 +glib opengl static-libs +svg valgrind xcb xlib-xcb"
+# gtk-doc regeneration doesn't seem to work with out-of-source builds
+#[[ ${PV} == *9999* ]] && IUSE="${IUSE} doc" # API docs are provided in tarball, no need to regenerate
+
+# Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
+RESTRICT="test"
+
+RDEPEND=">=dev-libs/lzo-2.06-r1[${MULTILIB_USEDEP}]
+	>=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}]
+	>=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}]
+	>=media-libs/libpng-1.6.10:0=[${MULTILIB_USEDEP}]
+	sys-libs/binutils-libs:0=[${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	>=x11-libs/pixman-0.32.4[${MULTILIB_USEDEP}]
+	directfb? ( dev-libs/DirectFB )
+	gles2? ( >=media-libs/mesa-9.1.6[gles2,${MULTILIB_USEDEP}] )
+	glib? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
+	opengl? ( || ( >=media-libs/mesa-9.1.6[egl,${MULTILIB_USEDEP}] media-libs/opengl-apple ) )
+	X? (
+		>=x11-libs/libXrender-0.9.8[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+	)
+	xcb? (
+		>=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
+	)
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-gtklibs-20131008-r1
+		!app-emulation/emul-linux-x86-gtklibs[-abi_x86_32(-)]
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	>=sys-devel/libtool-2
+	X? (
+		>=x11-proto/renderproto-0.11.1-r1[${MULTILIB_USEDEP}]
+	)"
+#[[ ${PV} == *9999* ]] && DEPEND="${DEPEND}
+#	doc? (
+#		>=dev-util/gtk-doc-1.6
+#		~app-text/docbook-xml-dtd-4.2
+#	)"
+
+REQUIRED_USE="
+	gles2? ( !opengl )
+	xlib-xcb? ( xcb )
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/cairo/cairo-directfb.h
+)
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.12.18-disable-test-suite.patch
+	epatch "${FILESDIR}"/${PN}-respect-fontconfig.patch
+
+	# tests and perf tools require X, bug #483574
+	if ! use X; then
+		sed -e '/^SUBDIRS/ s#boilerplate test perf# #' -i Makefile.am || die
+	fi
+
+	epatch_user
+
+	# Slightly messed build system YAY
+	if [[ ${PV} == *9999* ]]; then
+		touch boilerplate/Makefile.am.features
+		touch src/Makefile.am.features
+		touch ChangeLog
+	fi
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myopts
+
+	[[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
+
+	use elibc_FreeBSD && myopts+=" --disable-symbol-lookup"
+
+	# TODO: remove this (and add USE-dep) when DirectFB is converted,
+	# bug #484248 -- but beware of the circular dep.
+	if ! multilib_is_native_abi; then
+		myopts+=" --disable-directfb"
+	fi
+
+	# TODO: remove this (and add USE-dep) when qtgui is converted, bug #498010
+	if ! multilib_is_native_abi; then
+		myopts+=" --disable-qt"
+	fi
+
+	# [[ ${PV} == *9999* ]] && myopts+=" $(use_enable doc gtk-doc)"
+
+	ECONF_SOURCE="${S}" \
+	econf \
+		--disable-dependency-tracking \
+		$(use_with X x) \
+		$(use_enable X tee) \
+		$(use_enable X xlib) \
+		$(use_enable X xlib-xrender) \
+		$(use_enable aqua quartz) \
+		$(use_enable aqua quartz-image) \
+		$(use_enable debug test-surfaces) \
+		$(use_enable directfb) \
+		$(use_enable gles2 glesv2) \
+		$(use_enable glib gobject) \
+		$(use_enable opengl gl) \
+		$(use_enable static-libs static) \
+		$(use_enable svg) \
+		$(use_enable valgrind) \
+		$(use_enable xcb) \
+		$(use_enable xcb xcb-shm) \
+		$(use_enable xlib-xcb) \
+		--enable-ft \
+		--enable-pdf \
+		--enable-png \
+		--enable-ps \
+		--disable-drm \
+		--disable-gallium \
+		--disable-qt \
+		--disable-vg \
+		${myopts}
+}
+
+multilib_src_install_all() {
+	prune_libtool_files --all
+	einstalldocs
+}
+
+pkg_postinst() {
+	if use !xlib-xcb; then
+		if has_version net-misc/nxserver-freenx \
+				|| has_version net-misc/x2goserver; then
+			ewarn "cairo-1.12 is known to cause GTK+ errors with NX servers."
+			ewarn "Enable USE=\"xlib-xcb\" if you notice incorrect behavior in GTK+"
+			ewarn "applications that are running inside NX sessions. For details, see"
+			ewarn "https://bugs.gentoo.org/441878 or https://bugs.freedesktop.org/59173"
+		fi
+	fi
+}