[gentoo-commits] repo/gentoo:master commit in: net-misc/aria2/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1ac46041db8c84deccc8e45bcb0fa819f73b9d9e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 21 21:55:16 2015 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Nov 21 22:23:54 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1ac46041

net-misc/aria2: Bump to 1.19.2, #566408

Bump to version 1.19.2 which contains quite a large list of bugfixes.
Most importantly, RSA-SHA1 was reenabled in TLS since it caused many
interoperability problems.

 net-misc/aria2/Manifest            |   1 +
 net-misc/aria2/aria2-1.19.2.ebuild | 149 +++++++++++++++++++++++++++++++++++++
 2 files changed, 150 insertions(+)

diff --git a/net-misc/aria2/Manifest b/net-misc/aria2/Manifest
index 8d0df88..c5769b6 100644
--- a/net-misc/aria2/Manifest
+++ b/net-misc/aria2/Manifest
@@ -6,3 +6,4 @@ DIST aria2-1.18.5.tar.bz2 2102797 SHA256 25e21f94bb278a8624e0e4e131e740d105f7d55
 DIST aria2-1.18.7.tar.bz2 2141933 SHA256 358bda2a7b1d5aca1acc4b528f32bd01f5db819c067e7a4bbfab08d23500368f SHA512 d8b70d0235eb96289ebeb4adc4c5a917785dcd15ebae884b367b3645717bc969ded9c0f520be773fc80ed5dd112fd5937bee6cb0e8c238dc39debbf8862b25a3 WHIRLPOOL 714c2d88ef5a66e3d08970aa02dfa1a2da284042faf5e6e8ad6bb6f6706c8c4ba1d44681ef0f6c58ced052debb000cebcc0266b45226f31983bb3e3790149d7c
 DIST aria2-1.18.9.tar.bz2 2151923 SHA256 e24bca91edbe8fff52615420085317ce22faec4a0a9c34843f86dbcc2a79c4b2 SHA512 6a701f23167255a8ea135c6c9455a11d0eddf007fbcc1c3af663dd98825c0812d7db0214be963a06740e60d8b6fdae92bee5062aa4864b212b959e97ac857d74 WHIRLPOOL 0996dbbcd9828e8a977275f889e14a0e5a8fc0dc5d1a05a7550542cab27de252597389a796da98590935d02a81fdf302f9d078c8c0068af0587a2437ee01e85a
 DIST aria2-1.19.0.tar.bz2 2155310 SHA256 ae2b6fce7a0974c9156415cccf2395cd258580ab34eec2b34a8e76120b7240ce SHA512 ba505b45f84266543cb403752cc3592469545dea806e77bd7b7fec1fbe7ed5baf14372cf6dea840ccbdd054cd0c92cdeb4516eb52b167aca03909000f02aec95 WHIRLPOOL b13502f9dd646832799af6a0db199e87abae042c0e48b778f9b782d56d838c5b9d36bc04c487534f3fe1c59e970dc34702facc5508927325e34bcffa39946519
+DIST aria2-1.19.2.tar.xz 1377356 SHA256 3605486dd495cd8c2f672b7d0b763397989d831396862f15730697ebcf0ad53e SHA512 ae3fb231fa9f989a8c4f8015d7e64db2b62b922548839a884454ef1fc6dc024363b482268200efa234ac71a1dba969aaefbeb81c811223e2e117f3adae9a8468 WHIRLPOOL 10f4ad709e26f29685b05e5db4fde687c733404a994649d4f5c5a8f66bf60142ae3bc65179db7b83766e32663100b5c7c58f1b6e4a6f6a4d2f089176604a8c95

diff --git a/net-misc/aria2/aria2-1.19.2.ebuild b/net-misc/aria2/aria2-1.19.2.ebuild
new file mode 100644
index 0000000..512ee76
--- /dev/null
+++ b/net-misc/aria2/aria2-1.19.2.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit bash-completion-r1 eutils
+
+DESCRIPTION="A download utility with segmented downloading with BitTorrent support"
+HOMEPAGE="http://aria2.sourceforge.net/"
+SRC_URI="https://github.com/tatsuhiro-t/${PN}/releases/download/release-${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+SLOT="0"
+IUSE="adns bittorrent +gnutls jemalloc libuv +libxml2 metalink +nettle nls sqlite scripts ssh ssl tcmalloc test xmlrpc"
+
+CDEPEND="sys-libs/zlib:0=
+	ssl? (
+		app-misc/ca-certificates
+		gnutls? ( >=net-libs/gnutls-1.2.9:0= )
+		!gnutls? ( dev-libs/openssl:0= ) )
+	adns? ( >=net-dns/c-ares-1.5.0:0= )
+	bittorrent? (
+		ssl? (
+			gnutls? (
+				nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-5:0= )
+				!nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+		!ssl? (
+			nettle? ( >=dev-libs/nettle-2.4:0=[gmp] >=dev-libs/gmp-5:0= )
+			!nettle? ( >=dev-libs/libgcrypt-1.2.2:0= ) ) )
+	jemalloc? ( dev-libs/jemalloc )
+	libuv? ( dev-libs/libuv:0= )
+	metalink? (
+		libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+		!libxml2? ( dev-libs/expat:0= ) )
+	sqlite? ( dev-db/sqlite:3= )
+	ssh? ( net-libs/libssh2:= )
+	tcmalloc? ( dev-util/google-perftools )
+	xmlrpc? (
+		libxml2? ( >=dev-libs/libxml2-2.6.26:2= )
+		!libxml2? ( dev-libs/expat:0= ) )"
+
+DEPEND="${CDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( >=dev-util/cppunit-1.12.0:0 )"
+RDEPEND="${CDEPEND}
+	nls? ( virtual/libiconv virtual/libintl )
+	scripts? ( dev-lang/ruby )"
+
+REQUIRED_USE="jemalloc? ( !tcmalloc )
+	tcmalloc? ( !jemalloc )"
+
+pkg_setup() {
+	if use scripts && use !xmlrpc && use !metalink; then
+		ewarn "Please note that you may need to enable USE=xmlrpc to run the aria2rpc"
+		ewarn "and aria2mon scripts against the local aria2."
+	fi
+}
+
+src_prepare() {
+	epatch_user
+	sed -i -e "s|/tmp|${T}|" test/*.cc test/*.txt || die "sed failed"
+}
+
+src_configure() {
+	local myconf=(
+		# threads, epoll: check for best portability
+
+		# do not try to compile and run a test LIBXML program
+		--disable-xmltest
+		# enable the shared library
+		--enable-libaria2
+		# zlib should always be available anyway
+		--with-libz
+		--with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt"
+
+		# optional features
+		$(use_enable bittorrent)
+		$(use_enable metalink)
+		$(use_enable nls)
+		$(use_with sqlite sqlite3)
+		$(use_with adns libcares)
+		$(use_with libuv)
+		$(use_with jemalloc)
+		$(use_with tcmalloc)
+	)
+
+	# SSL := gnutls / openssl
+	# USE=ssl
+	#  + USE=gnutls -> gnutls
+	#  + USE=-gnutls -> openssl
+
+	if use ssl; then
+		myconf+=( $(use_with gnutls) $(use_with !gnutls openssl) )
+	else
+		myconf+=( --without-gnutls --without-openssl )
+	fi
+
+	# message-digest := nettle / gcrypt / openssl
+	# bignum := nettle+gmp / gcrypt / openssl
+	# bittorrent := message-digest + bignum
+	# USE=bittorrent
+	#  + USE=(ssl -gnutls) -> openssl
+	#  + USE=nettle -> nettle+gmp
+	#  + USE=-nettle -> gcrypt
+
+	if use !bittorrent || use ssl && use !gnutls; then
+		myconf+=( --without-libgcrypt --without-libnettle --without-libgmp )
+	else
+		myconf+=( $(use_with !nettle libgcrypt)
+			$(use_with nettle libnettle) $(use_with nettle libgmp) )
+	fi
+
+	# metalink+xmlrpc := libxml2 / expat
+	# USE=(metalink || xmlrpc)
+	#  + USE=libxml2 -> libxml2
+	#  + USE=-libxml2 -> expat
+
+	if use metalink || use xmlrpc; then
+		myconf+=( $(use_with !libxml2 libexpat) $(use_with libxml2) )
+	else
+		myconf+=( --without-libexpat --without-libxml2 )
+	fi
+
+	# Note:
+	# - always enable gzip/http compression since zlib should always be available anyway
+	# - always enable epoll since we can assume kernel 2.6.x
+	# - other options for threads: solaris, pth, win32
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	rm -rf "${D}"/usr/share/doc/aria2 \
+		"${D}"/usr/share/doc/${PF}/README{,.html}
+
+	dobashcomp doc/bash_completion/aria2c
+	use scripts && dobin doc/xmlrpc/aria2{mon,rpc}
+}
+
+pkg_postinst() {
+	if use xmlrpc || use metalink; then
+		elog "If you would like to use the additional aria2mon and aria2rpc tools,"
+		elog "you need to have \033[1mdev-lang/ruby\033[0m installed."
+	fi
+}