[gentoo-commits] proj/gnome:master commit in: gnome-extra/gnome-tweak-tool/

["Ole Reifschneider" <tranquility@gentoo.org>]

commit:     7d351c4ab02f5ee6c0c88b04d0b558b3c9ca3ada
Author:     Ole Reifschneider <tranquility <AT> gentoo <DOT> org>
AuthorDate: Sat Nov  7 18:22:30 2015 +0000
Commit:     Ole Reifschneider <tranquility <AT> gentoo <DOT> org>
CommitDate: Sat Nov  7 18:23:17 2015 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=7d351c4a

gnome-extra/gnome-tweak-tool: Bump version to 3.18.0

Package-Manager: portage-2.2.23
Manifest-Sign-Key: 0xE9E568677E8B4D42

 .../gnome-tweak-tool-3.18.0.ebuild                 | 74 ++++++++++++++++++++++
 1 file changed, 74 insertions(+)

diff --git a/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.18.0.ebuild b/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.18.0.ebuild
new file mode 100644
index 0000000..5314e0a
--- /dev/null
+++ b/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.18.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils gnome2 python-r1
+
+DESCRIPTION="Tool to customize GNOME 3 options"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/GnomeTweakTool"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Newer pygobject needed due upstream bug #723951
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=gnome-base/gsettings-desktop-schemas-3.4
+	>=dev-python/pygobject-3.10.2:3[${PYTHON_USEDEP}]
+"
+# g-s-d, gnome-desktop, gnome-shell etc. needed at runtime for the gsettings schemas
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-base/gnome-desktop-3.6.0.1:3=[introspection]
+	>=x11-libs/gtk+-3.12:3[introspection]
+
+	net-libs/libsoup[introspection]
+	x11-libs/libnotify[introspection]
+
+	>=gnome-base/gnome-settings-daemon-3
+	gnome-base/gnome-shell
+	>=gnome-base/nautilus-3
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Add contents of Gentoo's cursor theme directory to cursor theme list
+	epatch "${FILESDIR}/${PN}-3.10.1-gentoo-cursor-themes.patch"
+
+	# Prevent problems setting WM preferences, upstream bug #706834
+	epatch "${FILESDIR}/${PN}-3.8.1-wm-preferences.patch"
+
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	install_python() {
+		gnome2_src_install
+		python_doscript gnome-tweak-tool || die
+	}
+	python_foreach_impl run_in_build_dir install_python
+}