[gentoo-commits] repo/gentoo:master commit in: games-engines/scummvm-tools/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     888e9aa0168d733e3afaf7bc30e58761f5b31873
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 25 14:20:07 2015 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Oct 25 14:20:07 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=888e9aa0

games-engines/scummvm-tools: Support wxGTK:3.0

Package-Manager: portage-2.2.23

 .../scummvm-tools/scummvm-tools-1.7.0-r1.ebuild    | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/games-engines/scummvm-tools/scummvm-tools-1.7.0-r1.ebuild b/games-engines/scummvm-tools/scummvm-tools-1.7.0-r1.ebuild
new file mode 100644
index 0000000..6c675fe
--- /dev/null
+++ b/games-engines/scummvm-tools/scummvm-tools-1.7.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+WX_GTK_VER=3.0
+inherit wxwidgets eutils flag-o-matic games
+
+DESCRIPTION="utilities for the SCUMM game engine"
+HOMEPAGE="http://scummvm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/scummvm/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="flac iconv mad png vorbis"
+RESTRICT="test" # some tests require external files
+
+RDEPEND="png? ( media-libs/libpng:0 )
+	mad? ( media-libs/libmad )
+	flac? ( media-libs/flac )
+	vorbis? ( media-libs/libvorbis )
+	iconv? ( virtual/libiconv media-libs/freetype:2 )
+	sys-libs/zlib
+	>=dev-libs/boost-1.32
+	x11-libs/wxGTK:${WX_GTK_VER}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	need-wxwidgets unicode
+	rm -rf *.bat dists/win32
+	sed -ri -e '/^(CC|CXX)\b/d' Makefile || die
+	epatch "${FILESDIR}/${P}-binprefix.patch"
+}
+
+src_configure() {
+	# Not an autoconf script
+	./configure \
+		--enable-verbose-build \
+		--mandir=/usr/share/man \
+		--prefix="${GAMES_PREFIX}" \
+		--libdir="${GAMES_PREFIX}/lib" \
+		--datadir="${GAMES_DATADIR}" \
+		$(use_enable flac) \
+		$(use_enable iconv) \
+		$(use_enable iconv freetype) \
+		$(use_enable mad) \
+		$(use_enable png) \
+		$(use_enable vorbis) || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" EXEPREFIX="${PN}-" install
+	dodoc README TODO
+	prepgamesdirs
+}