[gentoo-commits] repo/gentoo:master commit in: sci-biology/bowtie/

["Justin Lecher" <jlec@gentoo.org>]

commit:     5ca4d1505a37f273d7eaee41f89b676381e6305e
Author:     Ted Tanberry <ted.tanberry <AT> gmail <DOT> com>
AuthorDate: Sat Oct 10 19:07:16 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Wed Oct 14 12:47:58 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5ca4d150

sci-biology/bowtie: Add bowtie2 in SLOT=2

 sci-biology/bowtie/bowtie-2.2.6.ebuild | 54 ++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/sci-biology/bowtie/bowtie-2.2.6.ebuild b/sci-biology/bowtie/bowtie-2.2.6.ebuild
new file mode 100644
index 0000000..50aca7e
--- /dev/null
+++ b/sci-biology/bowtie/bowtie-2.2.6.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="Popular short read aligner for Next-generation sequencing data, allowing for gaps"
+HOMEPAGE="http://bowtie-bio.sourceforge.net/bowtie2/"
+SRC_URI="mirror://sourceforge/project/${PN}-bio/${PN}2/${PV}/${PN}2-${PV}-source.zip"
+
+LICENSE="GPL-3"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="examples cpu_flags_x86_sse2 tbb"
+REQUIRED_USE="cpu_flags_x86_sse2"
+
+RDEPEND="dev-lang/perl"
+DEPEND="${RDEPEND}
+		app-arch/unzip
+		tbb? ( dev-cpp/tbb )"
+
+S="${WORKDIR}/${PN}2-${PV}"
+
+DOCS=( AUTHORS NEWS TUTORIAL )
+HTML_DOCS=( doc/{manual.html,style.css} )
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CPP="$(tc-getCXX)" \
+		CFLAGS="" \
+		CXXFLAGS="" \
+		EXTRA_FLAGS="${LDFLAGS}" \
+		RELEASE_FLAGS="${CXXFLAGS} -msse2" \
+		WITH_TBB="$(usex tbb 1 0)"
+}
+
+src_install() {
+	dobin ${PN}2 ${PN}2-*
+
+	exeinto /usr/libexec/${PN}2
+	doexe scripts/*
+
+	newman MANUAL ${PN}2.1
+	einstalldocs
+
+	if use examples; then
+		insinto /usr/share/${PN}2
+		doins -r example
+	fi
+}