[gentoo-commits] proj/sci:master commit in: sci-biology/atsas/

["Justin Lecher" <jlec@gentoo.org>]

commit:     ea709a858a4b1c6a6fc0a213a9372c9f4d5ee538
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Mon Oct 12 13:48:09 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Mon Oct 12 13:48:09 2015 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=ea709a85

sci-biology/atsas: Version Bump

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>

 sci-biology/atsas/atsas-2.7.0.ebuild | 76 ++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)

diff --git a/sci-biology/atsas/atsas-2.7.0.ebuild b/sci-biology/atsas/atsas-2.7.0.ebuild
new file mode 100644
index 0000000..7991ec6
--- /dev/null
+++ b/sci-biology/atsas/atsas-2.7.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-r1
+
+DESCRIPTION="Biological Small Angle Scattering"
+HOMEPAGE="http://www.embl-hamburg.de/biosaxs"
+#SRC_URI="ATSAS-${PV}-1.sl5.x86_64.tar.gz"
+#SRC_URI="ATSAS-${PV}-1.el6.x86_64.tar.gz"
+SRC_URI="ATSAS-${PV}-1_amd64.tar.gz"
+
+SLOT="0"
+LICENSE="atsas"
+KEYWORDS="~amd64 ~amd64-linux"
+IUSE="examples"
+
+RDEPEND="
+	dev-libs/libxml2:2
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	media-libs/tiff:0
+	sci-libs/cbflib
+	x11-libs/qwt:5
+"
+DEPEND="dev-util/patchelf"
+
+RESTRICT="fetch"
+
+S="${WORKDIR}"/${P^^}-1
+
+QA_PREBUILT="opt/.* usr/.*"
+
+pkg_nofetch() {
+	elog "Please visit http://www.embl-hamburg.de/biosaxs/atsas-online/download.php"
+	elog "and download the ${A} for Ubuntu 14.04"
+	elog "and place it in ${DISTDIR}"
+}
+
+src_install() {
+	local i
+	for i in bin/*; do
+		patchelf \
+			--set-rpath "$(gcc-config -L):${EPREFIX}/opt/${PN}/:${EPREFIX}/usr/lib/qt4/" \
+			${i} || die
+	done
+	exeinto /opt/bin
+	doexe bin/*
+
+	insinto /opt/${PN}
+	doins lib/*/atsas/{libedf.so*,libqtsoap.so*,libqwt*.so*,libsaxs*.so*}
+
+	python_foreach_impl python_domodule lib/*/atsas/python*/dist-packages/*
+
+	rm share/doc/${P}/LICENSE.txt || die
+	if use examples; then
+		cp -rf share/doc/${P}/* share/${PN}/ || die
+	fi
+
+	pushd share/icons/hicolor/ > /dev/null
+	for i in *; do
+		doicon -s ${i} -t hicolor ${i}/*
+	done
+	popd > /dev/null
+
+	domenu share/applications/*
+
+	rm -rf share/{applications,doc,icons,mime} || die
+
+	insinto /usr
+	doins -r share
+}