[gentoo-commits] proj/sci:master commit in: dev-python/nbformat/

["Marius Brehler" <marbre@linux.sungazer.de>]

commit:     9a88502c1d3528899f000f1bf52691a1ad4c3d75
Author:     Marius Brehler <marbre <AT> linux <DOT> sungazer <DOT> de>
AuthorDate: Tue Oct  6 21:16:11 2015 +0000
Commit:     Marius Brehler <marbre <AT> linux <DOT> sungazer <DOT> de>
CommitDate: Tue Oct  6 21:16:11 2015 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=9a88502c

dev-python/nbformat: Version bump

Package-Manager: portage-2.2.20.1

 dev-python/nbformat/ChangeLog             |  5 +++
 dev-python/nbformat/nbformat-4.0.1.ebuild | 59 +++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-python/nbformat/ChangeLog b/dev-python/nbformat/ChangeLog
index 1fc6362..934c6c2 100644
--- a/dev-python/nbformat/ChangeLog
+++ b/dev-python/nbformat/ChangeLog
@@ -2,6 +2,11 @@
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
 # $Id$
 
+*nbformat-4.0.1 (06 Oct 2015)
+
+  06 Oct 2015; Marius Brehler <marbre@linux.sungazer.de> +nbformat-4.0.1.ebuild:
+  dev-python/nbformat: Version bump
+
   21 Sep 2015; Marius Brehler <marbre@linux.sungazer.de> nbformat-9999.ebuild:
   dev-python/nbformat: Add ~x86 to KEYWORDS
 

diff --git a/dev-python/nbformat/nbformat-4.0.1.ebuild b/dev-python/nbformat/nbformat-4.0.1.ebuild
new file mode 100644
index 0000000..cc116c0
--- /dev/null
+++ b/dev-python/nbformat/nbformat-4.0.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python{3_3,3_4} )
+PYTHON_REQ_USE='sqlite'
+
+inherit distutils-r1
+
+DESCRIPTION="Reference implementation of the Jupyter Notebook format"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	nosetests --with-coverage --cover-package=nbformat nbformat || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}