[gentoo-commits] repo/gentoo:master commit in: dev-haskell/hsopenssl/

["Julian Ospald" <hasufell@gentoo.org>]

commit:     23d8ca99c627a1b32eb9feb8bef00d42e46d869b
Author:     Julian Ospald <hasufell <AT> gentoo <DOT> org>
AuthorDate: Tue Oct  6 10:22:35 2015 +0000
Commit:     Julian Ospald <hasufell <AT> gentoo <DOT> org>
CommitDate: Tue Oct  6 10:25:45 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23d8ca99

dev-haskell/hsopenssl: add libressl support

This also fixes the incorrect slot operator on dev-libs/openssl.

 dev-haskell/hsopenssl/hsopenssl-0.11.1.1-r1.ebuild | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-haskell/hsopenssl/hsopenssl-0.11.1.1-r1.ebuild b/dev-haskell/hsopenssl/hsopenssl-0.11.1.1-r1.ebuild
new file mode 100644
index 0000000..1f9732a
--- /dev/null
+++ b/dev-haskell/hsopenssl/hsopenssl-0.11.1.1-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+# ebuild generated by hackport 0.4.4.9999
+
+CABAL_FEATURES="lib profile haddock hoogle hscolour test-suite"
+inherit haskell-cabal
+
+MY_PN="HsOpenSSL"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Partial OpenSSL binding for Haskell"
+HOMEPAGE="https://github.com/phonohawk/HsOpenSSL"
+SRC_URI="mirror://hackage/packages/archive/${MY_PN}/${PV}/${MY_P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="+fast-bignum libressl"
+
+RESTRICT=test # whoops, not good
+
+RDEPEND=">=dev-haskell/network-2.1:=[profile?] <dev-haskell/network-2.7:=[profile?]
+	>=dev-haskell/old-locale-1.0:=[profile?] <dev-haskell/old-locale-1.1:=[profile?]
+	>=dev-lang/ghc-7.4.1:=
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-haskell/cabal-1.8
+	test? ( >=dev-haskell/hunit-1.0 <dev-haskell/hunit-1.3
+		>=dev-haskell/test-framework-0.8 <dev-haskell/test-framework-0.9
+		>=dev-haskell/test-framework-hunit-0.3 <dev-haskell/test-framework-hunit-0.4 )
+"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	local fbn_flag=$(cabal_flag fast-bignum fast-bignum)
+
+	# not ported to integer-gmp-1.0:
+	#  https://github.com/phonohawk/HsOpenSSL/issues/36
+	[[ $(ghc-version) == 7.10.* ]] && fbn_flag=-f-fast-bignum
+
+	haskell-cabal_src_configure \
+		${fbn_flag}
+}