[gentoo-commits] proj/sci:master commit in: dev-python/jupyter_console/, dev-python/jupyter_client/, ...

[gentoo-commits] proj/sci:master commit in: dev-python/jupyter_console/, dev-python/jupyter_client/, ...

[Justin Lecher]

commit:     dbf36f65d5daefbc35b016d85bf7eb0e88f6f54e
Author:     Marius Brehler <marbre <AT> linux <DOT> sungazer <DOT> de>
AuthorDate: Tue Sep 22 09:15:53 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Tue Sep 22 09:15:53 2015 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=dbf36f65

dev-python/jupyter_{client,consolse,core}: Add missing ebuilds

repo-commit doesn't seem to like typechanges

 .../jupyter_client/jupyter_client-4.0.0.ebuild     | 36 +++++++++++++-
 .../jupyter_console/jupyter_console-4.0.2.ebuild   | 55 +++++++++++++++++++++-
 dev-python/jupyter_core/jupyter_core-4.0.6.ebuild  | 54 ++++++++++++++++++++-
 3 files changed, 142 insertions(+), 3 deletions(-)

diff --git a/dev-python/jupyter_client/jupyter_client-4.0.0.ebuild b/dev-python/jupyter_client/jupyter_client-4.0.0.ebuild
deleted file mode 120000
index f883a2e..0000000
--- a/dev-python/jupyter_client/jupyter_client-4.0.0.ebuild
+++ /dev/null
@@ -1 +0,0 @@
-jupyter_client-9999.ebuild
\ No newline at end of file

diff --git a/dev-python/jupyter_client/jupyter_client-4.0.0.ebuild b/dev-python/jupyter_client/jupyter_client-4.0.0.ebuild
new file mode 100644
index 0000000..7a24b82
--- /dev/null
+++ b/dev-python/jupyter_client/jupyter_client-4.0.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python{3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter protocol implementation and client libraries"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="test"
+
+RDEPEND="
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-14.4.0[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+	)
+	"
+
+python_test() {
+	nosetests --with-coverage jupyter_client || die
+}

diff --git a/dev-python/jupyter_console/jupyter_console-4.0.2.ebuild b/dev-python/jupyter_console/jupyter_console-4.0.2.ebuild
deleted file mode 120000
index 38c6bbe..0000000
--- a/dev-python/jupyter_console/jupyter_console-4.0.2.ebuild
+++ /dev/null
@@ -1 +0,0 @@
-jupyter_console-9999.ebuild
\ No newline at end of file

diff --git a/dev-python/jupyter_console/jupyter_console-4.0.2.ebuild b/dev-python/jupyter_console/jupyter_console-4.0.2.ebuild
new file mode 100644
index 0000000..a1fca11
--- /dev/null
+++ b/dev-python/jupyter_console/jupyter_console-4.0.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python{3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="A terminal-based console frontend for Jupyter kernels"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/ipython[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests --with-coverage --cover-package=jupyter_console jupyter_console || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

diff --git a/dev-python/jupyter_core/jupyter_core-4.0.6.ebuild b/dev-python/jupyter_core/jupyter_core-4.0.6.ebuild
deleted file mode 120000
index 6577c42..0000000
--- a/dev-python/jupyter_core/jupyter_core-4.0.6.ebuild
+++ /dev/null
@@ -1 +0,0 @@
-jupyter_core-9999.ebuild
\ No newline at end of file

diff --git a/dev-python/jupyter_core/jupyter_core-4.0.6.ebuild b/dev-python/jupyter_core/jupyter_core-4.0.6.ebuild
new file mode 100644
index 0000000..42b63ea
--- /dev/null
+++ b/dev-python/jupyter_core/jupyter_core-4.0.6.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python{3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Core common functionality of Jupyter projects"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	py.test jupyter_core || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}