[gentoo-commits] proj/sci:master commit in: dev-python/notebook/

["Justin Lecher" <jlec@gentoo.org>]

commit:     1bf8af55da3d685431f0dfe9d23f6a393d12b633
Author:     Marius Brehler <marbre <AT> linux <DOT> sungazer <DOT> de>
AuthorDate: Tue Sep 22 08:54:04 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Tue Sep 22 08:54:04 2015 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=1bf8af55

dev-python/notebook: Version bump

Package-Manager: portage-2.2.20.1

 dev-python/notebook/ChangeLog             |  5 ++
 dev-python/notebook/notebook-4.0.5.ebuild | 85 +++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)

diff --git a/dev-python/notebook/ChangeLog b/dev-python/notebook/ChangeLog
index 9585e9f..2d7e2ea 100644
--- a/dev-python/notebook/ChangeLog
+++ b/dev-python/notebook/ChangeLog
@@ -2,6 +2,11 @@
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
 # $Id$
 
+*notebook-4.0.5 (22 Sep 2015)
+
+  22 Sep 2015; Marius Brehler <marbre@linux.sungazer.de> +notebook-4.0.5.ebuild:
+  dev-python/notebook: Version bump
+
   22 Sep 2015; Marius Brehler <marbre@linux.sungazer.de>
   notebook-4.0.4-r3.ebuild, notebook-9999.ebuild:
   dev-python/notebook: Add ~x86 to KEYWORDS, fixes #561032

diff --git a/dev-python/notebook/notebook-4.0.5.ebuild b/dev-python/notebook/notebook-4.0.5.ebuild
new file mode 100644
index 0000000..1989a1a
--- /dev/null
+++ b/dev-python/notebook/notebook-4.0.5.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python{3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+RDEPEND="
+	>=dev-libs/mathjax-2.4
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.3.3[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/nbconvert[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+		>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+	)
+	doc? (
+		app-text/pandoc
+		>=dev-python/ipython-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	sed \
+		-e "/import setup/s:$:\nimport setuptools:g" \
+		-i setup.py || die
+
+	# disable bundled mathjax
+	sed -i 's/^.*MathJax.*$//' bower.json || die
+	sed -i 's/mj(/#mj(/' setupbase.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests --with-coverage --cover-package=notebook notebook || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	ln -sf "${EPREFIX}/usr/share/mathjax" "${D}$(python_get_sitedir)/notebook/static/components/MathJax" || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}
+
+pkg_preinst() {
+	# remove old mathjax folder if present
+	rm -rf "${EROOT}"/usr/lib*/python*/site-packages/notebook/static/components/MathJax
+}