[gentoo-commits] repo/gentoo:master commit in: dev-qt/qt-creator/

["Davide Pesavento" <pesa@gentoo.org>]

commit:     c7a6fb24c721d44bbdab8cb8bb42cd2978f1f845
Author:     Davide Pesavento <pesa <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 14 00:19:56 2015 +0000
Commit:     Davide Pesavento <pesa <AT> gentoo <DOT> org>
CommitDate: Mon Sep 14 00:21:05 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c7a6fb24

dev-qt/qt-creator: version bump

Package-Manager: portage-2.2.20.1

 dev-qt/qt-creator/Manifest                |   1 +
 dev-qt/qt-creator/qt-creator-3.5.0.ebuild | 155 ++++++++++++++++++++++++++++++
 2 files changed, 156 insertions(+)

diff --git a/dev-qt/qt-creator/Manifest b/dev-qt/qt-creator/Manifest
index 22e0b3c..ffde8f9 100644
--- a/dev-qt/qt-creator/Manifest
+++ b/dev-qt/qt-creator/Manifest
@@ -1,3 +1,4 @@
 DIST qt-creator-2.8.1-src.tar.gz 24381282 SHA256 d5ae007a297a4288d0e95fd605edbfb8aee80f6788c7a6cfb9cb297f50c364b9 SHA512 954b0caa9a4c6b7debf62562f3c8f1b4edee13488867208e7d41544b244a111024f2c4c144e4b44e98973cf1d7b5885c13c0b6996ade58e204887eb13bb999cb WHIRLPOOL 1aa5018e19315bd2528580ffa388ff17d96666747e4abad28ea4bcd38315e6efc66379cdda90cb32c17dd1631d0ebedff422e53ee0b9b3c40d7a5766ff4dd9b4
 DIST qt-creator-opensource-src-3.2.2.tar.gz 22789455 SHA256 a115f1d7b08446dcfeb79537f3d8d251dbc3c9808d0ff377efe5c4fad7dbd8f0 SHA512 f85381eb6f56d787e5efe02407c4b6f949fd2a766a25567ceccb3a002ec7dd9c6277d9cf39ef0afdd8e110d7bc7436344756225784009a2e01ba9fd8428f885e WHIRLPOOL aa65009cffbc10161cdd9f8e70121c5b2e80df034bb1e06400558a947dcf3284cc23d1b162f85a7ed19af216f0d94d0c5f997c0072c3f19149f64e528fde36a7
 DIST qt-creator-opensource-src-3.4.2.tar.gz 23239370 SHA256 f57df9954768badb252154a51cca9b21a4903f8e003ef944d25801cde1754bab SHA512 65a93574bf6dd35ef4769d4e8a40cb183b2904af6cd32616c15e57654ab575280e7a5d0bbe43296a012e79127831b46fa21890d65472e0c781a95461e5a50812 WHIRLPOOL a56fbb9ea76e9cc7886ee447503c4f7ca646ebf19a113ab95b9b3788d8d75871850c358f13bbd3093f544c65c65f916006cb7571a73292376a7629c236cf0e74
+DIST qt-creator-opensource-src-3.5.0.tar.gz 22583597 SHA256 5dc35f81b50d65243a6ae046125061051d03c3d50937a37e29e0669384bb0eb6 SHA512 bdae95a6ba9950ff7cfc021a89af52972ca735d3831f7df49418b06b0ce45130a42ed1d29a02dbb03f4739226adb22b55dd6701071da44f8c0e31ba389cc66d0 WHIRLPOOL 5bde80476b57df65defb2f32ef5c2263bc4c157ba0c85cf369d190ec364e916da5760ff57b53ef4f8bcad09cf7c4d24185aa52ffe08e54ce5035dc2d4ca95679

diff --git a/dev-qt/qt-creator/qt-creator-3.5.0.ebuild b/dev-qt/qt-creator/qt-creator-3.5.0.ebuild
new file mode 100644
index 0000000..e878225
--- /dev/null
+++ b/dev-qt/qt-creator/qt-creator-3.5.0.ebuild
@@ -0,0 +1,155 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PLOCALES="cs de fr ja pl ru sl uk zh_CN zh_TW"
+inherit eutils l10n multilib qmake-utils virtualx
+
+DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
+HOMEPAGE="http://doc.qt.io/qtcreator/"
+LICENSE="|| ( LGPL-2.1 LGPL-3 )"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI=(
+		"git://code.qt.io/${PN}/${PN}.git"
+		"https://code.qt.io/git/${PN}/${PN}.git"
+	)
+else
+	MY_PV=${PV/_/-}
+	MY_P=${PN}-opensource-src-${MY_PV}
+	[[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
+	SRC_URI="http://download.qt.io/${MY_REL}_releases/${PN/-}/${PV%.*}/${MY_PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+	S=${WORKDIR}/${MY_P}
+fi
+
+QTC_PLUGINS=('android:android|qmakeandroidsupport' autotools:autotoolsprojectmanager baremetal
+	bazaar clang:clangcodemodel clearcase cmake:cmakeprojectmanager cvs git ios mercurial
+	perforce python:pythoneditor qbs:qbsprojectmanager qnx subversion valgrind winrt)
+IUSE="doc systemd test webkit ${QTC_PLUGINS[@]%:*}"
+
+# minimum Qt version required
+QT_PV="5.4.0:5"
+
+RDEPEND="
+	=dev-libs/botan-1.10*[threads]
+	>=dev-qt/designer-${QT_PV}
+	>=dev-qt/qtconcurrent-${QT_PV}
+	>=dev-qt/qtcore-${QT_PV}
+	>=dev-qt/qtdeclarative-${QT_PV}[widgets]
+	>=dev-qt/qtgui-${QT_PV}
+	>=dev-qt/qthelp-${QT_PV}
+	>=dev-qt/qtnetwork-${QT_PV}[ssl]
+	>=dev-qt/qtprintsupport-${QT_PV}
+	>=dev-qt/qtquickcontrols-${QT_PV}
+	>=dev-qt/qtscript-${QT_PV}
+	>=dev-qt/qtsql-${QT_PV}[sqlite]
+	>=dev-qt/qtsvg-${QT_PV}
+	>=dev-qt/qtwidgets-${QT_PV}
+	>=dev-qt/qtx11extras-${QT_PV}
+	>=dev-qt/qtxml-${QT_PV}
+	>=sys-devel/gdb-7.5[client,python]
+	clang? ( >=sys-devel/clang-3.2:= )
+	qbs? ( >=dev-util/qbs-1.4.2 )
+	systemd? ( sys-apps/systemd:= )
+	webkit? ( >=dev-qt/qtwebkit-${QT_PV} )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/linguist-tools-${QT_PV}
+	virtual/pkgconfig
+	doc? ( >=dev-qt/qdoc-${QT_PV} )
+	test? ( >=dev-qt/qttest-${QT_PV} )
+"
+for x in ${PLOCALES}; do
+	# qt translations must be installed for qt-creator translations to work
+	RDEPEND+=" linguas_${x}? ( >=dev-qt/qttranslations-${QT_PV} )"
+done
+unset x
+
+PDEPEND="
+	autotools? ( sys-devel/autoconf )
+	bazaar? ( dev-vcs/bzr )
+	cmake? ( dev-util/cmake )
+	cvs? ( dev-vcs/cvs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	subversion? ( dev-vcs/subversion )
+	valgrind? ( dev-util/valgrind )
+"
+
+src_unpack() {
+	if [[ $(gcc-major-version) -lt 4 ]] || [[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -lt 7 ]]; then
+		eerror "GCC version 4.7 or later is required to build Qt Creator"
+		die "GCC >= 4.7 required"
+	fi
+
+	default
+}
+
+src_prepare() {
+	# disable unwanted plugins
+	for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
+		if ! use ${plugin%:*}; then
+			einfo "Disabling ${plugin%:*} plugin"
+			sed -i -re "/(^\s+|SUBDIRS\s*\+=\s*)(${plugin#*:})\>/d" \
+				src/plugins/plugins.pro || die "failed to disable ${plugin%:*} plugin"
+		fi
+	done
+
+	# automagic dep on qtwebkit (bug 538236)
+	if ! use webkit; then
+		sed -i -e 's/isEmpty(QT\.webkitwidgets\.name)/true/' \
+			src/plugins/help/help.pro || die "failed to disable webkit"
+	fi
+
+	# disable broken or unreliable tests
+	sed -i -e '/lexer/d' tests/auto/cplusplus/cplusplus.pro || die
+	sed -i -e '/dumpers\.pro/d' tests/auto/debugger/debugger.pro || die
+	sed -i -e '/CONFIG -=/ s/$/ testcase/' tests/auto/extensionsystem/pluginmanager/correctplugins1/plugin?/plugin?.pro || die
+	sed -i -e '/parsertests\.pro/d' tests/auto/valgrind/memcheck/memcheck.pro || die
+
+	# fix translations
+	sed -i -e "/^LANGUAGES =/ s:=.*:= $(l10n_get_locales):" \
+		share/qtcreator/translations/translations.pro || die
+
+	# remove bundled qbs
+	rm -rf src/shared/qbs || die
+}
+
+src_configure() {
+	eqmake5 IDE_LIBRARY_BASENAME="$(get_libdir)" \
+		IDE_PACKAGE_MODE=1 \
+		LLVM_INSTALL_DIR="${EPREFIX}/usr" \
+		QBS_INSTALL_DIR="${EPREFIX}/usr" \
+		CONFIG+=qbs_disable_rpath \
+		CONFIG+=qbs_enable_project_file_updates \
+		$(use systemd && echo CONFIG+=journald) \
+		$(use test && echo BUILD_TESTS=1) \
+		USE_SYSTEM_BOTAN=1
+}
+
+src_test() {
+	cd tests/auto || die
+	VIRTUALX_COMMAND=default virtualmake
+}
+
+src_install() {
+	emake INSTALL_ROOT="${ED}usr" install
+
+	dodoc dist/{changes-*,known-issues}
+
+	# install documentation
+	if use doc; then
+		emake docs
+		# don't use ${PF} or the doc will not be found
+		insinto /usr/share/doc/qtcreator
+		doins share/doc/qtcreator/qtcreator{,-dev}.qch
+		docompress -x /usr/share/doc/qtcreator/qtcreator{,-dev}.qch
+	fi
+
+	# install desktop file
+	make_desktop_entry qtcreator 'Qt Creator' QtProject-qtcreator 'Qt;Development;IDE'
+}