[gentoo-commits] proj/gnome:master commit in: dev-libs/gobject-introspection/

["Ole Reifschneider" <tranquility@gentoo.org>]

commit:     22f5e879edfc814bf44b012c8eba22acda29896c
Author:     Ole Reifschneider <tranquility <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 13 22:01:10 2015 +0000
Commit:     Ole Reifschneider <tranquility <AT> gentoo <DOT> org>
CommitDate: Sun Sep 13 22:01:10 2015 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=22f5e879

dev-libs/gobject-introspection: Bump version to 1.45.4

Package-Manager: portage-2.2.20.1
Manifest-Sign-Key: 7E8B4D42

 .../gobject-introspection-1.45.4.ebuild            | 73 ++++++++++++++++++++++
 1 file changed, 73 insertions(+)

diff --git a/dev-libs/gobject-introspection/gobject-introspection-1.45.4.ebuild b/dev-libs/gobject-introspection/gobject-introspection-1.45.4.ebuild
new file mode 100644
index 0000000..59e395a
--- /dev/null
+++ b/dev-libs/gobject-introspection/gobject-introspection-1.45.4.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml"
+
+inherit gnome2 python-single-r1 toolchain-funcs versionator
+
+DESCRIPTION="Introspection infrastructure for generating gobject library bindings for various languages"
+HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+IUSE="cairo doctool test"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	test? ( cairo )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+# virtual/pkgconfig needed at runtime, bug #505408
+# We force glib and goi to be in sync by this way as explained in bug #518424
+RDEPEND="
+	>=dev-libs/gobject-introspection-common-${PV}
+	>=dev-libs/glib-2.$(get_version_component_range 2).3:2
+	doctool? ( dev-python/mako )
+	virtual/libffi:=
+	virtual/pkgconfig
+	!<dev-lang/vala-0.20.0
+	${PYTHON_DEPS}
+"
+# Wants real bison, not virtual/yacc
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.19
+	sys-devel/bison
+	sys-devel/flex
+"
+# PDEPEND to avoid circular dependencies, bug #391213
+PDEPEND="cairo? ( x11-libs/cairo[glib] )"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	if ! has_version "x11-libs/cairo[glib]"; then
+		# Bug #391213: enable cairo-gobject support even if it's not installed
+		# We only PDEPEND on cairo to avoid circular dependencies
+		export CAIRO_LIBS="-lcairo -lcairo-gobject"
+		export CAIRO_CFLAGS="-I${EPREFIX}/usr/include/cairo"
+	fi
+
+	# To prevent crosscompiling problems, bug #414105
+	gnome2_src_configure \
+		--disable-static \
+		CC="$(tc-getCC)" \
+		YACC="$(type -p yacc)" \
+		$(use_with cairo) \
+		$(use_enable doctool)
+}
+
+src_install() {
+	DOCS="AUTHORS CONTRIBUTORS ChangeLog NEWS README TODO"
+	gnome2_src_install
+
+	# Prevent collision with gobject-introspection-common
+	rm -v "${ED}"usr/share/aclocal/introspection.m4 \
+		"${ED}"usr/share/gobject-introspection-1.0/Makefile.introspection || die
+	rmdir "${ED}"usr/share/aclocal || die
+}