* [gentoo-commits] repo/gentoo:master commit in: app-emulation/libvirt/, dev-python/libvirt-python/
@ 2015-09-11 15:48 Doug Goldstein
0 siblings, 0 replies; 2+ messages in thread
From: Doug Goldstein @ 2015-09-11 15:48 UTC (permalink / raw
To: gentoo-commits
commit: e25e14deda05c2be8792dbea61f0cd80ab1cefdd
Author: Doug Goldstein <cardoe <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 11 15:48:02 2015 +0000
Commit: Doug Goldstein <cardoe <AT> gentoo <DOT> org>
CommitDate: Fri Sep 11 15:48:46 2015 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e25e14de
app-emulation/libvirt / dev-python/libvirt-python: re-add keywords
These packages were previously un-keyworded while we worked on them,
they are now re-keyworded.
Signed-off-by: Doug Goldstein <cardoe <AT> gentoo.org>
app-emulation/libvirt/libvirt-1.2.19.ebuild | 2 +-
dev-python/libvirt-python/libvirt-python-1.2.19.ebuild | 2 +-
2 files changed, 2 insertions(+), 2 deletions(-)
diff --git a/app-emulation/libvirt/libvirt-1.2.19.ebuild b/app-emulation/libvirt/libvirt-1.2.19.ebuild
index 07a054d..55fb80d 100644
--- a/app-emulation/libvirt/libvirt-1.2.19.ebuild
+++ b/app-emulation/libvirt/libvirt-1.2.19.ebuild
@@ -28,7 +28,7 @@ else
SRC_URI+=" ${BACKPORTS:+
https://dev.gentoo.org/~cardoe/distfiles/${P}-${BACKPORTS}.tar.xz
https://dev.gentoo.org/~tamiko/distfiles/${P}-${BACKPORTS}.tar.xz}"
- KEYWORDS="" # "~amd64 ~x86"
+ KEYWORDS="~amd64 ~x86"
SLOT="0/${PV}"
fi
S="${WORKDIR}/${P%_rc*}"
diff --git a/dev-python/libvirt-python/libvirt-python-1.2.19.ebuild b/dev-python/libvirt-python/libvirt-python-1.2.19.ebuild
index 9bfab7e..cc59d1b 100644
--- a/dev-python/libvirt-python/libvirt-python-1.2.19.ebuild
+++ b/dev-python/libvirt-python/libvirt-python-1.2.19.ebuild
@@ -20,7 +20,7 @@ if [[ ${PV} = *9999* ]]; then
RDEPEND="app-emulation/libvirt:=[-python(-)]"
else
SRC_URI="http://libvirt.org/sources/python/${MY_P}.tar.gz"
- KEYWORDS="" # "~amd64 ~x86"
+ KEYWORDS="~amd64 ~x86"
RDEPEND="app-emulation/libvirt:0/${PV}"
fi
S="${WORKDIR}/${P%_rc*}"
^ permalink raw reply related [flat|nested] 2+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: app-emulation/libvirt/, dev-python/libvirt-python/
@ 2020-10-02 17:05 Matthias Maier
0 siblings, 0 replies; 2+ messages in thread
From: Matthias Maier @ 2020-10-02 17:05 UTC (permalink / raw
To: gentoo-commits
commit: 6e783633710d2749ee0787dc1291708d3b1f1aa2
Author: Jonathan Davies <jpds <AT> protonmail <DOT> com>
AuthorDate: Fri Oct 2 10:51:31 2020 +0000
Commit: Matthias Maier <tamiko <AT> gentoo <DOT> org>
CommitDate: Fri Oct 2 16:39:01 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6e783633
libvirt: Version updated to 6.8.0.
Bug: https://bugs.gentoo.org/746119
Signed-off-by: Jonathan Davies <jpds <AT> protonmail.com>
Signed-off-by: Matthias Maier <tamiko <AT> gentoo.org>
app-emulation/libvirt/Manifest | 1 +
app-emulation/libvirt/libvirt-6.8.0.ebuild | 344 +++++++++++++++++++++
dev-python/libvirt-python/Manifest | 1 +
.../libvirt-python/libvirt-python-6.8.0.ebuild | 46 +++
4 files changed, 392 insertions(+)
diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index 8abb22472ab..d0484121929 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -1,3 +1,4 @@
DIST libvirt-6.2.0.tar.xz 8307248 BLAKE2B 9d449e041fc548a688f974d0801e625cf023ef0df49c40028e486e88fcf14181869e0dfd87f0eabcdd184df67dda5b5fbdc0c2375832f1534faff531779255dd SHA512 96bef701fd73aef93d1490f0bc331901a0ff6250a4f36a3e4844f76cc262dc0ae4cce8686a603c2a9c575ce489d8d5ed1521ebd22b92aff8301efdb74dee91e4
DIST libvirt-6.5.0.tar.xz 9407160 BLAKE2B 592aace555a3b72311cb430784587180fa7dbf74f75509cd8373a046339b9c4c0707bf530dd2d06146d78a85f8af3dba5d0b146ecec180d3cc4d3bf78c19da61 SHA512 30a032270304b97945ff2c5087c72c2f5510634186f2eaf7c3d834a72cddcaec97bbe5ccc86802728a59f4c80b5bb54757400683df5f20175757cfe07ce67453
DIST libvirt-6.7.0.tar.xz 8362140 BLAKE2B d0afe33fcdaab3cc0f2ea8c552e7550bcece018b049a3b58e5c05ee85b39e2b3ebf42fa1b70ddb1d2a541d1114b6b49734f23a889b3589397a30a672f27a3a56 SHA512 cabfb6aa65a3a1412b0111654ad3a7d0a6dfc63399a892c540ca39ab4e56f87626a067037e4480bb55418a371d2b5e9ac74862c92a3cdea69822ec3d158d769f
+DIST libvirt-6.8.0.tar.xz 8412092 BLAKE2B c118ca6b263054bb6941c62f3d1415f7ed1a3f29a35294272d04bc726643247ee5691e0310a1bf013faeba856d7aadd00a90fe8dbdca6ff4c7eb480e94d92fa2 SHA512 9b69f3dcceb5e40470a78908654faf51b643f6793e556f3115daa4bfe08743af290882dd51f15eb27c38d589eb210d495de7c44a40b363420ab4f4d3a6393cc9
diff --git a/app-emulation/libvirt/libvirt-6.8.0.ebuild b/app-emulation/libvirt/libvirt-6.8.0.ebuild
new file mode 100644
index 00000000000..0ac6ec64feb
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-6.8.0.ebuild
@@ -0,0 +1,344 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit meson bash-completion-r1 eutils linux-info python-any-r1 readme.gentoo-r1 systemd
+
+if [[ ${PV} = *9999* ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt.git"
+ SRC_URI=""
+ SLOT="0"
+else
+ SRC_URI="https://libvirt.org/sources/${P}.tar.xz"
+ KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+ SLOT="0/${PV}"
+fi
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="https://www.libvirt.org/"
+LICENSE="LGPL-2.1"
+IUSE="
+ apparmor audit +caps +dbus dtrace firewalld fuse glusterfs iscsi
+ iscsi-direct +libvirtd lvm libssh lxc +macvtap nfs nls numa openvz
+ parted pcap policykit +qemu rbd sasl selinux +udev +vepa
+ virtualbox virt-network wireshark-plugins xen zfs
+"
+
+REQUIRED_USE="
+ firewalld? ( virt-network )
+ libvirtd? ( || ( lxc openvz qemu virtualbox xen ) )
+ lxc? ( caps libvirtd )
+ openvz? ( libvirtd )
+ policykit? ( dbus )
+ qemu? ( libvirtd )
+ vepa? ( macvtap )
+ virt-network? ( libvirtd )
+ virtualbox? ( libvirtd )
+ xen? ( libvirtd )"
+
+BDEPEND="
+ acct-user/qemu
+ policykit? ( acct-group/libvirt )
+ app-text/xhtml1
+ dev-lang/perl
+ dev-libs/libxslt
+ dev-perl/XML-XPath
+ dev-python/docutils
+ virtual/pkgconfig"
+
+# gettext.sh command is used by the libvirt command wrappers, and it's
+# non-optional, so put it into RDEPEND.
+# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
+# package will use 3 by default. Since we don't have slot pinning in an API,
+# we must go with the most recent
+RDEPEND="
+ app-misc/scrub
+ >=dev-libs/glib-2.48.0
+ dev-libs/libgcrypt:0
+ dev-libs/libnl:3
+ >=dev-libs/libxml2-2.7.6
+ >=net-analyzer/openbsd-netcat-1.105-r1
+ >=net-libs/gnutls-1.0.25:0=
+ net-libs/libssh2
+ net-libs/libtirpc
+ net-libs/rpcsvc-proto
+ >=net-misc/curl-7.18.0
+ sys-apps/dmidecode
+ sys-devel/gettext
+ sys-libs/ncurses:0=
+ sys-libs/readline:=
+ apparmor? ( sys-libs/libapparmor )
+ audit? ( sys-process/audit )
+ caps? ( sys-libs/libcap-ng )
+ dbus? ( sys-apps/dbus )
+ dtrace? ( dev-util/systemtap )
+ firewalld? ( >=net-firewall/firewalld-0.6.3 )
+ fuse? ( sys-fs/fuse:0= )
+ glusterfs? ( >=sys-cluster/glusterfs-3.4.1 )
+ iscsi? ( sys-block/open-iscsi )
+ iscsi-direct? ( >=net-libs/libiscsi-1.18.0 )
+ libssh? ( net-libs/libssh )
+ lvm? ( >=sys-fs/lvm2-2.02.48-r2[-device-mapper-only(-)] )
+ nfs? ( net-fs/nfs-utils )
+ numa? (
+ >sys-process/numactl-2.0.2
+ sys-process/numad
+ )
+ parted? (
+ >=sys-block/parted-1.8[device-mapper]
+ sys-fs/lvm2[-device-mapper-only(-)]
+ )
+ pcap? ( >=net-libs/libpcap-1.0.0 )
+ policykit? ( >=sys-auth/polkit-0.9 )
+ qemu? (
+ >=app-emulation/qemu-1.5.0
+ dev-libs/yajl
+ )
+ rbd? ( sys-cluster/ceph )
+ sasl? ( dev-libs/cyrus-sasl )
+ selinux? ( >=sys-libs/libselinux-2.0.85 )
+ virt-network? (
+ net-dns/dnsmasq[script]
+ net-firewall/ebtables
+ >=net-firewall/iptables-1.4.10[ipv6]
+ net-misc/radvd
+ sys-apps/iproute2[-minimal]
+ )
+ wireshark-plugins? ( net-analyzer/wireshark:= )
+ xen? (
+ >=app-emulation/xen-4.6.0
+ app-emulation/xen-tools:=
+ )
+ udev? (
+ virtual/libudev
+ >=x11-libs/libpciaccess-0.10.9
+ )
+ zfs? ( sys-fs/zfs )"
+
+DEPEND="${BDEPEND}
+ ${RDEPEND}
+ ${PYTHON_DEPS}"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-6.0.0-fix_paths_in_libvirt-guests_sh.patch
+ "${FILESDIR}"/${PN}-6.7.0-do-not-use-sysconfig.patch
+ "${FILESDIR}"/${PN}-6.7.0-doc-path.patch
+ "${FILESDIR}"/${PN}-6.7.0-fix-paths-for-apparmor.patch
+)
+
+pkg_setup() {
+ # Check kernel configuration:
+ CONFIG_CHECK=""
+ use fuse && CONFIG_CHECK+="
+ ~FUSE_FS"
+
+ use lvm && CONFIG_CHECK+="
+ ~BLK_DEV_DM
+ ~DM_MULTIPATH
+ ~DM_SNAPSHOT"
+
+ use lxc && CONFIG_CHECK+="
+ ~BLK_CGROUP
+ ~CGROUP_CPUACCT
+ ~CGROUP_DEVICE
+ ~CGROUP_FREEZER
+ ~CGROUP_NET_PRIO
+ ~CGROUP_PERF
+ ~CGROUPS
+ ~CGROUP_SCHED
+ ~CPUSETS
+ ~IPC_NS
+ ~MACVLAN
+ ~NAMESPACES
+ ~NET_CLS_CGROUP
+ ~NET_NS
+ ~PID_NS
+ ~POSIX_MQUEUE
+ ~SECURITYFS
+ ~USER_NS
+ ~UTS_NS
+ ~VETH
+ ~!GRKERNSEC_CHROOT_MOUNT
+ ~!GRKERNSEC_CHROOT_DOUBLE
+ ~!GRKERNSEC_CHROOT_PIVOT
+ ~!GRKERNSEC_CHROOT_CHMOD
+ ~!GRKERNSEC_CHROOT_CAPS"
+
+ kernel_is lt 4 7 && use lxc && CONFIG_CHECK+="
+ ~DEVPTS_MULTIPLE_INSTANCES"
+
+ use macvtap && CONFIG_CHECK+="
+ ~MACVTAP"
+
+ use virt-network && CONFIG_CHECK+="
+ ~BRIDGE_EBT_MARK_T
+ ~BRIDGE_NF_EBTABLES
+ ~NETFILTER_ADVANCED
+ ~NETFILTER_XT_CONNMARK
+ ~NETFILTER_XT_MARK
+ ~NETFILTER_XT_TARGET_CHECKSUM
+ ~IP_NF_FILTER
+ ~IP_NF_MANGLE
+ ~IP_NF_NAT
+ ~IP_NF_TARGET_MASQUERADE
+ ~IP6_NF_FILTER
+ ~IP6_NF_MANGLE
+ ~IP6_NF_NAT"
+ # Bandwidth Limiting Support
+ use virt-network && CONFIG_CHECK+="
+ ~BRIDGE_EBT_T_NAT
+ ~IP_NF_TARGET_REJECT
+ ~NET_ACT_POLICE
+ ~NET_CLS_FW
+ ~NET_CLS_U32
+ ~NET_SCH_HTB
+ ~NET_SCH_INGRESS
+ ~NET_SCH_SFQ"
+
+ # Handle specific kernel versions for different features
+ kernel_is lt 3 6 && CONFIG_CHECK+=" ~CGROUP_MEM_RES_CTLR"
+ if kernel_is ge 3 6; then
+ CONFIG_CHECK+=" ~MEMCG ~MEMCG_SWAP "
+ kernel_is lt 4 5 && CONFIG_CHECK+=" ~MEMCG_KMEM "
+ fi
+
+ ERROR_USER_NS="Optional depending on LXC configuration."
+
+ if [[ -n ${CONFIG_CHECK} ]]; then
+ linux-info_pkg_setup
+ fi
+}
+
+src_prepare() {
+ touch "${S}/.mailmap" || die
+
+ default
+
+ # Tweak the init script:
+ cp "${FILESDIR}/libvirtd.init-r19" "${S}/libvirtd.init" || die
+ sed -e "s/USE_FLAG_FIREWALLD/$(usex firewalld 'need firewalld' '')/" \
+ -i "${S}/libvirtd.init" || die "sed failed"
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_feature apparmor)
+ $(meson_use apparmor apparmor_profiles)
+ $(meson_feature audit)
+ $(meson_feature caps capng)
+ $(meson_feature dbus)
+ $(meson_feature dtrace)
+ $(meson_feature firewalld)
+ $(meson_feature fuse)
+ $(meson_feature glusterfs)
+ $(meson_feature glusterfs storage_gluster)
+ $(meson_feature iscsi storage_iscsi)
+ $(meson_feature iscsi-direct storage_iscsi_direct)
+ $(meson_feature libvirtd driver_libvirtd)
+ $(meson_feature libssh)
+ $(meson_feature lvm storage_lvm)
+ $(meson_feature lvm storage_mpath)
+ $(meson_feature lxc driver_lxc)
+ $(meson_feature macvtap)
+ $(meson_feature nls)
+ $(meson_feature numa numactl)
+ $(meson_feature numa numad)
+ $(meson_feature openvz driver_openvz)
+ $(meson_feature parted storage_disk)
+ $(meson_feature pcap libpcap)
+ $(meson_feature policykit polkit)
+ $(meson_feature qemu driver_qemu)
+ $(meson_feature qemu yajl)
+ $(meson_feature rbd storage_rbd)
+ $(meson_feature sasl)
+ $(meson_feature selinux)
+ $(meson_feature udev)
+ $(meson_feature vepa virtualport)
+ $(meson_feature virt-network driver_network)
+ $(meson_feature virtualbox driver_vbox)
+ $(meson_feature wireshark-plugins wireshark_dissector)
+ $(meson_feature xen driver_libxl)
+ $(meson_feature zfs storage_zfs)
+
+ -Dhal=disabled
+ -Dnetcf=disabled
+ -Dsanlock=disabled
+
+ -Ddriver_esx=enabled
+ -Dinit_script=systemd
+ -Dqemu_user=$(usex caps qemu root)
+ -Dqemu_group=$(usex caps qemu root)
+ -Ddriver_remote=enabled
+ -Dstorage_fs=enabled
+ -Ddriver_vmware=enabled
+
+ --localstatedir="${EPREFIX}/var"
+ -Drunstatedir="${EPREFIX}/run"
+ )
+
+ meson_src_configure
+}
+
+src_test() {
+ # remove problematic tests, bug #591416, bug #591418
+ sed -i -e 's#commandtest$(EXEEXT) # #' \
+ -e 's#virfirewalltest$(EXEEXT) # #' \
+ -e 's#nwfilterebiptablestest$(EXEEXT) # #' \
+ -e 's#nwfilterxml2firewalltest$(EXEEXT)$##' \
+ tests/Makefile
+
+ export VIR_TEST_DEBUG=1
+ meson_src_test
+}
+
+src_install() {
+ meson_src_install
+
+ # Remove bogus, empty directories. They are either not used, or
+ # libvirtd is able to create them on demand
+ rm -rf "${D}"/etc/sysconfig || die
+ rm -rf "${D}"/var || die
+ rm -rf "${D}"/run || die
+
+ newbashcomp "${S}/tools/bash-completion/vsh" virsh
+ bashcomp_alias virsh virt-admin
+
+ use libvirtd || return 0
+ # From here, only libvirtd-related instructions, be warned!
+
+ systemd_newtmpfilesd "${FILESDIR}"/libvirtd.tmpfiles.conf libvirtd.conf
+
+ newinitd "${S}/libvirtd.init" libvirtd
+ newinitd "${FILESDIR}/libvirt-guests.init-r4" libvirt-guests
+ newinitd "${FILESDIR}/virtlockd.init-r2" virtlockd
+ newinitd "${FILESDIR}/virtlogd.init-r2" virtlogd
+
+ newconfd "${FILESDIR}/libvirtd.confd-r5" libvirtd
+ newconfd "${FILESDIR}/libvirt-guests.confd" libvirt-guests
+
+ DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r3")
+ DISABLE_AUTOFORMATTING=true
+ readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+ # we only ever want to generate this once
+ if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+ rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml || die
+ fi
+}
+
+pkg_postinst() {
+ if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+ touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml || die
+ fi
+
+ use libvirtd || return 0
+ # From here, only libvirtd-related instructions, be warned!
+
+ readme.gentoo_print_elog
+}
diff --git a/dev-python/libvirt-python/Manifest b/dev-python/libvirt-python/Manifest
index 84a153a4715..a5ae81b192f 100644
--- a/dev-python/libvirt-python/Manifest
+++ b/dev-python/libvirt-python/Manifest
@@ -1,3 +1,4 @@
DIST libvirt-python-6.2.0.tar.gz 196971 BLAKE2B e11c82bd98c62072c14992c485339337bcc3639bbd56154185834c145f76984ced9f09f7f05c302609ce6629a8d13db77debd6f3d85e8fdb00c818bbe51cc552 SHA512 91f6940f60670221c914ee7ffc8d89a74222bcacbbf1afd5f679479f1e1bcec563f297a8e8359d6f51a1eee29162e39e2a276f5277fcec551d50f112e304a947
DIST libvirt-python-6.5.0.tar.gz 198753 BLAKE2B 90951af538c664f5da20cfced6b81dc2b06d36e723b3c41a0b2763bf0d73d3036d7e84a2db57f20fa2bd1ede8fb01c45dad9e5097a9f6008579dae319f825898 SHA512 a69c75b615f674bbb89fdb3e5cfc3dddfde68adffd0599e9d03f1552bb765823dc003859fe713ac0a324835c61f909bd43518571ddde8f99c37bee2416f094eb
DIST libvirt-python-6.7.0.tar.gz 208597 BLAKE2B 335bd89133b688586a55193635b4b75dabe6dd4a741a450e49067ac8a9b9d9da54787b50c23bc6d5322a7fecbe513422f02450e09d541cb112ccfd499ce18101 SHA512 7d5a7f87abc01285c2030c9408838d4e1496d0d0316b9ab775749e49719fa66c20114aad2bd281d6783e2cb4d47ceac5ac60ac584e881288d0b0d9cc76d5b2cb
+DIST libvirt-python-6.8.0.tar.gz 210034 BLAKE2B 667c2713bf9c0936f444c5b621f5af4e5273deda31496bc01c8834286a0ec0eb1c056006549cc5d129ef597264f8582acee62db3a2fd375daa4ebbceacb8fcc1 SHA512 6d2f82fafd414047cff16f0ad655fefd69c8c0da04be07d27da44e3ab17dd03e4e4ff102be1c30948c361268f57ea312978f9198fd128bfb54a3c1a07150e6af
diff --git a/dev-python/libvirt-python/libvirt-python-6.8.0.ebuild b/dev-python/libvirt-python/libvirt-python-6.8.0.ebuild
new file mode 100644
index 00000000000..234224f5717
--- /dev/null
+++ b/dev-python/libvirt-python/libvirt-python-6.8.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+DISTUTILS_USE_SETUPTOOLS=no
+
+MY_P="${P/_rc/-rc}"
+
+inherit distutils-r1
+
+if [[ ${PV} = *9999* ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://libvirt.org/git/libvirt-python.git"
+ RDEPEND="app-emulation/libvirt:=[-python(-)]"
+else
+ SRC_URI="https://libvirt.org/sources/python/${MY_P}.tar.gz"
+ KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+ RDEPEND="app-emulation/libvirt:0/${PV}"
+fi
+S="${WORKDIR}/${P%_rc*}"
+
+DESCRIPTION="libvirt Python bindings"
+HOMEPAGE="https://www.libvirt.org"
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="virtual/pkgconfig"
+BDEPEND="test? (
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/nose[${PYTHON_USEDEP}]
+)"
+
+distutils_enable_tests setup.py
+
+python_install_all() {
+ if use examples; then
+ dodoc -r examples
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+ distutils-r1_python_install_all
+}
^ permalink raw reply related [flat|nested] 2+ messages in thread
end of thread, other threads:[~2020-10-02 17:05 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-09-11 15:48 [gentoo-commits] repo/gentoo:master commit in: app-emulation/libvirt/, dev-python/libvirt-python/ Doug Goldstein
-- strict thread matches above, loose matches on Subject: below --
2020-10-02 17:05 Matthias Maier
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox