[gentoo-commits] repo/gentoo:master commit in: app-office/gnucash/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     3aef3ab9f9b68fab307c2bdb9e1f1104a7b2628e
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sat Sep  5 17:40:18 2015 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Sep  5 17:46:14 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3aef3ab9

app-office/gnucash: Version bump

Package-Manager: portage-2.2.20.1

 app-office/gnucash/Manifest             |   1 +
 app-office/gnucash/gnucash-2.6.7.ebuild | 120 ++++++++++++++++++++++++++++++++
 2 files changed, 121 insertions(+)

diff --git a/app-office/gnucash/Manifest b/app-office/gnucash/Manifest
index 3112de3..7d09c82 100644
--- a/app-office/gnucash/Manifest
+++ b/app-office/gnucash/Manifest
@@ -1,2 +1,3 @@
 DIST gnucash-2.6.5.tar.bz2 12997511 SHA256 b1b1a943a322e7bf7afb0c2202f491560d4734a2036438bf9820378c34203d65 SHA512 f45daa5a894f8cbe9ea552ccb354b08a4967f0a0f14595b871169a2a48495664a06e0f3dd81b6148b261418b67b76ae4e0ee3e72ec52ff3016c7f15523862538 WHIRLPOOL 38bdd5afec3337f929e4694dea072675baab86a68b730c0fc96c07c7287b0765140514ffd2c241784d857e7eba3d7bdbbf2b3c17f99d881d58095d68282b5d47
 DIST gnucash-2.6.6.tar.bz2 13303707 SHA256 2337c791511ec35ca1ab207bac5f80dd5764df6029adf46a15154df370c97180 SHA512 bfb6f0e444463bd69f7e31f1dc8ff0ea9ba1c103c5d7d0a7a985c765ca17680c9d821bfe39474e2c9d71b655aeba78c1ec6f97f7a8ce8731cfdc335b683e830f WHIRLPOOL 2d917c0ab2f6756ed5205826b881467366b92d7cd1365b4d2531a8432e71fec46f5323fcb017647317cd7788e044fa4601f5179cfef4d65ed86e247eb126cd35
+DIST gnucash-2.6.7.tar.bz2 13529748 SHA256 6c15b12eeddc095d6926d9ea84d885c20b8f52781602c15aa3f672a1f7e2beef SHA512 a5711d5d6b89e9c44a28b9733dd185ed9afbe8d2c719675ced9d3e56ecdb03b62313faa5fee42cff70869baf4a3c29d4f69abc54967e46c3aa7ad766fc5a489d WHIRLPOOL b6aff7d48557a4619bfe27c2088ede6c3d2e6820947f457d2db42bc763d5dc24011afd28eb94e66f7a6f5405f2e44f03ae8a43e2fe7679502ea38ad2bee0e36a

diff --git a/app-office/gnucash/gnucash-2.6.7.ebuild b/app-office/gnucash/gnucash-2.6.7.ebuild
new file mode 100644
index 0000000..b951b2d
--- /dev/null
+++ b/app-office/gnucash/gnucash-2.6.7.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools eutils gnome2 python-single-r1
+
+DESCRIPTION="A personal finance manager"
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="chipcard debug +doc gnome-keyring hbci mysql ofx postgres python quotes sqlite"
+
+# FIXME: rdepend on dev-libs/qof when upstream fix their mess (see configure.ac)
+# libdbi version requirement for sqlite taken from bug #455134
+RDEPEND="
+	>=dev-libs/glib-2.32.0:2
+	>=dev-libs/popt-1.5
+	>=dev-libs/libxml2-2.5.10:2
+	dev-libs/libxslt
+	>=dev-scheme/guile-1.8.3:12[deprecated,regex]
+	dev-scheme/guile-www
+	gnome-base/libgnomecanvas
+	>=net-libs/webkit-gtk-1.2:2
+	>=sys-libs/zlib-1.1.4
+	>=x11-libs/gtk+-2.24:2
+	>=x11-libs/goffice-0.7.0:0.8[gnome]
+	x11-libs/pango
+	gnome-keyring? ( >=app-crypt/libsecret-0.18 )
+	ofx? ( >=dev-libs/libofx-0.9.1 )
+	hbci? ( >=net-libs/aqbanking-5[gtk,ofx?]
+		sys-libs/gwenhywfar[gtk]
+		chipcard? ( sys-libs/libchipcard )
+	)
+	python? ( ${PYTHON_DEPS} )
+	quotes? ( dev-perl/DateManip
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/HTML-TableExtract )
+	sqlite? ( >=dev-db/libdbi-0.9.0
+		>=dev-db/libdbi-drivers-0.9.0[sqlite] )
+	postgres? ( dev-db/libdbi dev-db/libdbi-drivers[postgres] )
+	mysql? ( dev-db/libdbi dev-db/libdbi-drivers[mysql] )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	dev-util/intltool
+	gnome-base/gnome-common
+	sys-devel/libtool
+"
+PDEPEND="doc? ( >=app-doc/gnucash-docs-2.2.0 )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Skip test that needs some locales to be present
+	sed -i -e '/test_suite_gnc_date/d' src/libqof/qof/test/test-qof.c || die
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf
+
+	DOCS="doc/README.OFX doc/README.HBCI"
+
+	if use sqlite || use mysql || use postgres ; then
+		myconf+=" --enable-dbi"
+	else
+		myconf+=" --disable-dbi"
+	fi
+
+	# guile wrongly exports LDFLAGS as LIBS which breaks modules
+	# Filter until a better ebuild is available, bug #202205
+	local GUILE_LIBS=""
+	local lib
+	for lib in $(guile-config link); do
+		if [ "${lib#-Wl}" = "$lib" ]; then
+			GUILE_LIBS="$GUILE_LIBS $lib"
+		fi
+	done
+
+	# gtkmm is experimental and shouldn't be enabled, upstream bug #684166
+	gnome2_src_configure \
+		$(use_enable debug) \
+		$(use_enable gnome-keyring password-storage) \
+		$(use_enable ofx) \
+		$(use_enable hbci aqbanking) \
+		$(use_enable python) \
+		--disable-doxygen \
+		--disable-gtkmm \
+		--enable-locale-specific-tax \
+		--disable-error-on-warning \
+		 GUILE_LIBS="${GUILE_LIBS}" ${myconf}
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	GUILE_WARN_DEPRECATED=no \
+	GNC_DOT_DIR="${T}"/.gnucash \
+	emake check
+}
+
+src_install() {
+	# Parallel installation fails from time to time, bug #359123
+	MAKEOPTS="${MAKEOPTS} -j1" gnome2_src_install GNC_DOC_INSTALL_DIR=/usr/share/doc/${PF}
+
+	rm -rf "${ED}"/usr/share/doc/${PF}/{examples/,COPYING,INSTALL,*win32-bin.txt,projects.html}
+	mv "${ED}"/usr/share/doc/${PF} "${T}"/cantuseprepalldocs || die
+	dodoc "${T}"/cantuseprepalldocs/*
+}