[gentoo-commits] repo/gentoo:master commit in: media-sound/qmmp/

["Markos Chandras" <hwoarang@gentoo.org>]

commit:     f90b4f178f6e18306e96b17a3186b0c685ce8bc1
Author:     Markos Chandras <hwoarang <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 27 17:21:53 2015 +0000
Commit:     Markos Chandras <hwoarang <AT> gentoo <DOT> org>
CommitDate: Thu Aug 27 17:25:18 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f90b4f17

media-sound/qmmp: Version bump. Fixes bug #557536

Package-Manager: portage-2.2.20.1

 media-sound/qmmp/Manifest          |   1 +
 media-sound/qmmp/qmmp-0.8.8.ebuild | 122 +++++++++++++++++++++++++++++++++++++
 2 files changed, 123 insertions(+)

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index 361985c..3a3b156 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,3 +1,4 @@
 DIST qmmp-0.8.3.tar.bz2 991403 SHA256 9e73518adf011e60e36c18d55d05845f8103b4af61351e26edb6c105390dd949 SHA512 62e9e1671fa75103b3a77761b64b02ae9284e5b6512957cd83037fe90b3b02453d0d556ac64885d39acb1e79e676a5ba3a940c1af6e4e215db20fd95cefd57d0 WHIRLPOOL 0d42ab65c17c1fe10db46111c56375220a07204270045987ec8f1f0770ec9fb79a66f39301b6f57e43338dc9518837ddf377147cb17f55faa2a0063ccdd5d928
 DIST qmmp-0.8.4.tar.bz2 990768 SHA256 aef9f7685b5b5d79949bf501ac5420883ad2bceeeb6f57f9a7632a7f7d4fa6d1 SHA512 02af2f3d8a1f4f0b04613af21779e24509d696bb19de8f1a3173de124764ba950af6be00700271c0f14344a21bb69fdf9a350ddd179c9d48ab9acafcf3459608 WHIRLPOOL cd1b655a378275fc91a6ee15560b1ffa65a6c0f15238433a51207c35f540e0db82589686fb51b01ba0d48f57b2088a800cd8b69aba21266cb770d7d5b877f7ac
 DIST qmmp-0.8.5.tar.bz2 991464 SHA256 7fe9347ad6c66e8013b73f2c5cf628037c58151e0cfcb926a8f27b93ad2d7c0d SHA512 07659ea7421079da77f6caa77c1e5f007664b1732a8bae160c154e3a687f330e476d5b2fec2e1b79da512ca1b68fdf6d462975821ced76f4f4c87799e6d79c39 WHIRLPOOL a46264d2886953f924fae40bd43cd5e23a59592ae8456a6120f6e41cd2d9572fa94a8c68f212dabfa97b8534f723ab9c91f26a0d98e0b6109266802ecb18d7f4
+DIST qmmp-0.8.8.tar.bz2 993992 SHA256 23e422ef43e216f2d71f7d323d8345df2f3b6f46647e0ac0e03d4d69fbf62e57 SHA512 7882bfbc13ace5cca670a51b5f890b431163c4c0712222c16018b84080d7b42bed1f4cbe327ff767ececbf984193af7b0601be083ac1f0da1681d83e31f188de WHIRLPOOL 68f0a1f71dfe058226e4a4230c68fb48ac04935e16e326380ff3f0c6658c73921831ec5ced29073d3ce06de15cd7168cd7c6c7749db25ded6a092032b6bae025

diff --git a/media-sound/qmmp/qmmp-0.8.8.ebuild b/media-sound/qmmp/qmmp-0.8.8.ebuild
new file mode 100644
index 0000000..32aa727
--- /dev/null
+++ b/media-sound/qmmp/qmmp-0.8.8.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit cmake-utils
+[ "$PV" == "9999" ] && inherit subversion
+
+DESCRIPTION="Qt4-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~x86"
+else
+	SRC_URI=""
+	ESVN_REPO_URI="https://qmmp.googlecode.com/svn/trunk/qmmp/"
+	KEYWORDS=""
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa +dbus bs2b cdda cover crossfade enca ffmpeg flac jack game kde ladspa
+libsamplerate lyrics +mad midi mms modplug mplayer mpris musepack notifier opus oss
+projectm pulseaudio scrobbler sndfile stereo tray udisks +vorbis wavpack"
+
+RDEPEND="media-libs/taglib
+	dev-qt/qtgui:4
+	alsa? ( media-libs/alsa-lib )
+	bs2b? ( media-libs/libbs2b )
+	cdda? ( dev-libs/libcdio-paranoia )
+	dbus? ( sys-apps/dbus )
+	aac? ( media-libs/faad2 )
+	enca? ( app-i18n/enca )
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	ladspa? ( media-libs/ladspa-cmt )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	mplayer? ( || ( media-video/mplayer
+		media-video/mplayer2 )
+	)
+	mpris? ( dev-qt/qtdbus:4 )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	vorbis? ( media-libs/libvorbis
+		media-libs/libogg )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsamplerate )
+	ffmpeg? ( virtual/ffmpeg )
+	opus? ( media-libs/opusfile )
+	projectm? ( media-libs/libprojectm
+		dev-qt/qtopengl:4 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	wavpack? ( media-sound/wavpack )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )
+	udisks? ( sys-fs/udisks:2 )"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS ChangeLog README"
+
+CMAKE_IN_SOURCE_BUILD="1"
+
+REQUIRED_USE="kde? ( dbus ) "
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_use alsa)
+		$(cmake-utils_use_use aac)
+		$(cmake-utils_use_use bs2b)
+		$(cmake-utils_use_use cover)
+		$(cmake-utils_use_use cdda CDA)
+		$(cmake-utils_use_use crossfade)
+		$(cmake-utils_use_use dbus)
+		$(cmake-utils_use_use enca)
+		$(cmake-utils_use_use ffmpeg)
+		-DUSE_FFMPEG_LEGACY=OFF
+		$(cmake-utils_use_use flac)
+		$(cmake-utils_use_use game GME)
+		-DUSE_HAL=OFF
+		$(cmake-utils_use_use jack)
+		$(cmake-utils_use_use kde KDENOTIFY)
+		$(cmake-utils_use_use ladspa)
+		$(cmake-utils_use_use lyrics)
+		$(cmake-utils_use_use mad)
+		$(cmake-utils_use_use midi MIDI_WILDMIDI)
+		$(cmake-utils_use_use mplayer)
+		$(cmake-utils_use_use mms)
+		$(cmake-utils_use_use modplug)
+		$(cmake-utils_use_use mpris)
+		$(cmake-utils_use_use musepack MPC)
+		$(cmake-utils_use_use notifier)
+		$(cmake-utils_use_use opus)
+		$(cmake-utils_use_use oss)
+		$(cmake-utils_use_use projectm)
+		$(cmake-utils_use_use pulseaudio PULSE)
+		$(cmake-utils_use_use scrobbler)
+		$(cmake-utils_use_use sndfile)
+		$(cmake-utils_use_use stereo)
+		$(cmake-utils_use_use tray STATICON)
+		$(cmake-utils_use_use udisks UDISKS2)
+		$(cmake-utils_use_use libsamplerate SRC)
+		$(cmake-utils_use_use vorbis)
+		$(cmake-utils_use_use wavpack)
+		)
+
+	cmake-utils_src_configure
+}