[gentoo-commits] repo/gentoo:master commit in: media-libs/mlt/files/, media-libs/mlt/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     d889cb0f7a1dbda62e132c2eba19215f4209d8d9
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 19 14:18:48 2015 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Wed Aug 19 14:19:20 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d889cb0f

media-libs/mlt: version bump

Gentoo-bug: 517640

Package-Manager: portage-2.2.20.1

 media-libs/mlt/Manifest                        |   1 +
 media-libs/mlt/files/mlt-0.9.8-ruby-link.patch |  20 +++
 media-libs/mlt/mlt-0.9.8.ebuild                | 192 +++++++++++++++++++++++++
 3 files changed, 213 insertions(+)

diff --git a/media-libs/mlt/Manifest b/media-libs/mlt/Manifest
index 09ba865..405dcd6 100644
--- a/media-libs/mlt/Manifest
+++ b/media-libs/mlt/Manifest
@@ -1,3 +1,4 @@
 DIST mlt-0.8.2.tar.gz 1161293 SHA256 36c743d2abc68ce737ac526507fc2caf71b3d6a53a2bf31d22e8193a8b899577 SHA512 ab71018e5a188b95d91b4aceeb4ca0dfc59d0dd981ec3e4fa220b91ce812e2c98ebad1d51998005c6bc98999c7478444c8bfd398d61bd2084ff732a1638ca6aa WHIRLPOOL 4d72efbffd2f7c77041065c948c18ccbb4a65eb7f4ec7209ccde15e142fee84c70324390bc921c0302c30ad7673336c8cf00be8c710154fe31c8a3063987622b
 DIST mlt-0.8.8.tar.gz 1108652 SHA256 cc0e1cdb97a1cd59811a74553b5d3fbff590eb859c475253e188de1069ff9654 SHA512 d29d982632dec14e4397db602688816e06f095b1831514a816bc7640d574a04d3d56cc16240ea0a01229887e95c80891b87c5df981063cb2d6a14b50ff67589f WHIRLPOOL 6e5665e5b4c9471d252faea7073cfd21580e31b55941ba51a415783d79bec3d857fcd01f111da25e24551a3f03a728390e17ab9b127e1bd0977bac94c83162a5
 DIST mlt-0.9.0.tar.gz 1167943 SHA256 f20c6a9c9acaed3da84c601bf9293b2d148168386e5be2bc55651a75f95c1cc9 SHA512 631ab41ee6e3673c712f784b9c02b567a5e3b982d49eabe032ef20e89be9424cf9ce6d97fe6906f03b0ac082544316ba8524ae041d017aeac009ab9b98d457d9 WHIRLPOOL b39e78837f2f2785721315ac174d106e33bafd2dd55b8883b254a39dc98f664be29ce3e84413d2ba55f881bb42ca10c36a9117de00b1a5efc3dff8577a6a29af
+DIST mlt-0.9.8.tar.gz 1263364 SHA256 1214d6ad7fd1c3d36f0b1e64fd1c8d8a7ab6290e8452396003e79d58c0d21074 SHA512 2f3db19cbff8bdd11c53fe835fcc1c32d775ead061b2e225466376be98c622cdd18e67f66becda503a57725ac9a296bc48aae4c3ae1111ed09ba878f61fd1e10 WHIRLPOOL 615323613eeee9ea80f8d6727a05129a9dc32097a8c2bf41cb818843fa8d47885744c1534fd7d26817262f60404e4caa12ea67ae9b3f59984874981865ee9148

diff --git a/media-libs/mlt/files/mlt-0.9.8-ruby-link.patch b/media-libs/mlt/files/mlt-0.9.8-ruby-link.patch
new file mode 100755
index 0000000..3dd319a
--- /dev/null
+++ b/media-libs/mlt/files/mlt-0.9.8-ruby-link.patch
@@ -0,0 +1,20 @@
+The build system tries to link to installed system libraries first, which
+fails because the ABI has changed...
+
+--- swig/ruby/build
++++ swig/ruby/build
+@@ -0,0 +1,14 @@
++#!/usr/bin/env ruby
++require 'mkmf'
++if ARGV.shift == 'clean'
++  system( "rm -f *.cxx *.so *.o mlt.i ../.ruby Makefile" )
++  exit 0
++end
++system( "ln -sf ../mlt.i" )
++system( "ln -sf ../../framework/libmlt.so" )
++system( "ln -sf ../../mlt++/libmlt++.so" )
++system( "swig -c++ -ruby -I../../mlt++ -I../.. mlt.i" )
++$CFLAGS += " -I../.. " + (ENV.has_key?('CXXFLAGS')? ENV['CXXFLAGS'] : '')
++$LIBS += " -lmlt++ -lmlt -lstdc++"
++create_makefile('mlt')
++system( "make" )

diff --git a/media-libs/mlt/mlt-0.9.8.ebuild b/media-libs/mlt/mlt-0.9.8.ebuild
new file mode 100644
index 0000000..410643c
--- /dev/null
+++ b/media-libs/mlt/mlt-0.9.8.ebuild
@@ -0,0 +1,192 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_DEPEND="python? 2:2.6"
+inherit eutils toolchain-funcs multilib python
+
+DESCRIPTION="An open source multimedia framework, designed and developed for television broadcasting"
+HOMEPAGE="http://www.mltframework.org/"
+SRC_URI="https://github.com/mltframework/mlt/archive/v0.9.8.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="compressed-lumas dv debug ffmpeg fftw frei0r gtk jack kde kdenlive libav libsamplerate melt opengl
+cpu_flags_x86_mmx qt4 quicktime rtaudio sdl cpu_flags_x86_sse cpu_flags_x86_sse2 xine xml lua python ruby vdpau" # java perl php tcl
+IUSE="${IUSE} kernel_linux"
+
+#rtaudio will use OSS on non linux OSes
+RDEPEND="
+	ffmpeg? (
+		libav? ( media-video/libav:0=[vdpau?] )
+		!libav? ( media-video/ffmpeg:0=[vdpau?] )
+	)
+	dv? ( >=media-libs/libdv-0.104 )
+	xml? ( >=dev-libs/libxml2-2.5 )
+	sdl? ( >=media-libs/libsdl-1.2.10[X,opengl]
+		 >=media-libs/sdl-image-1.2.4 )
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.121.3
+		media-libs/ladspa-sdk
+		>=dev-libs/libxml2-2.5 )
+	fftw? ( sci-libs/fftw:3.0= )
+	frei0r? ( media-plugins/frei0r-plugins )
+	gtk? ( x11-libs/gtk+:2
+		media-libs/libexif
+		x11-libs/pango )
+	opengl? ( media-video/movit )
+	quicktime? ( media-libs/libquicktime )
+	rtaudio? ( kernel_linux? ( media-libs/alsa-lib ) )
+	xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
+	qt4? ( dev-qt/qtcore:4
+		dev-qt/qtgui:4
+		dev-qt/qtsvg:4
+		media-libs/libexif
+		x11-libs/libX11 )
+	kde? ( kde-base/kdelibs:4
+		media-libs/libexif )
+	!media-libs/mlt++
+	lua? ( >=dev-lang/lua-5.1.4-r4 )
+	ruby? ( dev-lang/ruby )"
+#	sox? ( media-sound/sox )
+#	java? ( >=virtual/jre-1.5 )
+#	perl? ( dev-lang/perl )
+#	php? ( dev-lang/php )
+#	tcl? ( dev-lang/tcl:0= )
+
+SWIG_DEPEND=">=dev-lang/swig-2.0"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	compressed-lumas? ( || ( media-gfx/imagemagick[png]
+			media-gfx/graphicsmagick[imagemagick,png] ) )
+	lua? ( ${SWIG_DEPEND} virtual/pkgconfig )
+	python? ( ${SWIG_DEPEND} )
+	ruby? ( ${SWIG_DEPEND} )"
+#	java? ( ${SWIG_DEPEND} >=virtual/jdk-1.5 )
+#	perl? ( ${SWIG_DEPEND} )
+#	php? ( ${SWIG_DEPEND} )
+#	tcl? ( ${SWIG_DEPEND} )
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.9.8-ruby-link.patch
+
+	# respect CFLAGS LDFLAGS when building shared libraries. Bug #308873
+	for x in python lua; do
+		sed -i "/mlt.so/s: -lmlt++ :& ${CFLAGS} ${LDFLAGS} :" src/swig/$x/build || die
+	done
+	sed -i "/^LDFLAGS/s: += :& ${LDFLAGS} :" src/swig/ruby/build || die
+
+	epatch_user
+}
+
+src_configure() {
+	tc-export CC CXX
+
+	local myconf="--enable-gpl
+		--enable-gpl3
+		--enable-motion-est
+		--target-arch=$(tc-arch-kernel)
+		--disable-swfdec
+		$(use_enable debug)
+		$(use_enable dv)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_enable cpu_flags_x86_sse2 sse2)
+		$(use_enable gtk gtk2)
+		$(use_enable sdl)
+		$(use_enable jack jackrack)
+		$(use_enable ffmpeg avformat)
+		$(use_enable fftw plus)
+		$(use_enable frei0r)
+		$(use_enable melt)
+		$(use_enable opengl)
+		$(use_enable libsamplerate resample)
+		$(use_enable rtaudio)
+		$(use vdpau && echo ' --avformat-vdpau')
+		$(use_enable xml)
+		$(use_enable xine)
+		$(use_enable kdenlive)
+		$(use_enable qt4 qt)
+		--disable-sox"
+		#$(use_enable sox) FIXME
+
+	use ffmpeg && myconf="${myconf} --avformat-swscale"
+	use kde || myconf="${myconf} --without-kde"
+	(use quicktime && use dv) || myconf="${myconf} --disable-kino"
+	use compressed-lumas && myconf="${myconf} --luma-compress"
+
+	( use x86 || use amd64 ) && \
+		myconf="${myconf} $(use_enable cpu_flags_x86_mmx mmx)" ||
+		myconf="${myconf} --disable-mmx"
+
+	if ! use melt; then
+		sed -i -e "s;src/melt;;" Makefile || die
+	fi
+
+	# TODO: add swig language bindings
+	# see also http://www.mltframework.org/twiki/bin/view/MLT/ExtremeMakeover
+
+	local swig_lang
+	# TODO: java perl php tcl
+	for i in lua python ruby ; do
+		use $i && swig_lang="${swig_lang} $i"
+	done
+	[ -z "${swig_lang}" ] && swig_lang="none"
+
+	econf ${myconf} --swig-languages="${swig_lang}"
+	sed -i -e s/^OPT/#OPT/ "${S}/config.mak" || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog NEWS README docs/*.txt
+
+	dodir /usr/share/${PN}
+	insinto /usr/share/${PN}
+	doins -r demo
+
+	docinto swig
+
+	# Install SWIG bindings
+	if use lua; then
+		cd "${S}"/src/swig/lua || die
+		exeinto $(pkg-config --variable INSTALL_CMOD lua)
+		doexe mlt.so
+		dodoc play.lua
+	fi
+
+	if use python; then
+		cd "${S}"/src/swig/python || die
+		insinto $(python_get_sitedir)
+		doins mlt.py
+		exeinto $(python_get_sitedir)
+		doexe _mlt.so
+		dodoc play.py
+	fi
+
+	if use ruby; then
+		cd "${S}"/src/swig/ruby || die
+		exeinto $("${EPREFIX}"/usr/bin/ruby -r rbconfig -e 'print Config::CONFIG["sitearchdir"]')
+		doexe mlt.so
+		dodoc play.rb thumbs.rb
+	fi
+	# TODO: java perl php tcl
+}
+
+pkg_postinst() {
+	if use python; then
+		python_mod_optimize mlt.py
+	fi
+}
+
+pkg_postrm() {
+	if use python; then
+		python_mod_cleanup mlt.py
+	fi
+}