[gentoo-commits] proj/gnome:master commit in: media-libs/gegl/

[gentoo-commits] proj/gnome:master commit in: media-libs/gegl/

[Gilles Dartiguelongue]

commit:     7be4e35b9c4908c42bf2c2e703ff4fe7740e1b0a
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Thu May 14 15:08:49 2015 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Thu May 14 15:35:00 2015 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=7be4e35b

media-libs/gegl: 0.2.0-r2 → 0.3.0 snapshot

Required by gnome-photos 3.16. Talked to gnome devs and it appears this
is no way around doing a snapshot for now.

 media-libs/gegl/gegl-0.3.0_pre20150304.ebuild | 163 ++++++++++++++++++++++++++
 media-libs/gegl/metadata.xml                  |  13 ++
 2 files changed, 176 insertions(+)

diff --git a/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild b/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
new file mode 100644
index 0000000..2308f9a
--- /dev/null
+++ b/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+# vala and introspection support is broken, bug #468208
+VALA_MIN_API_VERSION=0.20
+VALA_USE_DEPEND=vapigen
+
+inherit versionator gnome2-utils eutils autotools vala
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="http://www.gegl.org/"
+SRC_URI="http://dev.gentoo.org/~eva/distfiles/${PN}/${PN}-0.3.0-c9bbc81.tar.bz2 -> ${P}.tar.bz2"
+#ftp://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0.3"
+KEYWORDS="alpha amd64 ~arm hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+
+IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg jpeg2k lcms lensfun libav openexr png raw sdl svg umfpack vala v4l webp"
+REQUIRED_IUSE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.36:2
+	>=media-libs/babl-0.1.12
+	sys-libs/zlib
+	>=x11-libs/gdk-pixbuf-2.18:2
+	x11-libs/pango
+
+	cairo? ( x11-libs/cairo )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	introspection? (
+		>=dev-libs/gobject-introspection-1.32
+		>=dev-python/pygobject-3.2:3 )
+	jpeg? ( virtual/jpeg )
+	jpeg2k? ( >=media-libs/jasper-1.900.1 )
+	lcms? ( >=media-libs/lcms-2.2:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( media-libs/openexr )
+	png? ( media-libs/libpng )
+	raw? ( =media-libs/libopenraw-0.0.9 )
+	sdl? ( media-libs/libsdl )
+	svg? ( >=gnome-base/librsvg-2.14:2 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( media-libs/libwebp )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.40.1
+	dev-lang/perl
+	virtual/pkgconfig
+	>=sys-devel/libtool-2.2
+	vala? ( $(vala_depend) )
+"
+
+DOCS=( ChangeLog INSTALL README NEWS )
+S="${WORKDIR}/${PN}-0.3.0"
+
+src_prepare() {
+	# FIXME: the following should be proper patch sent to upstream
+	# fix OSX loadable module filename extension
+	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	#epatch "${FILESDIR}"/${P}-g_log_domain.patch
+
+	# gegl test fail on 64bits and a later commit switch the break to 32bits
+	sed -e '/gegl.xml/d' \
+		-e '/contrast-curve.xml/d' \
+		-i tests/compositions/Makefile.am || die
+
+	# Skip broken test with >=dev-python/pygobject-3.14
+	sed -e '/test_buffer/ i\    @unittest.skip("broken")\' \
+		-i tests/python/test-gegl-format.py || die
+
+	eautoreconf
+
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	# never enable altering of CFLAGS via profile option
+	# libspiro: not in portage main tree
+	# disable documentation as the generating is bit automagic
+	#    if anyone wants to work on it just create bug with patch
+
+	# Also please note that:
+	#
+	#  - Some auto-detections are not patched away since the docs are
+	#    not built (--disable-docs, lack of --enable-gtk-doc) and these
+	#    tools affect re-generation of docs, only
+	#    (e.g. ruby, asciidoc, dot (of graphviz), enscript)
+	#
+	#  - Parameter --with-exiv2 compiles a noinst-app only, no use
+	#
+	#  - Parameter --disable-workshop disables any use of Lua, effectivly
+	#
+	#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+	#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+	#
+	#  - There are two checks for dot, one controllable by --with(out)-graphviz
+	#    which toggles HAVE_GRAPHVIZ that is not used anywhere.  Yes.
+	#
+	# So that's why USE="exif graphviz lua v4l" got resolved.  More at:
+	# https://bugs.gentoo.org/show_bug.cgi?id=451136
+	#
+	econf \
+		--disable-docs \
+		--disable-profile \
+		--disable-silent-rules \
+		--disable-workshop \
+		--with-gdk-pixbuf \
+		--with-pango \
+		--without-libspiro \
+		$(use_enable cpu_flags_x86_mmx mmx) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable debug) \
+		$(use_with cairo) \
+		$(use_with cairo pangocairo) \
+		--without-exiv2 \
+		$(use_with ffmpeg libavformat) \
+		--without-graphviz \
+		$(use_with jpeg libjpeg) \
+		$(use_with jpeg2k jasper) \
+		$(use_with lcms) \
+		$(use_with lensfun) \
+		--without-lua \
+		$(use_with openexr) \
+		$(use_with png libpng) \
+		$(use_with raw libopenraw) \
+		$(use_with sdl) \
+		$(use_with svg librsvg) \
+		$(use_with umfpack) \
+		$(use_with v4l libv4l) \
+		$(use_with v4l libv4l2) \
+		$(use_enable introspection) \
+		$(use_with vala) \
+		$(use_with webp)
+}
+
+src_test() {
+	gnome2_environment_reset  # sandbox issues
+	default
+}
+
+src_compile() {
+	gnome2_environment_reset  # sandbox issues (bug #396687)
+	default
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}

diff --git a/media-libs/gegl/metadata.xml b/media-libs/gegl/metadata.xml
new file mode 100644
index 0000000..16edd81
--- /dev/null
+++ b/media-libs/gegl/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer>
+	<email>sping@gentoo.org</email>
+</maintainer>
+<use>
+	<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for introspection.</flag>
+	<flag name="lensfun">Enable support for <pkg>media-libs/lensfun</pkg>.</flag>
+	<flag name="umfpack">Enable sparse solving via <pkg>sci-libs/umfpack</pkg>.</flag>
+	<flag name="vala">Enable bindings for <pkg>dev-lang/vala</pkg></flag>
+</use>
+</pkgmetadata>

[gentoo-commits] proj/gnome:master commit in: media-libs/gegl/

[Gilles Dartiguelongue]

commit:     a16257511d12f791e93cbf64d73c64ad85311e8a
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Thu May 14 22:03:15 2015 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Thu May 14 22:03:15 2015 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=a1625751

media-libs/gegl: fix repoman warnings

 media-libs/gegl/gegl-0.3.0_pre20150304.ebuild | 6 +++---
 media-libs/gegl/metadata.xml                  | 1 +
 2 files changed, 4 insertions(+), 3 deletions(-)

diff --git a/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild b/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
index 2308f9a..014332e 100644
--- a/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
+++ b/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
@@ -17,7 +17,7 @@ SRC_URI="http://dev.gentoo.org/~eva/distfiles/${PN}/${PN}-0.3.0-c9bbc81.tar.bz2
 
 LICENSE="|| ( GPL-3 LGPL-3 )"
 SLOT="0.3"
-KEYWORDS="alpha amd64 ~arm hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
 
 IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg jpeg2k lcms lensfun libav openexr png raw sdl svg umfpack vala v4l webp"
 REQUIRED_IUSE="vala? ( introspection )"
@@ -37,12 +37,12 @@ RDEPEND="
 	introspection? (
 		>=dev-libs/gobject-introspection-1.32
 		>=dev-python/pygobject-3.2:3 )
-	jpeg? ( virtual/jpeg )
+	jpeg? ( virtual/jpeg:= )
 	jpeg2k? ( >=media-libs/jasper-1.900.1 )
 	lcms? ( >=media-libs/lcms-2.2:2 )
 	lensfun? ( >=media-libs/lensfun-0.2.5 )
 	openexr? ( media-libs/openexr )
-	png? ( media-libs/libpng )
+	png? ( media-libs/libpng:= )
 	raw? ( =media-libs/libopenraw-0.0.9 )
 	sdl? ( media-libs/libsdl )
 	svg? ( >=gnome-base/librsvg-2.14:2 )

diff --git a/media-libs/gegl/metadata.xml b/media-libs/gegl/metadata.xml
index 16edd81..93d122d 100644
--- a/media-libs/gegl/metadata.xml
+++ b/media-libs/gegl/metadata.xml
@@ -9,5 +9,6 @@
 	<flag name="lensfun">Enable support for <pkg>media-libs/lensfun</pkg>.</flag>
 	<flag name="umfpack">Enable sparse solving via <pkg>sci-libs/umfpack</pkg>.</flag>
 	<flag name="vala">Enable bindings for <pkg>dev-lang/vala</pkg></flag>
+	<flag name="webp">Enable support for <pkg>media-libs/libwebp</pkg></flag>
 </use>
 </pkgmetadata>

[gentoo-commits] proj/gnome:master commit in: media-libs/gegl/

[Gilles Dartiguelongue]

commit:     468107a12f0ab7178b973eb1b28213c275be336e
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun May 24 10:38:48 2015 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun May 24 10:38:48 2015 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=468107a1

media-libs/gegl: fix file collision between slots

 media-libs/gegl/gegl-0.3.0_pre20150304.ebuild | 1 +
 1 file changed, 1 insertion(+)

diff --git a/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild b/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
index 014332e..e09b792 100644
--- a/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
+++ b/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
@@ -118,6 +118,7 @@ src_configure() {
 		--disable-profile \
 		--disable-silent-rules \
 		--disable-workshop \
+		--program-suffix=-${SLOT} \
 		--with-gdk-pixbuf \
 		--with-pango \
 		--without-libspiro \

[gentoo-commits] proj/gnome:master commit in: media-libs/gegl/

[Gilles Dartiguelongue]

commit:     13cc28e63ea60826ba5f4e73cf69f6f11eae73a7
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Mon May 25 14:47:52 2015 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Mon May 25 14:47:52 2015 +0000
URL:        https://gitweb.gentoo.org/proj/gnome.git/commit/?id=13cc28e6

media-libs/gegl: add missing json-glib dependency, bug #549530

 media-libs/gegl/gegl-0.3.0_pre20150304.ebuild | 1 +
 1 file changed, 1 insertion(+)

diff --git a/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild b/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
index e09b792..78f8046 100644
--- a/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
+++ b/media-libs/gegl/gegl-0.3.0_pre20150304.ebuild
@@ -24,6 +24,7 @@ REQUIRED_IUSE="vala? ( introspection )"
 
 RDEPEND="
 	>=dev-libs/glib-2.36:2
+	dev-libs/json-glib
 	>=media-libs/babl-0.1.12
 	sys-libs/zlib
 	>=x11-libs/gdk-pixbuf-2.18:2