[gentoo-commits] proj/gamerlay:master commit in: games-strategy/vcmi/, games-strategy/vcmi-data/

[gentoo-commits] proj/gamerlay:master commit in: games-strategy/vcmi/, games-strategy/vcmi-data/

[Vadim A. Misbakh-Soloviov]

commit:     cf86e98add5342a50115265f8c2865e70cf175e9
Author:     Vadim A. Misbakh-Soloviov <git <AT> mva <DOT> name>
AuthorDate: Mon May  4 16:50:32 2015 +0000
Commit:     Vadim A. Misbakh-Soloviov <mva <AT> mva <DOT> name>
CommitDate: Mon May  4 16:50:32 2015 +0000
URL:        https://gitweb.gentoo.org/proj/gamerlay.git/commit/?id=cf86e98a

[games-strategy/vcmi{,-data}] Added

 games-strategy/vcmi-data/vcmi-data-0.90.ebuild | 45 +++++++++++++++
 games-strategy/vcmi/vcmi-0.98.ebuild           | 79 ++++++++++++++++++++++++++
 2 files changed, 124 insertions(+)

diff --git a/games-strategy/vcmi-data/vcmi-data-0.90.ebuild b/games-strategy/vcmi-data/vcmi-data-0.90.ebuild
new file mode 100644
index 0000000..b66c6d3
--- /dev/null
+++ b/games-strategy/vcmi-data/vcmi-data-0.90.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit games
+
+DESCRIPTION="Core data for vcmi"
+HOMEPAGE="http://forum.vcmi.eu/index.php"
+MY_P="core"
+SRC_URI="
+	http://download.vcmi.eu/core.zip
+	http://download.vcmi.eu/WoG/wog.zip
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE=""
+
+DEPEND="app-arch/unzip"
+RDEPEND=""
+
+S="${WORKDIR}"
+
+src_install() {
+	insinto "${GAMES_DATADIR}/${PN%-data}"
+	rm -rf Mods/vcmi/Data/s
+	doins -r *
+}
+
+pkg_postinst() {
+	elog "For the game to work properly, please copy your"
+	elog 'Heroes Of Might and Magic ("The Wake Of Gods" or'
+	elog '"Shadow of Death" or "Complete edition")'
+	elog "game directory into ${GAMES_DATADIR}/${PN}."
+	elog "or use 'vcmibuilder' utility on your:"
+	elog "   a) One or two CD's or CD images"
+	elog "   b) gog.com installer"
+	elog "   c) Directory with installed game"
+	elog "(although installing it in such way is 'bad practices')."
+	elog "For more information, please visit:"
+	elog "http://wiki.vcmi.eu/index.php?title=Installation_on_Linux"
+}

diff --git a/games-strategy/vcmi/vcmi-0.98.ebuild b/games-strategy/vcmi/vcmi-0.98.ebuild
new file mode 100644
index 0000000..80ff809
--- /dev/null
+++ b/games-strategy/vcmi/vcmi-0.98.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit eutils games cmake-utils
+
+DESCRIPTION="Heroes of Might and Magic III game engine rewrite"
+HOMEPAGE="http://forum.vcmi.eu/index.php"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="debug editor launcher +erm"
+
+CDEPEND="
+	media-libs/libsdl2[video]
+	media-libs/sdl2-image
+	media-libs/sdl2-mixer
+	media-libs/sdl2-ttf
+	virtual/ffmpeg
+	sys-libs/zlib[minizip]
+	editor? (
+		dev-qt/qtgui
+		dev-qt/qtcore
+		dev-qt/qtwidgets
+	)
+	launcher? (
+		dev-qt/qtgui
+		dev-qt/qtcore
+		dev-qt/qtnetwork
+		dev-qt/qtwidgets
+	)
+	dev-libs/fuzzylite
+"
+
+DEPEND="
+	>dev-libs/boost-1.48.0
+	virtual/pkgconfig
+	${CDEPEND}
+"
+RDEPEND="
+	${CDEPEND}
+"
+PDEPEND="
+	games-strategy/vcmi-data
+"
+
+src_configure() {
+	local MY_DATADIR="${GAMES_DATADIR#/usr/}/${PN}"
+	local MY_GAMESLIBDIR=$(games_get_libdir)
+	local MY_LIBDIR=${MY_GAMESLIBDIR#/usr/}
+	local MY_BINDIR=${GAMES_BINDIR#/usr/}
+
+	use editor && ewarn "Editor seems to be broken. At least, it fails to build for me"
+	use debug || ewarn "Somewhy, buildsystem don't want to use cotire (compile time reducer) generated pch (precompiled header) with disabled debug, so, you will see the warnings on each target."
+
+	local mycmakeargs=(
+		-DDATA_DIR="${MY_DATADIR}"
+		-DLIB_DIR="${MY_LIBDIR}"
+		-DBIN_DIR="${MY_BINDIR}"
+		$(cmake-utils_use_enable erm ERM)
+		$(cmake-utils_use_enable editor EDITOR)
+		$(cmake-utils_use_enable launcher LAUNCHER)
+	)
+	export CCACHE_SLOPPINESS="time_macros"
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+}