[gentoo-commits] proj/gnome:master commit in: dev-libs/gobject-introspection/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     5d5422efc4a500df1dc5418495ce48443fdc4116
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 21 12:39:02 2014 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Dec 21 12:39:10 2014 +0000
URL:        http://sources.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=5d5422ef

dev-libs/gobject-introspection: moved to gentoo-x86

---
 .../gobject-introspection-1.42.0.ebuild            | 73 ----------------------
 1 file changed, 73 deletions(-)

diff --git a/dev-libs/gobject-introspection/gobject-introspection-1.42.0.ebuild b/dev-libs/gobject-introspection/gobject-introspection-1.42.0.ebuild
deleted file mode 100644
index 1032794..0000000
--- a/dev-libs/gobject-introspection/gobject-introspection-1.42.0.ebuild
+++ /dev/null
@@ -1,73 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="5"
-GCONF_DEBUG="no"
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE="xml"
-
-inherit gnome2 python-single-r1 toolchain-funcs versionator
-
-DESCRIPTION="Introspection infrastructure for generating gobject library bindings for various languages"
-HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
-
-LICENSE="LGPL-2+ GPL-2+"
-SLOT="0"
-IUSE="cairo doctool test"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	test? ( cairo )
-"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-
-# virtual/pkgconfig needed at runtime, bug #505408
-# We force glib and goi to be in sync by this way as explained in bug #518424
-RDEPEND="
-	>=dev-libs/gobject-introspection-common-${PV}
-	>=dev-libs/glib-2.$(get_version_component_range 2):2
-	doctool? ( dev-python/mako )
-	virtual/libffi:=
-	virtual/pkgconfig
-	!<dev-lang/vala-0.20.0
-	${PYTHON_DEPS}
-"
-# Wants real bison, not virtual/yacc
-DEPEND="${RDEPEND}
-	>=dev-util/gtk-doc-am-1.19
-	sys-devel/bison
-	sys-devel/flex
-"
-# PDEPEND to avoid circular dependencies, bug #391213
-PDEPEND="cairo? ( x11-libs/cairo[glib] )"
-
-pkg_setup() {
-	python-single-r1_pkg_setup
-}
-
-src_configure() {
-	if ! has_version "x11-libs/cairo[glib]"; then
-		# Bug #391213: enable cairo-gobject support even if it's not installed
-		# We only PDEPEND on cairo to avoid circular dependencies
-		export CAIRO_LIBS="-lcairo -lcairo-gobject"
-		export CAIRO_CFLAGS="-I${EPREFIX}/usr/include/cairo"
-	fi
-
-	# To prevent crosscompiling problems, bug #414105
-	gnome2_src_configure \
-		--disable-static \
-		CC=$(tc-getCC) \
-		YACC=$(type -p yacc) \
-		$(use_with cairo) \
-		$(use_enable doctool)
-}
-
-src_install() {
-	DOCS="AUTHORS CONTRIBUTORS ChangeLog NEWS README TODO"
-	gnome2_src_install
-
-	# Prevent collision with gobject-introspection-common
-	rm -v "${ED}"usr/share/aclocal/introspection.m4 \
-		"${ED}"usr/share/gobject-introspection-1.0/Makefile.introspection || die
-	rmdir "${ED}"usr/share/aclocal || die
-}