[gentoo-commits] proj/sci:master commit in: sci-libs/gsl/

["Christoph Junghans" <ottxor@gentoo.org>]

commit:     abe549ffad5e6e319ca9947fa96e65f443ef6012
Author:     Christoph Junghans <ottxor <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 10 23:25:42 2014 +0000
Commit:     Christoph Junghans <ottxor <AT> gentoo <DOT> org>
CommitDate: Mon Nov 10 23:25:42 2014 +0000
URL:        http://sources.gentoo.org/gitweb/?p=proj/sci.git;a=commit;h=abe549ff

added multilib support (bug #528622)

Package-Manager: portage-2.2.8-r2

---
 sci-libs/gsl/ChangeLog          |  5 ++++
 sci-libs/gsl/gsl-1.16-r2.ebuild | 60 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/sci-libs/gsl/ChangeLog b/sci-libs/gsl/ChangeLog
index 81ecb25..0ffe3bd 100644
--- a/sci-libs/gsl/ChangeLog
+++ b/sci-libs/gsl/ChangeLog
@@ -2,6 +2,11 @@
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
 # $Header: /var/cvsroot/gentoo-x86/sci-libs/gsl/ChangeLog,v 1.77 2010/08/09 09:32:55 xarthisius Exp $
 
+*gsl-1.16-r2 (10 Nov 2014)
+
+  10 Nov 2014; Christoph Junghans <ottxor@gentoo.org> +gsl-1.16-r2.ebuild:
+  added multilib support (bug #528622)
+
   02 Jul 2014; François Bissey <francois.bissey@canterbury.ac.nz>
   gsl-1.16-r1.ebuild:
   Tested on x64-macos, keywording.

diff --git a/sci-libs/gsl/gsl-1.16-r2.ebuild b/sci-libs/gsl/gsl-1.16-r2.ebuild
new file mode 100644
index 0000000..7cf4402
--- /dev/null
+++ b/sci-libs/gsl/gsl-1.16-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+
+inherit alternatives-2 autotools-multilib eutils toolchain-funcs
+
+DESCRIPTION="GNU Scientific Library"
+HOMEPAGE="http://www.gnu.org/software/gsl/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+IUSE="cblas-external static-libs"
+
+RDEPEND="cblas-external? ( >=virtual/cblas-2.0-r3[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
+
+PATCHES=( "${FILESDIR}"/${P}-cblas-external.patch )
+
+src_configure() {
+	if use cblas-external; then
+		export CBLAS_LIBS="$($(tc-getPKG_CONFIG) --libs cblas)"
+		export CBLAS_CFLAGS="$($(tc-getPKG_CONFIG) --cflags cblas)"
+	fi
+	local myeconfargs=(
+		$(use_with cblas-external)
+	)
+	autotools-multilib_src_configure
+}
+
+multilib_src_install() {
+	autotools-utils_src_install
+	local libname=gslcblas
+
+	cat <<-EOF > ${libname}.pc
+		prefix=${EPREFIX}/usr
+		libdir=\${prefix}/$(get_libdir)
+		includedir=\${prefix}/include
+		Name: ${libname}
+		Description: ${DESCRIPTION} CBLAS implementation
+		Version: ${PV}
+		URL: ${HOMEPAGE}
+		Libs: -L\${libdir} -l${libname}
+		Libs.private: -lm
+		Cflags: -I\${includedir}
+	EOF
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${libname}.pc
+
+	# Don't add gsl as a cblas alternative if using cblas-external
+	use cblas-external || alternatives_for cblas gsl 0 \
+		/usr/$(get_libdir)/pkgconfig/cblas.pc ${libname}.pc \
+		/usr/include/cblas.h gsl/gsl_cblas.h
+}