From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-731536-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	by finch.gentoo.org (Postfix) with ESMTP id CE25913838B
	for <garchives@archives.gentoo.org>; Fri, 12 Sep 2014 19:26:16 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id C463BE0769;
	Fri, 12 Sep 2014 19:26:15 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 59A68E0769
	for <gentoo-commits@lists.gentoo.org>; Fri, 12 Sep 2014 19:26:15 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher AECDH-AES256-SHA (256/256 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 3573833EDF8
	for <gentoo-commits@lists.gentoo.org>; Fri, 12 Sep 2014 19:26:14 +0000 (UTC)
Received: from localhost.localdomain (localhost [127.0.0.1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 6EF8754DB
	for <gentoo-commits@lists.gentoo.org>; Fri, 12 Sep 2014 19:26:12 +0000 (UTC)
From: "Michael Palimaka" <kensington@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michael Palimaka" <kensington@gentoo.org>
Message-ID: <1410549962.f2f9b8920a87ad2dd02dfdca9cff8e43921293e6.kensington@gentoo>
Subject: [gentoo-commits] proj/kde:master commit in: kde-base/kwin/, kde-base/plasma-nm/, kde-base/baloo/, kde-base/ksysguard/, ...
X-VCS-Repository: proj/kde
X-VCS-Files: kde-base/baloo/baloo-5.0.2.ebuild kde-base/breeze/breeze-5.0.2.ebuild kde-base/kde-cli-tools/kde-cli-tools-5.0.2.ebuild kde-base/kfilemetadata/kfilemetadata-5.0.2.ebuild kde-base/khelpcenter/khelpcenter-5.0.2.ebuild kde-base/khotkeys/khotkeys-5.0.2.ebuild kde-base/kinfocenter/kinfocenter-5.0.2.ebuild kde-base/kio-extras/kio-extras-5.0.2.ebuild kde-base/kmenuedit/kmenuedit-5.0.2.ebuild kde-base/ksysguard/ksysguard-5.0.2.ebuild kde-base/kwin/kwin-5.0.2.ebuild kde-base/kwrited/kwrited-5.0.2.ebuild kde-base/libksysguard/libksysguard-5.0.2.ebuild kde-base/milou/milou-5.0.2.ebuild kde-base/oxygen/oxygen-5.0.2.ebuild kde-base/plasma-desktop/plasma-desktop-5.0.2.ebuild kde-base/plasma-nm/plasma-nm-5.0.2.ebuild kde-base/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.0.2.ebuild kde-base/plasma-workspace/plasma-workspace-5.0.2.ebuild kde-base/powerdevil/powerdevil-5.0.2.ebuild kde-base/systemsettings/systemsettings-5.0.2.ebuild
X-VCS-Directories: kde-base/kwin/ kde-base/plasma-nm/ kde-base/baloo/ kde-base/ksysguard/ kde-base/plasma-desktop/ kde-base/libksysguard/ kde-base/plasma-workspace/ kde-base/plasma-workspace-wallpapers/ kde-base/kinfocenter/ kde-base/powerdevil/ kde-base/milou/ kde-base/kwrited/ kde-base/khelpcenter/ kde-base/systemsettings/ kde-base/kmenuedit/ kde-base/breeze/ kde-base/kfilemetadata/ kde-base/kde-cli-tools/ kde-base/khotkeys/ kde-base/kio-extras/ kde-base/oxygen/
X-VCS-Committer: kensington
X-VCS-Committer-Name: Michael Palimaka
X-VCS-Revision: f2f9b8920a87ad2dd02dfdca9cff8e43921293e6
X-VCS-Branch: master
Date: Fri, 12 Sep 2014 19:26:12 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Archives-Salt: a4b2c2c7-74ce-4fc8-a7a6-f3aeac94b7e8
X-Archives-Hash: 0423c691334da3dc84e99952adf3a1af

commit:     f2f9b8920a87ad2dd02dfdca9cff8e43921293e6
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 12 19:26:02 2014 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Fri Sep 12 19:26:02 2014 +0000
URL:        http://sources.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=f2f9b892

[kde-base] Add Plasma 5.0.2

---
 kde-base/baloo/baloo-5.0.2.ebuild                  |  45 +++++++
 kde-base/breeze/breeze-5.0.2.ebuild                |  22 ++++
 kde-base/kde-cli-tools/kde-cli-tools-5.0.2.ebuild  |  50 ++++++++
 kde-base/kfilemetadata/kfilemetadata-5.0.2.ebuild  |  38 ++++++
 kde-base/khelpcenter/khelpcenter-5.0.2.ebuild      |  49 ++++++++
 kde-base/khotkeys/khotkeys-5.0.2.ebuild            |  45 +++++++
 kde-base/kinfocenter/kinfocenter-5.0.2.ebuild      |  70 +++++++++++
 kde-base/kio-extras/kio-extras-5.0.2.ebuild        |  82 +++++++++++++
 kde-base/kmenuedit/kmenuedit-5.0.2.ebuild          |  44 +++++++
 kde-base/ksysguard/ksysguard-5.0.2.ebuild          |  47 +++++++
 kde-base/kwin/kwin-5.0.2.ebuild                    |  78 ++++++++++++
 kde-base/kwrited/kwrited-5.0.2.ebuild              |  23 ++++
 kde-base/libksysguard/libksysguard-5.0.2.ebuild    |  53 ++++++++
 kde-base/milou/milou-5.0.2.ebuild                  |  23 ++++
 kde-base/oxygen/oxygen-5.0.2.ebuild                |  34 ++++++
 .../plasma-desktop/plasma-desktop-5.0.2.ebuild     | 109 +++++++++++++++++
 kde-base/plasma-nm/plasma-nm-5.0.2.ebuild          |  62 ++++++++++
 .../plasma-workspace-wallpapers-5.0.2.ebuild       |  16 +++
 .../plasma-workspace/plasma-workspace-5.0.2.ebuild | 135 +++++++++++++++++++++
 kde-base/powerdevil/powerdevil-5.0.2.ebuild        |  56 +++++++++
 .../systemsettings/systemsettings-5.0.2.ebuild     |  39 ++++++
 21 files changed, 1120 insertions(+)

diff --git a/kde-base/baloo/baloo-5.0.2.ebuild b/kde-base/baloo/baloo-5.0.2.ebuild
new file mode 100644
index 0000000..5962a40
--- /dev/null
+++ b/kde-base/baloo/baloo-5.0.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Framework for searching and managing metadata"
+KEYWORDS=" ~amd64"
+IUSE=""
+
+# TODO re-enable kdepim integration
+DEPEND="
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kidletime)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep solid)
+	$(add_kdebase_dep kfilemetadata)
+	=dev-libs/xapian-1.2*[chert]
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	sys-apps/attr
+	!<kde-base/nepomuk-4.12.50
+"
+RDEPEND="${DEPEND}
+	!kde-base/baloo:4[-minimal(-)]
+"
+
+src_configure() {
+	local mycmakeargs=( -DKDEPIM_SUPPORT_BUILD=OFF )
+
+	kde5_src_configure
+}

diff --git a/kde-base/breeze/breeze-5.0.2.ebuild b/kde-base/breeze/breeze-5.0.2.ebuild
new file mode 100644
index 0000000..c10b429
--- /dev/null
+++ b/kde-base/breeze/breeze-5.0.2.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Breeze visual style for the Plasma desktop"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/breeze"
+KEYWORDS=" ~amd64"
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kcoreaddons)
+	dev-qt/qtwidgets:5
+"
+RDEPEND="
+	${DEPEND}
+	dev-qt/qtgraphicaleffects:5
+"

diff --git a/kde-base/kde-cli-tools/kde-cli-tools-5.0.2.ebuild b/kde-base/kde-cli-tools/kde-cli-tools-5.0.2.ebuild
new file mode 100644
index 0000000..8b362e2
--- /dev/null
+++ b/kde-base/kde-cli-tools/kde-cli-tools-5.0.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Tools based on KDE Frameworks 5 to better interact with the system"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/kde-cli-tools"
+KEYWORDS=" ~amd64"
+IUSE="X"
+
+DEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep kdesu)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	X? (
+		dev-qt/qtx11extras:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}"
+
+# requires running kde environment
+RESTRICT="test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package X Qt5X11Extras)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/kfilemetadata/kfilemetadata-5.0.2.ebuild b/kde-base/kfilemetadata/kfilemetadata-5.0.2.ebuild
new file mode 100644
index 0000000..cd7fa23
--- /dev/null
+++ b/kde-base/kfilemetadata/kfilemetadata-5.0.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Library for extracting file metadata"
+KEYWORDS=" ~amd64"
+IUSE="epub exif ffmpeg pdf taglib"
+
+# TODO: mobi? ( $(add_kdebase_dep kdegraphics-mobipocket) ) NOTE: not integrated upstream
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kservice)
+	dev-qt/qtxml:5
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( virtual/ffmpeg )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package epub EPub)
+		$(cmake-utils_use_find_package exif Exiv2)
+		$(cmake-utils_use_find_package ffmpeg FFmpeg)
+		$(cmake-utils_use_find_package pdf PopplerQt5)
+		$(cmake-utils_use_find_package taglib Taglib)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/khelpcenter/khelpcenter-5.0.2.ebuild b/kde-base/khelpcenter/khelpcenter-5.0.2.ebuild
new file mode 100644
index 0000000..fd9a804
--- /dev/null
+++ b/kde-base/khelpcenter/khelpcenter-5.0.2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="The KDE Help Center"
+HOMEPAGE+=" http://userbase.kde.org/KHelpCenter"
+KEYWORDS=" ~amd64"
+IUSE="compat"
+
+DEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep khtml)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kinit)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	!kde-base/khelpcenter:4
+"
+RDEPEND="${DEPEND}"
+
+src_install() {
+	kde5_src_install
+
+	if use compat ; then
+		insinto /usr/share/kde4/services
+		doins "${D}"/usr/share/kservices5/khelpcenter.desktop
+	fi
+}

diff --git a/kde-base/khotkeys/khotkeys-5.0.2.ebuild b/kde-base/khotkeys/khotkeys-5.0.2.ebuild
new file mode 100644
index 0000000..f132be3
--- /dev/null
+++ b/kde-base/khotkeys/khotkeys-5.0.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="KDE workspace hotkey module"
+KEYWORDS=" ~amd64"
+IUSE=""
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_kdebase_dep plasma-workspace)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	x11-libs/libX11
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kded)
+	!kde-base/khotkeys:4
+	!kde-base/systemsettings:4
+"
+DEPEND="${COMMON_DEPEND}
+	x11-libs/libxcb
+	x11-libs/libXtst
+	x11-proto/xproto
+"

diff --git a/kde-base/kinfocenter/kinfocenter-5.0.2.ebuild b/kde-base/kinfocenter/kinfocenter-5.0.2.ebuild
new file mode 100644
index 0000000..367feeb
--- /dev/null
+++ b/kde-base/kinfocenter/kinfocenter-5.0.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="A utility that provides information about a computer system"
+HOMEPAGE="http://www.kde.org/applications/system/kinfocenter/"
+KEYWORDS=" ~amd64"
+IUSE="egl gles ieee1394 +opengl +pci samba nfs server wayland X"
+
+REQUIRED_USE="egl? ( || ( gles opengl ) )"
+
+RDEPEND="
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	dev-qt/qtgui:5[opengl?]
+	dev-qt/qtwidgets:5
+	gles? (
+		dev-qt/qtgui:5[gles2]
+		|| (
+		media-libs/mesa[egl,gles1]
+		media-libs/mesa[egl,gles2]
+	) )
+	ieee1394? ( sys-libs/libraw1394 )
+	nfs? ( net-fs/nfs-utils )
+	opengl? (
+		virtual/glu
+		virtual/opengl
+	)
+	pci? ( sys-apps/pciutils )
+	samba? ( net-fs/samba[server=] )
+	wayland? ( >=dev-libs/wayland-1.2 )
+	X? ( x11-libs/libX11 )
+	!kde-base/kcontrol:4
+	!kde-base/kinfocenter:4
+"
+DEPEND="${RDEPEND}
+	$(add_frameworks_dep plasma)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package egl EGL)
+		$(cmake-utils_use_find_package gles OpenGLES)
+		$(cmake-utils_use_find_package ieee1394 RAW1394)
+		$(cmake-utils_use_find_package opengl OpenGL)
+		$(cmake-utils_use_find_package pci PCIUTILS)
+		$(cmake-utils_use_find_package wayland Wayland)
+		$(cmake-utils_use_find_package X X11)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/kio-extras/kio-extras-5.0.2.ebuild b/kde-base/kio-extras/kio-extras-5.0.2.ebuild
new file mode 100644
index 0000000..be6e568
--- /dev/null
+++ b/kde-base/kio-extras/kio-extras-5.0.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit fdo-mime kde5
+
+DESCRIPTION="KIO plugins present a filesystem-like view of arbitrary data"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/kio-extras"
+KEYWORDS=" ~amd64"
+IUSE="exif openexr phonon samba +sftp slp"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep karchive 'bzip2,lzma')
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep kdnssd)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep khtml)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	virtual/jpeg:0
+	exif? ( media-gfx/exiv2:= )
+	openexr? ( media-libs/openexr:= )
+	phonon? ( media-libs/phonon[qt5] )
+	samba? ( || ( <net-fs/samba-4.0.0_alpha1[smbclient] >=net-fs/samba-4.0.0_alpha1[client] ) )
+	sftp? ( >=net-libs/libssh-0.6.0:=[sftp] )
+	slp? ( net-libs/openslp )
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kded)
+	!kde-base/kcontrol:4
+	!kde-base/kdebase-kioslaves:4[-minimal(-)]
+"
+DEPEND="${COMMON_DEPEND}
+	x11-misc/shared-mime-info
+"
+
+# requires running kde environment
+RESTRICT="test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package exif Exiv2)
+		$(cmake-utils_use_find_package openexr OpenEXR)
+		$(cmake-utils_use_find_package phonon Phonon4Qt5)
+		$(cmake-utils_use_find_package samba)
+		$(cmake-utils_use_find_package sftp LibSSH)
+		$(cmake-utils_use_find_package slp)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	kde5_pkg_postinst
+	fdo-mime_mime_database_update
+}

diff --git a/kde-base/kmenuedit/kmenuedit-5.0.2.ebuild b/kde-base/kmenuedit/kmenuedit-5.0.2.ebuild
new file mode 100644
index 0000000..dee4f86
--- /dev/null
+++ b/kde-base/kmenuedit/kmenuedit-5.0.2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE menu editor"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/kmenuedit"
+KEYWORDS=" ~amd64"
+IUSE="+hotkeys"
+
+DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep sonnet)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	hotkeys? ( $(add_kdebase_dep khotkeys) )
+"
+RDEPEND="${DEPEND}
+	!kde-base/kmenuedit:4
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package hotkeys KHotKeysDBusInterface)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/ksysguard/ksysguard-5.0.2.ebuild b/kde-base/ksysguard/ksysguard-5.0.2.ebuild
new file mode 100644
index 0000000..0e407f9
--- /dev/null
+++ b/kde-base/ksysguard/ksysguard-5.0.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="Network-enabled task manager and system monitor"
+LICENSE="GPL-2+"
+KEYWORDS=" ~amd64"
+IUSE="lm_sensors"
+
+DEPEND="
+	$(add_kdebase_dep libksysguard)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	lm_sensors? ( sys-apps/lm_sensors )
+"
+RDEPEND="${DEPEND}
+	!kde-base/ksysguard:4
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package lm_sensors Sensors)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/kwin/kwin-5.0.2.ebuild b/kde-base/kwin/kwin-5.0.2.ebuild
new file mode 100644
index 0000000..0fd6e0b
--- /dev/null
+++ b/kde-base/kwin/kwin-5.0.2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE window manager"
+LICENSE="GPL-2+"
+KEYWORDS=" ~amd64"
+IUSE="gles2 wayland"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kinit)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5[gles2=,opengl]
+	dev-qt/qtmultimedia:5[qml]
+	dev-qt/qtscript:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras
+	media-libs/libepoxy
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXxf86vm
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-keysyms
+	wayland? (
+		>=dev-libs/wayland-1.2
+		>=x11-libs/libxkbcommon-0.4.1
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	!kde-base/kwin:4
+	!kde-base/systemsettings:4
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/designer:5
+	dev-qt/qtconcurrent:5
+	media-libs/mesa[egl,gles2?]
+	x11-proto/xproto
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package wayland)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/kwrited/kwrited-5.0.2.ebuild b/kde-base/kwrited/kwrited-5.0.2.ebuild
new file mode 100644
index 0000000..10e7992
--- /dev/null
+++ b/kde-base/kwrited/kwrited-5.0.2.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE daemon listening for wall and write messages"
+LICENSE="GPL-2"
+KEYWORDS=" ~amd64"
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kpty)
+"
+RDEPEND="${DEPEND}
+	!kde-base/kwrited:4
+"

diff --git a/kde-base/libksysguard/libksysguard-5.0.2.ebuild b/kde-base/libksysguard/libksysguard-5.0.2.ebuild
new file mode 100644
index 0000000..b3a3795
--- /dev/null
+++ b/kde-base/libksysguard/libksysguard-5.0.2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Task management and system monitoring library"
+LICENSE="LGPL-2+"
+KEYWORDS=" ~amd64"
+IUSE="X"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwebkit:5[widgets]
+	dev-qt/qtwidgets:5
+	sys-libs/zlib
+	X? (
+		dev-qt/qtx11extras:5
+		x11-libs/libX11
+		x11-libs/libXres
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	!kde-base/ksysguard:4
+"
+DEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep plasma)
+	X? ( x11-proto/xproto )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package X X11)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/milou/milou-5.0.2.ebuild b/kde-base/milou/milou-5.0.2.ebuild
new file mode 100644
index 0000000..87807ec
--- /dev/null
+++ b/kde-base/milou/milou-5.0.2.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Dedicated search application built on top of Baloo"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/milou"
+
+LICENSE="GPL-2 LGPL-2.1"
+KEYWORDS=" ~amd64"
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep krunner)
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep baloo)
+"

diff --git a/kde-base/oxygen/oxygen-5.0.2.ebuild b/kde-base/oxygen/oxygen-5.0.2.ebuild
new file mode 100644
index 0000000..38b72fe
--- /dev/null
+++ b/kde-base/oxygen/oxygen-5.0.2.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE window manager theme"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/oxygen"
+KEYWORDS=" ~amd64"
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep frameworkintegration)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_kdebase_dep kwin)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	x11-libs/libxcb
+"
+RDEPEND="${DEPEND}
+	!kde-base/kdebase-cursors:4
+"

diff --git a/kde-base/plasma-desktop/plasma-desktop-5.0.2.ebuild b/kde-base/plasma-desktop/plasma-desktop-5.0.2.ebuild
new file mode 100644
index 0000000..9a3e3b9
--- /dev/null
+++ b/kde-base/plasma-desktop/plasma-desktop-5.0.2.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="KDE Plasma desktop"
+KEYWORDS=" ~amd64"
+IUSE="bluetooth +fontconfig networkmanager pulseaudio usb"
+
+COMMON_DEPEND="
+	$(add_kdebase_dep kwin)
+	$(add_kdebase_dep plasma-workspace)
+	$(add_frameworks_dep attica)
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep kemoticons)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep krunner)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	$(add_frameworks_dep solid)
+	$(add_frameworks_dep sonnet)
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	media-libs/phonon[qt5]
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXi
+	x11-libs/libxkbfile
+	x11-libs/libXtst
+	bluetooth? ( net-wireless/bluedevil:5 )
+	fontconfig? (
+		media-libs/fontconfig
+		media-libs/freetype
+		x11-libs/libXft
+		x11-libs/xcb-util-image
+	)
+	networkmanager? ( $(add_kdebase_dep plasma-nm) )
+	pulseaudio? (
+		dev-libs/glib:2
+		media-libs/libcanberra
+		media-sound/pulseaudio
+	)
+	usb? (
+		x11-libs/libXcursor
+		x11-libs/libXfixes
+		virtual/libusb:0
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kded)
+	sys-apps/accountsservice
+	!kde-base/attica:4
+	!kde-base/kcontrol:4
+	!kde-base/knetattach:4
+	!kde-base/kdepasswd:4
+	!kde-base/plasma-workspace:4
+	!kde-base/systemsettings:4
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/qtconcurrent:5
+	x11-proto/xproto
+	fontconfig? ( x11-libs/libXrender )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package fontconfig Fontconfig)
+		$(cmake-utils_use_find_package pulseaudio PulseAudio)
+		$(cmake-utils_use_find_package usb USB)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/plasma-nm/plasma-nm-5.0.2.ebuild b/kde-base/plasma-nm/plasma-nm-5.0.2.ebuild
new file mode 100644
index 0000000..adb618a
--- /dev/null
+++ b/kde-base/plasma-nm/plasma-nm-5.0.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+LICENSE="GPL-2 LGPL-2.1"
+KEYWORDS=" ~amd64"
+IUSE="modemmanager openconnect"
+
+DEPEND="
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	$(add_frameworks_dep solid)
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	>=net-libs/libnm-qt-5.0
+	net-misc/mobile-broadband-provider-info
+	>=net-misc/networkmanager-0.9.8.0
+	modemmanager? ( >=net-libs/libmm-qt-5.0 )
+	openconnect? (
+		net-misc/networkmanager-openconnect
+		net-misc/openconnect
+	)
+"
+RDEPEND="${DEPEND}
+	!kde-misc/networkmanagement
+	!kde-misc/plasma-nm:4
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package modemmanager ModemManager)
+		$(cmake-utils_use_find_package modemmanager KF5ModemManagerQt)
+		$(cmake-utils_use_find_package openconnect OpenConnect)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.0.2.ebuild b/kde-base/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.0.2.ebuild
new file mode 100644
index 0000000..d1db0cf
--- /dev/null
+++ b/kde-base/plasma-workspace-wallpapers/plasma-workspace-wallpapers-5.0.2.ebuild
@@ -0,0 +1,16 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_AUTODEPS="false"
+KDE_DEBUG="false"
+KDE_SCM="svn"
+inherit kde5
+
+DESCRIPTION="Additional wallpapers for the Plasma workspace"
+KEYWORDS=" ~amd64"
+IUSE=""
+
+DEPEND="dev-libs/extra-cmake-modules"

diff --git a/kde-base/plasma-workspace/plasma-workspace-5.0.2.ebuild b/kde-base/plasma-workspace/plasma-workspace-5.0.2.ebuild
new file mode 100644
index 0000000..0044ebd
--- /dev/null
+++ b/kde-base/plasma-workspace/plasma-workspace-5.0.2.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KDE Plasma workspace"
+KEYWORDS=" ~amd64"
+IUSE="dbus gps prison qalculate X"
+
+COMMON_DEPEND="
+	$(add_kdebase_dep libksysguard)
+	$(add_kdebase_dep baloo)
+	$(add_kdebase_dep kwin)
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdeclarative)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep kdesu)
+	$(add_frameworks_dep kdewebkit)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kidletime)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep kjs)
+	$(add_frameworks_dep kjsembed)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep krunner)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktexteditor)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwallet)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep plasma)
+	$(add_frameworks_dep solid)
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5[jpeg]
+	dev-qt/qtnetwork:5
+	dev-qt/qtscript:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-libs/phonon[qt5]
+	sys-libs/pam
+	sys-libs/zlib
+	x11-libs/libkscreen:5
+	dbus? ( dev-libs/libdbusmenu-qt[qt5] )
+	gps? ( sci-geosciences/gpsd )
+	prison? ( media-libs/prison:5 )
+	qalculate? ( sci-libs/libqalculate )
+	X? (
+		dev-qt/qtx11extras:5
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXau
+		x11-libs/libxcb
+		x11-libs/libXrender
+		x11-libs/xcb-util-keysyms
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kded)
+	$(add_kdebase_dep milou)
+	dev-qt/qdbus:5
+	dev-qt/qtpaths:5
+	dev-qt/qtquickcontrols:5[widgets]
+	!kde-base/freespacenotifier:4
+	!kde-base/libkworkspace:4
+	!kde-base/libtaskmanager:4
+	!kde-base/kcminit:4
+	!kde-base/kdebase-startkde:4
+	!kde-base/klipper:4
+	!kde-base/krunner:4
+	!kde-base/ksmserver:4
+	!kde-base/ksplash:4
+	!kde-base/plasma-workspace:4
+"
+DEPEND="${COMMON_DEPEND}
+	X? ( x11-proto/xproto )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-startkde-script.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package dbus dbusmenu-qt5)
+		$(cmake-utils_use_find_package gps libgps)
+		$(cmake-utils_use_find_package prison)
+		$(cmake-utils_use_find_package qalculate Qalculate)
+		$(cmake-utils_use_find_package X X11)
+	)
+
+	kde5_src_configure
+}
+
+src_install() {
+	kde5_src_install
+
+	# startup and shutdown scripts
+	insinto /etc/plasma/startup
+	doins "${FILESDIR}/agent-startup.sh"
+
+	insinto /etc/plasma/shutdown
+	doins "${FILESDIR}/agent-shutdown.sh"
+}
+
+pkg_postinst () {
+	kde5_pkg_postinst
+
+	echo
+	elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
+	elog "edit ${EPREFIX}/etc/plasma/startup/agent-startup.sh and"
+	elog "${EPREFIX}/etc/plasma/shutdown/agent-shutdown.sh"
+	echo
+}

diff --git a/kde-base/powerdevil/powerdevil-5.0.2.ebuild b/kde-base/powerdevil/powerdevil-5.0.2.ebuild
new file mode 100644
index 0000000..f59e87d
--- /dev/null
+++ b/kde-base/powerdevil/powerdevil-5.0.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit kde5
+
+DESCRIPTION="Power management for KDE Plasma Shell"
+HOMEPAGE="https://projects.kde.org/projects/kde/workspace/powerdevil"
+KEYWORDS=" ~amd64"
+IUSE="+upower"
+
+DEPEND="
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep kglobalaccel)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kidletime)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_kdebase_dep plasma-workspace)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXext
+	x11-libs/libXrandr
+	upower? ( virtual/udev )
+"
+
+RDEPEND="
+	${DEPEND}
+	upower? ( || ( >=sys-power/upower-0.9.23 sys-power/upower-pm-utils ) )
+	!kde-base/powerdevil:4
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package upower UDev)
+	)
+
+	kde5_src_configure
+}

diff --git a/kde-base/systemsettings/systemsettings-5.0.2.ebuild b/kde-base/systemsettings/systemsettings-5.0.2.ebuild
new file mode 100644
index 0000000..9208993
--- /dev/null
+++ b/kde-base/systemsettings/systemsettings-5.0.2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="true"
+inherit kde5
+
+DESCRIPTION="System settings utility"
+LICENSE="GPL-2"
+KEYWORDS=" ~amd64"
+IUSE=""
+
+DEPEND="
+	$(add_frameworks_dep kauth)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdelibs4support)
+	$(add_frameworks_dep khtml)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+"
+RDEPEND="${DEPEND}
+	!kde-base/systemsettings:4
+"