[gentoo-commits] proj/kde:master commit in: app-office/akonadi-server/

["Johannes Huber" <johu@gentoo.org>]

commit:     11d3304ddb837c46430e5f6a73c77d8fa0192813
Author:     Johannes Huber <johu <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 10 11:42:50 2014 +0000
Commit:     Johannes Huber <johu <AT> gentoo <DOT> org>
CommitDate: Sun Aug 10 11:42:50 2014 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=11d3304d

[app-office/akonadi-server] Remove, newer version in tree

Package-Manager: portage-2.2.11-r1

---
 .../akonadi-server/akonadi-server-1.12.91.ebuild   | 128 ---------------------
 1 file changed, 128 deletions(-)

diff --git a/app-office/akonadi-server/akonadi-server-1.12.91.ebuild b/app-office/akonadi-server/akonadi-server-1.12.91.ebuild
deleted file mode 100644
index 93bc60a..0000000
--- a/app-office/akonadi-server/akonadi-server-1.12.91.ebuild
+++ /dev/null
@@ -1,128 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI=5
-
-if [[ $PV = *9999* ]]; then
-	scm_eclass=git-r3
-	EGIT_REPO_URI=( "git://anongit.kde.org/akonadi" )
-	SRC_URI=""
-	KEYWORDS=""
-else
-	SRC_URI="mirror://kde/stable/${PN/-server/}/src/${P/-server/}.tar.bz2"
-	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
-	S="${WORKDIR}/${P/-server/}"
-fi
-
-inherit cmake-utils ${scm_eclass}
-
-DESCRIPTION="The server part of Akonadi"
-HOMEPAGE="http://pim.kde.org/akonadi"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-IUSE="+mysql postgres +qt4 qt5 soprano sqlite test"
-
-REQUIRED_USE="^^ ( qt4 qt5 ) || ( sqlite mysql postgres )"
-
-CDEPEND="
-	dev-libs/boost:=
-	x11-misc/shared-mime-info
-	qt4? (
-		>=dev-qt/qtcore-4.8.5:4
-		>=dev-qt/qtdbus-4.8.5:4
-		>=dev-qt/qtgui-4.8.5:4
-		>=dev-qt/qtsql-4.8.5:4[mysql?,postgres?]
-		>=dev-qt/qttest-4.8.5:4
-	)
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtdbus:5
-		dev-qt/qtgui:5
-		dev-qt/qtnetwork:5
-		dev-qt/qtsql:5[mysql?,postgres?]
-		dev-qt/qttest:5
-		dev-qt/qtwidgets:5
-		dev-qt/qtxml:5
-		soprano? ( dev-libs/soprano[-qt4,qt5] )
-	)
-	soprano? ( dev-libs/soprano )
-	sqlite? ( dev-db/sqlite:3 )
-"
-DEPEND="${CDEPEND}
-	dev-libs/libxslt
-	>=dev-util/automoc-0.9.88
-	test? ( sys-apps/dbus )
-"
-RDEPEND="${CDEPEND}
-	postgres? ( dev-db/postgresql-server )
-"
-
-RESTRICT="test"
-
-pkg_setup() {
-	# Set default storage backend in order: MySQL, SQLite PostgreSQL
-	# reverse driver check to keep the order
-	if use postgres; then
-		DRIVER="QPSQL"
-		AVAILABLE+=" ${DRIVER}"
-	fi
-
-	if use sqlite; then
-		DRIVER="QSQLITE3"
-		AVAILABLE+=" ${DRIVER}"
-	fi
-
-	if use mysql; then
-		DRIVER="QMYSQL"
-		AVAILABLE+=" ${DRIVER}"
-	fi
-
-	# Notify about MySQL is recommend by upstream
-	if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
-		ewarn
-		ewarn "We strongly recommend you change your Akonadi database backend to MySQL in your"
-		ewarn "user configuration. This is the backend recommended by KDE upstream."
-		ewarn "In particular, kde-base/kmail-4.10 does not work properly with the sqlite"
-		ewarn "backend anymore."
-		ewarn "You can select the backend in your ~/.config/akonadi/akonadiserverrc."
-		ewarn "Available drivers are:${AVAILABLE}"
-		ewarn
-	fi
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DINSTALL_QSQLITE_IN_QT_PREFIX=ON
-		$(cmake-utils_use test AKONADI_BUILD_TESTS)
-		$(cmake-utils_use_with soprano)
-		$(cmake-utils_use sqlite AKONADI_BUILD_QSQLITE)
-		$(cmake-utils_use qt5 QT5_BUILD)
-	)
-
-	cmake-utils_src_configure
-}
-
-src_test() {
-	export $(dbus-launch)
-	cmake-utils_src_test
-}
-
-src_install() {
-	# Who knows, maybe it accidentally fixes our permission issues
-	cat <<-EOF > "${T}"/akonadiserverrc
-[%General]
-Driver=${DRIVER}
-EOF
-	insinto /usr/share/config/akonadi
-	doins "${T}"/akonadiserverrc
-
-	cmake-utils_src_install
-}
-
-pkg_postinst() {
-	elog "${DRIVER} has been set as your default akonadi storage backend."
-	elog "You can override it in your ~/.config/akonadi/akonadiserverrc."
-	elog "Available drivers are: ${AVAILABLE}"
-}