[gentoo-commits] proj/sci:master commit in: dev-python/specutils/

["Justin Lecher" <jlec@gentoo.org>]

commit:     ee14f2ab1333b59ae63b627c33fa8d93af362b92
Author:     Joseph Jon Booker <joe <AT> neoturbine <DOT> net>
AuthorDate: Fri Aug  8 20:09:23 2014 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Fri Aug  8 20:09:23 2014 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/sci.git;a=commit;h=ee14f2ab

dev-python/specutils: Add specutils package

Package-Manager: portage-2.2.11-r1

---
 dev-python/specutils/ChangeLog             |  9 +++++
 dev-python/specutils/metadata.xml          | 10 +++++
 dev-python/specutils/specutils-9999.ebuild | 59 ++++++++++++++++++++++++++++++
 3 files changed, 78 insertions(+)

diff --git a/dev-python/specutils/ChangeLog b/dev-python/specutils/ChangeLog
new file mode 100644
index 0000000..6447cd6
--- /dev/null
+++ b/dev-python/specutils/ChangeLog
@@ -0,0 +1,9 @@
+# ChangeLog for dev-python/specutils
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: $
+
+*specutils-9999 (08 Aug 2014)
+
+  08 Aug 2014; Joseph Jon Booker <joe@neoturbine.net> +metadata.xml,
+  +specutils-9999.ebuild:
+  dev-python/specutils: Add specutils package

diff --git a/dev-python/specutils/metadata.xml b/dev-python/specutils/metadata.xml
new file mode 100644
index 0000000..91594d0
--- /dev/null
+++ b/dev-python/specutils/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>sci-astronomy</herd>
+	<longdescription lang="en">
+		specutils is a package to implement utilities and data structures to
+		analyse astronomical spectra within python. It extends NDData from Astropy
+		into a class with special handling of 1D spectra.
+	</longdescription>
+</pkgmetadata>

diff --git a/dev-python/specutils/specutils-9999.ebuild b/dev-python/specutils/specutils-9999.ebuild
new file mode 100644
index 0000000..f8cfd5c
--- /dev/null
+++ b/dev-python/specutils/specutils-9999.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} )
+inherit distutils-r1
+
+if [ ${PV} == "9999" ] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/astropy/${PN}.git"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Affiliated package for 1D spectral operations"
+HOMEPAGE="https://github.com/astropy/specutils"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc"
+DOCS=( README.rst )
+
+RDEPEND="
+	>=dev-python/astropy-0.4[${PYTHON_USEDEP}]
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	sed -e '/import ah_bootstrap/d' -i setup.py || die "Removing ah_bootstrap failed"
+}
+
+python_compile_all() {
+	if use doc; then
+		python_export_best
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}" || die
+	"${EPYTHON}" -c "import ${PN}, sys;r = ${PN}.test(verbose=True);sys.exit(r)" \
+		|| die "tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}