[gentoo-commits] proj/lisp:master commit in: x11-wm/stumpwm/

["José María Alonso" <nimiux@gentoo.org>]

commit:     e89708c0dc80f95482f720fa14b889770b1a60af
Author:     Chema Alonso <nimiux <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 21 10:30:47 2014 +0000
Commit:     José María Alonso <nimiux <AT> gentoo <DOT> org>
CommitDate: Mon Jul 21 10:30:47 2014 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/lisp.git;a=commit;h=e89708c0

x11-wm/stumpwm: bump to version 0.9.8

---
 x11-wm/stumpwm/stumpwm-0.9.8.ebuild | 79 +++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

diff --git a/x11-wm/stumpwm/stumpwm-0.9.8.ebuild b/x11-wm/stumpwm/stumpwm-0.9.8.ebuild
new file mode 100644
index 0000000..3bcc4da
--- /dev/null
+++ b/x11-wm/stumpwm/stumpwm-0.9.8.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit common-lisp-3 glo-utils eutils elisp-common autotools
+
+DESCRIPTION="Stumpwm is a tiling, keyboard driven X11 Window Manager written entirely in Common Lisp."
+HOMEPAGE="http://www.nongnu.org/stumpwm/"
+SRC_URI="http://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="doc clisp ecl +sbcl emacs"
+
+RESTRICT="strip mirror"
+
+RDEPEND="dev-lisp/cl-ppcre
+		sbcl? ( >=dev-lisp/clx-0.7.3_p20081030 )
+		>=dev-lisp/cl-launch-2.11-r1
+		!sbcl? ( !clisp? ( !ecl? ( >=dev-lisp/sbcl-1.0.32 ) ) )
+		!sbcl? ( !clisp? (  ecl? ( >=dev-lisp/ecls-10.4.1 ) ) )
+		!sbcl? (  clisp? ( >=dev-lisp/clisp-2.44[X,new-clx] ) )
+		sbcl?  ( >=dev-lisp/sbcl-1.0.32 )
+		emacs? ( virtual/emacs app-emacs/slime )"
+DEPEND="${RDEPEND}
+		sys-apps/texinfo
+		doc? ( virtual/texi2dvi )"
+
+SITEFILE=70${PN}-gentoo.el
+
+do_doc() {
+	local pdffile="${PN}.pdf"
+
+	texi2pdf -o "${pdffile}" "${PN}.texi.in" && dodoc "${pdffile}" || die
+	cp "${FILESDIR}"/README.Gentoo . && sed -i "s:@VERSION@:${PV}:" README.Gentoo
+	dodoc AUTHORS NEWS README.md README.Gentoo
+	doinfo ${PN}.info
+	docinto examples ; dodoc sample-stumpwmrc.lisp
+}
+
+src_configure() {
+	eautoreconf
+	econf --with-lisp=$(glo_best_flag sbcl clisp ecl) \
+		--with-contrib-dir="${CLSOURCEROOT}/${PN}/contrib"
+}
+
+src_compile() {
+	emake -j1
+	if use emacs ; then
+		elisp-compile contrib/*.el || die "Cannot compile contrib Elisp files"
+	fi
+}
+
+src_install() {
+	common-lisp-export-impl-args $(glo_best_flag sbcl clisp ecl)
+	dobin stumpwm contrib/stumpish
+	make_session_desktop StumpWM /usr/bin/stumpwm
+
+	if use emacs; then
+		elisp-install ${PN} contrib/*.el{,c} || die "Cannot install contrib Elisp files"
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE} \
+			|| die "elisp-site-file-install failed"
+	fi
+
+	common-lisp-install-sources *.lisp contrib/
+	common-lisp-install-asdf ${PN}.asd
+	use doc && do_doc
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}