[gentoo-commits] proj/kde:master commit in: sys-auth/polkit-qt/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     adcdc0bec6632c50b4df11a0138aba8680553579
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Wed Jul  9 12:21:06 2014 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Wed Jul  9 12:21:06 2014 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=adcdc0be

[sys-auth/polkit-qt] Add snapshot.

Package-Manager: portage-2.2.10

---
 .../polkit-qt/polkit-qt-0.103.0_p20140709.ebuild   | 76 ++++++++++++++++++++++
 1 file changed, 76 insertions(+)

diff --git a/sys-auth/polkit-qt/polkit-qt-0.103.0_p20140709.ebuild b/sys-auth/polkit-qt/polkit-qt-0.103.0_p20140709.ebuild
new file mode 100644
index 0000000..69492ec
--- /dev/null
+++ b/sys-auth/polkit-qt/polkit-qt-0.103.0_p20140709.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+MY_P="${P/qt/qt-1}"
+inherit cmake-utils multibuild
+
+DESCRIPTION="PolicyKit Qt4 API wrapper library."
+HOMEPAGE="http://kde.org/"
+SRC_URI="http://dev.gentoo.org/~kensington/distfiles/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug examples +qt4 qt5"
+
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	dev-libs/glib:2
+	>=sys-auth/polkit-0.103
+	qt4? (
+		dev-qt/qtcore:4[glib]
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4[glib]
+	)
+	qt5? (
+		dev-qt/qtcore:5[glib]
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5[glib]
+		dev-qt/qtwidgets:5
+		examples? ( dev-qt/qtxml:5 )
+	)
+"
+DEPEND="${RDEPEND}
+	dev-util/automoc
+"
+
+DOCS=( AUTHORS README README.porting TODO )
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=()
+	use qt4 && MULTIBUILD_VARIANTS+=( qt4 )
+	use qt5 && MULTIBUILD_VARIANTS+=( qt5 )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			$(cmake-utils_use_build examples)
+		)
+
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]] ; then
+			mycmakeargs+=( -DUSE_QT4=ON )
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]] ; then
+			mycmakeargs+=( -DUSE_QT5=ON )
+		fi
+
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}