[gentoo-commits] proj/kde:master commit in: kde-base/kwin/, kde-base/libkworkspace/, kde-base/libplasmagenericshell/, ...

["Michael Palimaka" <kensington@gentoo.org>]

commit:     3bb3baf10dc549f1d27c7a96205aeda7c34ee89c
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 29 14:19:27 2014 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Sat Mar 29 14:19:27 2014 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=3bb3baf1

[kde-base] Add kde-workspace 4.11.8

---
 .../freespacenotifier-4.11.8.ebuild                |  12 ++
 kde-base/kcheckpass/kcheckpass-4.11.8.ebuild       |  33 +++++
 kde-base/kcminit/kcminit-4.11.8.ebuild             |  17 +++
 .../kdebase-cursors/kdebase-cursors-4.11.8.ebuild  |  13 ++
 .../kdebase-startkde-4.11.8.ebuild                 |  92 ++++++++++++
 kde-base/kdm/kdm-4.11.8.ebuild                     | 162 +++++++++++++++++++++
 kde-base/kephal/kephal-4.11.8.ebuild               |  25 ++++
 kde-base/khotkeys/khotkeys-4.11.8.ebuild           |  23 +++
 kde-base/kinfocenter/kinfocenter-4.11.8.ebuild     |  37 +++++
 kde-base/klipper/klipper-4.11.8.ebuild             |  31 ++++
 kde-base/kmenuedit/kmenuedit-4.11.8.ebuild         |  31 ++++
 kde-base/krunner/krunner-4.11.8.ebuild             |  51 +++++++
 kde-base/kscreensaver/kscreensaver-4.11.8.ebuild   |  22 +++
 kde-base/ksmserver/ksmserver-4.11.8.ebuild         |  38 +++++
 kde-base/ksplash/ksplash-4.11.8.ebuild             |  38 +++++
 .../kstartupconfig/kstartupconfig-4.11.8.ebuild    |  12 ++
 kde-base/kstyles/kstyles-4.11.8.ebuild             |  22 +++
 kde-base/ksysguard/ksysguard-4.11.8.ebuild         |  46 ++++++
 kde-base/ksystraycmd/ksystraycmd-4.11.8.ebuild     |  15 ++
 kde-base/kwin/kwin-4.11.8.ebuild                   |  80 ++++++++++
 kde-base/kwrited/kwrited-4.11.8.ebuild             |  16 ++
 kde-base/libkworkspace/libkworkspace-4.11.8.ebuild |  34 +++++
 .../liboxygenstyle/liboxygenstyle-4.11.8.ebuild    |  16 ++
 .../libplasmaclock/libplasmaclock-4.11.8.ebuild    |  33 +++++
 .../libplasmagenericshell-4.11.8.ebuild            |  28 ++++
 .../libtaskmanager/libtaskmanager-4.11.8.ebuild    |  35 +++++
 .../plasma-workspace-4.11.8.ebuild                 | 126 ++++++++++++++++
 kde-base/powerdevil/powerdevil-4.11.8.ebuild       |  32 ++++
 .../qguiplatformplugin_kde-4.11.8.ebuild           |  12 ++
 .../solid-actions-kcm-4.11.8.ebuild                |  19 +++
 .../systemsettings/systemsettings-4.11.8.ebuild    |  96 ++++++++++++
 31 files changed, 1247 insertions(+)

diff --git a/kde-base/freespacenotifier/freespacenotifier-4.11.8.ebuild b/kde-base/freespacenotifier/freespacenotifier-4.11.8.ebuild
new file mode 100644
index 0000000..afb0b93
--- /dev/null
+++ b/kde-base/freespacenotifier/freespacenotifier-4.11.8.ebuild
@@ -0,0 +1,12 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="A module that monitors free disk space on the home dir"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"

diff --git a/kde-base/kcheckpass/kcheckpass-4.11.8.ebuild b/kde-base/kcheckpass/kcheckpass-4.11.8.ebuild
new file mode 100644
index 0000000..1bf9b54
--- /dev/null
+++ b/kde-base/kcheckpass/kcheckpass-4.11.8.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="A simple password checker, used by any software in need of user authentication."
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug pam"
+
+RDEPEND="
+	pam? (
+		>=kde-base/kdebase-pam-7
+		virtual/pam
+	)
+"
+
+src_prepare() {
+	kde4-meta_src_prepare
+
+	use pam && epatch "${FILESDIR}/${PN}-4.4.2-no-SUID-no-GUID.patch"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with pam)
+	)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/kcminit/kcminit-4.11.8.ebuild b/kde-base/kcminit/kcminit-4.11.8.ebuild
new file mode 100644
index 0000000..1c8abe9
--- /dev/null
+++ b/kde-base/kcminit/kcminit-4.11.8.ebuild
@@ -0,0 +1,17 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="KCMInit - runs startups initialization for Control Modules."
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	x11-libs/libX11
+"
+RDEPEND="${DEPEND}"

diff --git a/kde-base/kdebase-cursors/kdebase-cursors-4.11.8.ebuild b/kde-base/kdebase-cursors/kdebase-cursors-4.11.8.ebuild
new file mode 100644
index 0000000..6d77197
--- /dev/null
+++ b/kde-base/kdebase-cursors/kdebase-cursors-4.11.8.ebuild
@@ -0,0 +1,13 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+KMMODULE="cursors"
+inherit kde4-meta
+
+DESCRIPTION="oxygen cursors from kdebase"
+IUSE=""
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"

diff --git a/kde-base/kdebase-startkde/kdebase-startkde-4.11.8.ebuild b/kde-base/kdebase-startkde/kdebase-startkde-4.11.8.ebuild
new file mode 100644
index 0000000..cfa6b8c
--- /dev/null
+++ b/kde-base/kdebase-startkde/kdebase-startkde-4.11.8.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+KMNOMODULE="true"
+inherit kde4-meta prefix
+
+DESCRIPTION="Startkde script, which starts a complete KDE session, and associated scripts"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+wallpapers"
+
+# The KDE apps called from the startkde script.
+# These provide the most minimal KDE desktop.
+RDEPEND="
+	$(add_kdebase_dep kcminit)
+	$(add_kdebase_dep kdebase-runtime-meta)
+	wallpapers? ( $(add_kdebase_dep kde-wallpapers) )
+	$(add_kdebase_dep kfmclient)
+	$(add_kdebase_dep knotify)
+	$(add_kdebase_dep kreadconfig)
+	$(add_kdebase_dep krunner)
+	$(add_kdebase_dep ksmserver)
+	$(add_kdebase_dep ksplash)
+	$(add_kdebase_dep kstartupconfig)
+	$(add_kdebase_dep kwin)
+	$(add_kdebase_dep phonon-kde)
+	$(add_kdebase_dep plasma-apps)
+	$(add_kdebase_dep plasma-workspace)
+	$(add_kdebase_dep systemsettings)
+	x11-apps/mkfontdir
+	x11-apps/xmessage
+	x11-apps/xprop
+	x11-apps/xrandr
+	x11-apps/xrdb
+	x11-apps/xsetroot
+	x11-apps/xset
+"
+
+KMEXTRACTONLY="
+	ConfigureChecks.cmake
+	kdm/
+	startkde.cmake
+"
+
+PATCHES=("${FILESDIR}/gentoo-startkde4-4.patch")
+
+src_prepare() {
+	kde4-meta_src_prepare
+
+	cp "${FILESDIR}/KDE-4" "${T}"
+
+	# fix ${EPREFIX}
+	eprefixify startkde.cmake "${T}/KDE-4"
+}
+
+src_install() {
+	kde4-meta_src_install
+
+	# startup and shutdown scripts
+	insinto /etc/kde/startup
+	doins "${FILESDIR}/agent-startup.sh"
+
+	insinto /etc/kde/shutdown
+	doins "${FILESDIR}/agent-shutdown.sh"
+
+	# x11 session script
+	exeinto /etc/X11/Sessions
+	doexe "${T}/KDE-4"
+
+	# freedesktop compliant session script
+	sed -e "s:\${BIN_INSTALL_DIR}:${EPREFIX}/usr/bin:g" \
+		"${S}/kdm/kfrontend/sessions/kde-plasma.desktop.cmake" > "${T}/KDE-4.desktop"
+	insinto /usr/share/xsessions
+	doins "${T}/KDE-4.desktop"
+}
+
+pkg_postinst () {
+	kde4-meta_pkg_postinst
+
+	echo
+	elog "To enable gpg-agent and/or ssh-agent in KDE sessions,"
+	elog "edit ${EPREFIX}/etc/kde/startup/agent-startup.sh and"
+	elog "${EPREFIX}/etc/kde/shutdown/agent-shutdown.sh"
+	echo
+	elog "The name of the session script has changed."
+	elog "If you currently have XSESSION=\"kde-$(get_kde_version)\" in your"
+	elog "configuration files, you will need to change it to"
+	elog "XSESSION=\"KDE-4\""
+}

diff --git a/kde-base/kdm/kdm-4.11.8.ebuild b/kde-base/kdm/kdm-4.11.8.ebuild
new file mode 100644
index 0000000..97d0aa1
--- /dev/null
+++ b/kde-base/kdm/kdm-4.11.8.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+inherit systemd kde4-meta flag-o-matic user
+
+DESCRIPTION="KDE login manager, similar to xdm and gdm"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug +consolekit kerberos pam systemd"
+
+REQUIRED_USE="consolekit? ( !systemd ) systemd? ( !consolekit )"
+
+DEPEND="
+	$(add_kdebase_dep libkworkspace)
+	media-libs/qimageblitz
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	x11-libs/libXtst
+	consolekit? (
+		>=sys-apps/dbus-1.0.2
+		sys-auth/consolekit
+	)
+	kerberos? ( virtual/krb5 )
+	pam? (
+		$(add_kdebase_dep kcheckpass)
+		virtual/pam
+	)
+	systemd? ( sys-apps/systemd )
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep kdepasswd)
+	>=x11-apps/xinit-1.0.5-r2
+	x11-apps/xmessage
+"
+
+KMEXTRA="
+	libs/kdm/
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4-gentoo-xinitrc.d.patch"
+)
+
+pkg_setup() {
+	kde4-meta_pkg_setup
+
+	# Create kdm:kdm user
+	KDM_HOME=/var/lib/kdm
+	enewgroup kdm
+	enewuser kdm -1 -1 "${KDM_HOME}" kdm
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use kerberos KDE4_KRB5AUTH)
+		$(cmake-utils_use_with pam)
+		$(cmake-utils_use_with consolekit CkConnector)
+	)
+
+	kde4-meta_src_configure
+}
+
+src_install() {
+	export GENKDMCONF_FLAGS="--no-old --no-backup"
+
+	kde4-meta_src_install
+
+	# an equivalent file is already installed by kde-base/startkde, bug 377151
+	rm "${ED}/usr/share/apps/kdm/sessions/kde-plasma.desktop" || die
+
+	# Customize the kdmrc configuration:
+	# - SessionDirs set to /usr/share/xsessions
+	# - increase server timeout to 30s
+	# - TerminateServer=true to workaround X server regen bug, bug 278473
+	# - DataDir set to /var/lib/kdm
+	# - FaceDir set to /var/lib/kdm/faces
+	sed -e "s|^.*SessionsDirs=.*$|#&\nSessionsDirs=${EPREFIX}/usr/share/apps/kdm/sessions,${EPREFIX}/usr/share/xsessions|" \
+		-e "/#ServerTimeout=/s/^.*$/ServerTimeout=30/" \
+		-e "/#TerminateServer=/s/^.*$/TerminateServer=true/" \
+		-e "s|^.*DataDir=.*$|#&\nDataDir=${EPREFIX}${KDM_HOME}|" \
+		-e "s|^.*FaceDir=.*$|#&\nFaceDir=${EPREFIX}${KDM_HOME}/faces|" \
+		-i "${ED}"/usr/share/config/kdm/kdmrc \
+		|| die "Failed to set ServerTimeout and SessionsDirs correctly in kdmrc."
+
+	# Don't install empty dir
+	rmdir "${ED}"/usr/share/config/kdm/sessions
+
+	# Set up permissions to kdm work directory
+	keepdir "${KDM_HOME}"
+	fowners root:kdm "${KDM_HOME}"
+	fperms 1770 "${KDM_HOME}"
+
+	# install logrotate file
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/kdm-logrotate kdm
+
+	systemd_dounit "${FILESDIR}"/kdm.service
+}
+
+pkg_postinst() {
+	kde4-meta_pkg_postinst
+
+	local file src dest dir old_dirs=(
+		/var/lib/kdm-live
+		/var/lib/kdm-4.6
+		/var/lib/kdm-4.5
+		/var/lib/kdm-4.4
+		/usr/share/apps/kdm
+		/usr/kde/4.4/share/apps/kdm
+		/usr/kde/4.3/share/apps/kdm
+		/usr/kde/4.2/share/apps/kdm
+	)
+
+	mkdir -p "${EROOT}${KDM_HOME}/faces"
+	# Set the default kdm face icon if it's not already set by the system admin
+	# because this is user-overrideable in that way, it's not in src_install
+	for file in faces/.default.face.icon:default1.png faces/root.face.icon:root1.png kdmsts: ; do
+		src=${file#*:}
+		dest=${file%:*}
+		if [[ ! -e ${EROOT}${KDM_HOME}/$dest ]]; then
+			for dir in "${old_dirs[@]}"; do
+				if [[ -e ${EROOT}${dir}/${dest} ]]; then
+					cp "${EROOT}${dir}/${dest}" "${EROOT}${KDM_HOME}/${dest}"
+					break 2
+				fi
+			done
+			if [[ -n ${src} ]]; then
+				cp "${EROOT}/usr/share/apps/kdm/pics/users/${src}" \
+					"${EROOT}${KDM_HOME}/${dest}"
+			fi
+		fi
+	done
+	for dir in "${old_dirs[@]}"; do
+		if [[ ${dir} != /usr/* && -d ${EROOT}${dir} ]]; then
+			echo
+			elog "The directory ${EROOT%/}${dir} still exists from an older installation of KDE."
+			elog "You may wish to copy relevant settings into ${EROOT%/}${KDM_HOME}."
+			echo
+			elog "After doing so, you may delete the directory."
+			echo
+		fi
+	done
+
+	# Make sure permissions are correct -- old installations may have
+	# gotten this wrong
+	use prefix || chown root:kdm "${EROOT}${KDM_HOME}"
+	chmod 1770 "${EROOT}${KDM_HOME}"
+
+	if use consolekit; then
+		echo
+		elog "You have compiled 'kdm' with consolekit support. If you want to use kdm,"
+		elog "make sure consolekit daemon is running and started at login time"
+		elog
+		elog "rc-update add consolekit default && /etc/init.d/consolekit start"
+		echo
+	fi
+}

diff --git a/kde-base/kephal/kephal-4.11.8.ebuild b/kde-base/kephal/kephal-4.11.8.ebuild
new file mode 100644
index 0000000..b5e7909
--- /dev/null
+++ b/kde-base/kephal/kephal-4.11.8.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+KMMODULE="libs/kephal"
+inherit kde4-meta
+
+DESCRIPTION="Allows handling of multihead systems via the XRandR extension"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXrandr
+"
+DEPEND="${RDEPEND}
+	x11-proto/randrproto
+"
+
+KMEXTRACTONLY+="
+	kephal/kephal/screens.h
+"

diff --git a/kde-base/khotkeys/khotkeys-4.11.8.ebuild b/kde-base/khotkeys/khotkeys-4.11.8.ebuild
new file mode 100644
index 0000000..094fafd
--- /dev/null
+++ b/kde-base/khotkeys/khotkeys-4.11.8.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="KDE: hotkey daemon"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep libkworkspace)
+	x11-libs/libX11
+	x11-libs/libXtst
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	libs/kworkspace/
+"

diff --git a/kde-base/kinfocenter/kinfocenter-4.11.8.ebuild b/kde-base/kinfocenter/kinfocenter-4.11.8.ebuild
new file mode 100644
index 0000000..18f0e4a
--- /dev/null
+++ b/kde-base/kinfocenter/kinfocenter-4.11.8.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+OPENGL_REQUIRED="optional"
+inherit kde4-meta
+
+DESCRIPTION="The KDE Info Center"
+HOMEPAGE="http://www.kde.org/applications/system/kinfocenter/"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug ieee1394"
+
+DEPEND="
+	sys-apps/pciutils
+	x11-libs/libX11
+	ieee1394? ( sys-libs/libraw1394 )
+	opengl? (
+		virtual/glu
+		virtual/opengl
+	)
+"
+RDEPEND="${DEPEND}
+	sys-apps/usbutils
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with ieee1394 RAW1394)
+		$(cmake-utils_use_with opengl OpenGL)
+	)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/klipper/klipper-4.11.8.ebuild b/kde-base/klipper/klipper-4.11.8.ebuild
new file mode 100644
index 0000000..8eac7dc
--- /dev/null
+++ b/kde-base/klipper/klipper-4.11.8.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="Applet for KDE and X clipboard management"
+HOMEPAGE+=" http://userbase.kde.org/Klipper"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug prison"
+
+DEPEND="
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep libtaskmanager)
+	sys-libs/zlib
+	x11-libs/libX11
+	prison? ( media-libs/prison )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with prison)
+	)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/kmenuedit/kmenuedit-4.11.8.ebuild b/kde-base/kmenuedit/kmenuedit-4.11.8.ebuild
new file mode 100644
index 0000000..10fab5d
--- /dev/null
+++ b/kde-base/kmenuedit/kmenuedit-4.11.8.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="KDE menu editor"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+RDEPEND="
+	$(add_kdebase_dep khotkeys)
+"
+DEPEND=${RDEPEND}
+
+KMEXTRACTONLY="
+	libs/kworkspace/
+"
+
+src_configure() {
+	sed -i -e \
+		"s:\${CMAKE_CURRENT_BINARY_DIR}/../khotkeys/app/org.kde.khotkeys.xml:${EPREFIX}/usr/share/dbus-1/interfaces/org.kde.khotkeys.xml:g" \
+		kmenuedit/CMakeLists.txt \
+		|| die "sed failed"
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/krunner/krunner-4.11.8.ebuild b/kde-base/krunner/krunner-4.11.8.ebuild
new file mode 100644
index 0000000..998221a
--- /dev/null
+++ b/kde-base/krunner/krunner-4.11.8.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+OPENGL_REQUIRED="optional"
+inherit kde4-meta
+
+DESCRIPTION="KDE Command Runner"
+HOMEPAGE+=" http://userbase.kde.org/Plasma/Krunner"
+IUSE="debug"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="
+	$(add_kdebase_dep kcheckpass)
+	$(add_kdebase_dep kephal)
+	$(add_kdebase_dep ksmserver)
+	$(add_kdebase_dep ksysguard)
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep libplasmagenericshell)
+	!aqua? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+		x11-libs/libXext
+	)
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	libs/kdm/
+	libs/kephal/
+	libs/ksysguard/
+	libs/kworkspace/
+	libs/plasmagenericshell/
+	kcheckpass/
+	ksmserver/org.kde.KSMServerInterface.xml
+	ksysguard/
+	plasma/screensaver/shell/org.kde.plasma-overlay.App.xml
+"
+
+KMLOADLIBS="libkworkspace"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with opengl OpenGL)
+	)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/kscreensaver/kscreensaver-4.11.8.ebuild b/kde-base/kscreensaver/kscreensaver-4.11.8.ebuild
new file mode 100644
index 0000000..7f205ee
--- /dev/null
+++ b/kde-base/kscreensaver/kscreensaver-4.11.8.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="KDE screensaver framework"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+RDEPEND="
+	$(add_kdebase_dep kcheckpass)
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.5.95-nsfw.patch"
+)

diff --git a/kde-base/ksmserver/ksmserver-4.11.8.ebuild b/kde-base/ksmserver/ksmserver-4.11.8.ebuild
new file mode 100644
index 0000000..e9bd71a
--- /dev/null
+++ b/kde-base/ksmserver/ksmserver-4.11.8.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+DECLARATIVE_REQUIRED="always"
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="The reliable KDE session manager that talks the standard X11R6"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kcminit)
+	$(add_kdebase_dep libkworkspace)
+	media-libs/qimageblitz
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXrender
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep kdm)
+"
+
+KMEXTRACTONLY="
+	kcminit/main.h
+	libs/kdm/kgreeterplugin.h
+	kcheckpass/
+	libs/kephal/
+	libs/kworkspace/
+"
+
+KMLOADLIBS="libkworkspace"
+
+PATCHES=( "${FILESDIR}/${PN}-4.11.97-noplasmalock.patch" )

diff --git a/kde-base/ksplash/ksplash-4.11.8.ebuild b/kde-base/ksplash/ksplash-4.11.8.ebuild
new file mode 100644
index 0000000..32cc943
--- /dev/null
+++ b/kde-base/ksplash/ksplash-4.11.8.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+DECLARATIVE_REQUIRED="always"
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="KDE splashscreen framework (the splashscreen of KDE itself, not of individual apps)"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="3dnow altivec debug mmx sse sse2 xinerama"
+
+COMMONDEPEND="
+	media-libs/libpng:0=
+	virtual/jpeg:0
+	x11-libs/libX11
+	x11-libs/libXext
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${COMMONDEPEND}
+	xinerama? ( x11-proto/xineramaproto )
+"
+RDEPEND="${COMMONDEPEND}"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_has 3dnow X86_3DNOW)
+		$(cmake-utils_use_has altivec PPC_ALTIVEC)
+		$(cmake-utils_use_has mmx X86_MMX)
+		$(cmake-utils_use_has sse X86_SSE)
+		$(cmake-utils_use_has sse2 X86_SSE2)
+		$(cmake-utils_use_with xinerama)
+	)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/kstartupconfig/kstartupconfig-4.11.8.ebuild b/kde-base/kstartupconfig/kstartupconfig-4.11.8.ebuild
new file mode 100644
index 0000000..41a7938
--- /dev/null
+++ b/kde-base/kstartupconfig/kstartupconfig-4.11.8.ebuild
@@ -0,0 +1,12 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="KDE: Utility to launch applications with special window properties"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"

diff --git a/kde-base/kstyles/kstyles-4.11.8.ebuild b/kde-base/kstyles/kstyles-4.11.8.ebuild
new file mode 100644
index 0000000..c607921
--- /dev/null
+++ b/kde-base/kstyles/kstyles-4.11.8.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="KDE: A set of different KDE styles."
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep liboxygenstyle)
+	x11-libs/libX11
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	libs/oxygen
+"

diff --git a/kde-base/ksysguard/ksysguard-4.11.8.ebuild b/kde-base/ksysguard/ksysguard-4.11.8.ebuild
new file mode 100644
index 0000000..0c8aaf0
--- /dev/null
+++ b/kde-base/ksysguard/ksysguard-4.11.8.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+CPPUNIT_REQUIRED="optional"
+VIRTUALX_REQUIRED="test"
+inherit kde4-meta
+
+DESCRIPTION="KSysguard is a network enabled task manager and system monitor application."
+HOMEPAGE+=" http://userbase.kde.org/KSysGuard"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug lm_sensors test"
+
+DEPEND="
+	sys-libs/zlib
+	x11-libs/libX11
+	x11-libs/libXres
+	lm_sensors? ( sys-apps/lm_sensors )
+"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test"
+# bug 393091
+
+KMEXTRA="
+	libs/ksysguard/
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with lm_sensors Sensors)
+	)
+
+	kde4-meta_src_configure
+}
+
+pkg_postinst() {
+	kde4-meta_pkg_postinst
+	ewarn "Note that ksysguard has powerful features; one of these is the executing of arbitrary"
+	ewarn "programs with elevated privileges (as data sources). So be careful opening worksheets"
+	ewarn "from untrusted sources!"
+}

diff --git a/kde-base/ksystraycmd/ksystraycmd-4.11.8.ebuild b/kde-base/ksystraycmd/ksystraycmd-4.11.8.ebuild
new file mode 100644
index 0000000..f81525e
--- /dev/null
+++ b/kde-base/ksystraycmd/ksystraycmd-4.11.8.ebuild
@@ -0,0 +1,15 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="Ksystraycmd embeds applications given as argument into the system tray."
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="x11-libs/libX11"
+RDEPEND="${DEPEND}"

diff --git a/kde-base/kwin/kwin-4.11.8.ebuild b/kde-base/kwin/kwin-4.11.8.ebuild
new file mode 100644
index 0000000..1ff9b25
--- /dev/null
+++ b/kde-base/kwin/kwin-4.11.8.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+DECLARATIVE_REQUIRED="always"
+OPENGL_REQUIRED="always"
+
+#VIRTUALX_REQUIRED=test
+RESTRICT=test
+# test 8: kwin-TestVirtualDesktops hangs even with virtualx
+
+inherit flag-o-matic kde4-meta
+
+DESCRIPTION="KDE window manager"
+HOMEPAGE+=" http://userbase.kde.org/KWin"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug gles opengl wayland"
+
+COMMONDEPEND="
+	$(add_kdebase_dep kactivities)
+	$(add_kdebase_dep kdelibs opengl)
+	$(add_kdebase_dep kephal)
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep liboxygenstyle)
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-keysyms
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	>=x11-libs/libXrandr-1.2.1
+	x11-libs/libXrender
+	x11-libs/libXxf86vm
+	opengl? ( >=media-libs/mesa-7.10 )
+	gles? ( >=media-libs/mesa-7.12[egl(+),gles2] )
+	wayland? ( >=media-libs/mesa-9.0[egl(+),wayland] )
+"
+DEPEND="${COMMONDEPEND}
+	x11-libs/xcb-util-renderutil
+	x11-proto/compositeproto
+	x11-proto/damageproto
+	x11-proto/fixesproto
+	x11-proto/randrproto
+	x11-proto/renderproto
+"
+RDEPEND="${COMMONDEPEND}
+	x11-apps/scripts
+"
+
+KMEXTRACTONLY="
+	ksmserver/
+	libs/kephal/
+	libs/oxygen/
+"
+
+# you need one of these
+REQUIRED_USE="!opengl? ( gles ) !gles? ( opengl ) wayland? ( gles )"
+
+src_configure() {
+	# FIXME Remove when activity API moved away from libkworkspace
+	append-cppflags "-I${EPREFIX}/usr/include/kworkspace"
+
+	mycmakeargs=(
+		$(cmake-utils_use_with gles OpenGLES)
+		$(cmake-utils_use gles KWIN_BUILD_WITH_OPENGLES)
+		$(cmake-utils_use_with opengl OpenGL)
+		$(cmake-utils_use_with wayland Wayland)
+		-DWITH_X11_Xcomposite=ON
+	)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/kwrited/kwrited-4.11.8.ebuild b/kde-base/kwrited/kwrited-4.11.8.ebuild
new file mode 100644
index 0000000..8515d9e
--- /dev/null
+++ b/kde-base/kwrited/kwrited-4.11.8.ebuild
@@ -0,0 +1,16 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="KDE daemon listening for wall and write messages."
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	|| ( >=sys-libs/libutempter-1.1.5 >=sys-freebsd/freebsd-lib-9.0 )
+"
+RDEPEND="${DEPEND}"

diff --git a/kde-base/libkworkspace/libkworkspace-4.11.8.ebuild b/kde-base/libkworkspace/libkworkspace-4.11.8.ebuild
new file mode 100644
index 0000000..75f587a
--- /dev/null
+++ b/kde-base/libkworkspace/libkworkspace-4.11.8.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+KMMODULE="libs/kworkspace"
+inherit kde4-meta
+
+DESCRIPTION="A library for KDE desktop applications"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+KMEXTRACTONLY="
+	ksmserver/org.kde.KSMServerInterface.xml
+	kwin/org.kde.KWin.xml
+"
+
+KMSAVELIBS="true"
+
+DEPEND="
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libXau
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	sed -i -e 's/install( FILES kdisplaymanager.h/install( FILES kdisplaymanager.h screenpreviewwidget.h/' \
+		libs/kworkspace/CMakeLists.txt || die "failed to provide screenpreviewwidget.h"
+
+	kde4-meta_src_prepare
+}

diff --git a/kde-base/liboxygenstyle/liboxygenstyle-4.11.8.ebuild b/kde-base/liboxygenstyle/liboxygenstyle-4.11.8.ebuild
new file mode 100644
index 0000000..c9c4fa0
--- /dev/null
+++ b/kde-base/liboxygenstyle/liboxygenstyle-4.11.8.ebuild
@@ -0,0 +1,16 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+KMMODULE="libs/oxygen"
+inherit kde4-meta
+
+DESCRIPTION="Library to support the Oxygen style in KDE"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="x11-libs/libX11"
+RDEPEND="${DEPEND}"

diff --git a/kde-base/libplasmaclock/libplasmaclock-4.11.8.ebuild b/kde-base/libplasmaclock/libplasmaclock-4.11.8.ebuild
new file mode 100644
index 0000000..2f86f37
--- /dev/null
+++ b/kde-base/libplasmaclock/libplasmaclock-4.11.8.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+KMMODULE="libs/plasmaclock"
+inherit kde4-meta
+
+DESCRIPTION="Libraries for KDE Plasma's clocks"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug semantic-desktop"
+
+DEPEND="
+	$(add_kdebase_dep kephal)
+	semantic-desktop? ( $(add_kdebase_dep kdepimlibs) )
+"
+RDEPEND="${DEPEND}"
+
+KMSAVELIBS="true"
+
+KMEXTRACTONLY="
+	libs/kephal/
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with semantic-desktop KdepimLibs)
+	)
+
+	kde4-meta_src_configure
+}

diff --git a/kde-base/libplasmagenericshell/libplasmagenericshell-4.11.8.ebuild b/kde-base/libplasmagenericshell/libplasmagenericshell-4.11.8.ebuild
new file mode 100644
index 0000000..d9466a0
--- /dev/null
+++ b/kde-base/libplasmagenericshell/libplasmagenericshell-4.11.8.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+DECLARATIVE_REQUIRED="always"
+KMNAME="kde-workspace"
+KMMODULE="libs/plasmagenericshell"
+inherit kde4-meta
+
+DESCRIPTION="Libraries for the KDE Plasma shell"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug test"
+
+DEPEND="
+	$(add_kdebase_dep kephal)
+	$(add_kdebase_dep libkworkspace)
+	x11-libs/libX11
+"
+RDEPEND="${DEPEND}"
+
+KMSAVELIBS="true"
+
+KMEXTRACTONLY="
+	libs/kephal/kephal/
+	plasma/desktop/shell/data/
+"

diff --git a/kde-base/libtaskmanager/libtaskmanager-4.11.8.ebuild b/kde-base/libtaskmanager/libtaskmanager-4.11.8.ebuild
new file mode 100644
index 0000000..31b2a1b
--- /dev/null
+++ b/kde-base/libtaskmanager/libtaskmanager-4.11.8.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+KMMODULE="libs/taskmanager"
+inherit kde4-meta
+
+DESCRIPTION="A library that provides basic taskmanager functionality"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kactivities)
+	$(add_kdebase_dep kephal)
+	$(add_kdebase_dep ksysguard)
+	$(add_kdebase_dep libkworkspace)
+	x11-libs/libX11
+"
+RDEPEND="${DEPEND}"
+
+KMSAVELIBS="true"
+
+KMEXTRACTONLY="
+	libs/kephal/
+	libs/kworkspace/
+"
+
+src_prepare() {
+	kde4-meta_src_prepare
+	sed -e 's:ksysguard/processcore/processes.h:ksysguard/processes.h:g' -i "${S}/libs/taskmanager/taskitem.cpp" || die
+	sed -e 's:ksysguard/processcore/process.h:ksysguard/process.h:g' -i "${S}/libs/taskmanager/taskitem.cpp" || die
+}

diff --git a/kde-base/plasma-workspace/plasma-workspace-4.11.8.ebuild b/kde-base/plasma-workspace/plasma-workspace-4.11.8.ebuild
new file mode 100644
index 0000000..2bba34b
--- /dev/null
+++ b/kde-base/plasma-workspace/plasma-workspace-4.11.8.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+DECLARATIVE_REQUIRED="always"
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+KMMODULE="plasma"
+PYTHON_COMPAT=( python2_{6,7} )
+OPENGL_REQUIRED="always"
+inherit python-single-r1 kde4-meta
+
+DESCRIPTION="Plasma: KDE desktop framework"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug gps json python qalculate semantic-desktop"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMONDEPEND="
+	dev-libs/libdbusmenu-qt
+	>=dev-qt/qtcore-4.8.4-r3:4
+	!kde-misc/ktouchpadenabler
+	$(add_kdebase_dep kactivities)
+	$(add_kdebase_dep kdelibs 'semantic-desktop?')
+	$(add_kdebase_dep kephal)
+	$(add_kdebase_dep ksysguard)
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep libplasmaclock 'semantic-desktop?')
+	$(add_kdebase_dep libplasmagenericshell)
+	$(add_kdebase_dep libtaskmanager)
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrender
+	gps? ( >=sci-geosciences/gpsd-2.37 )
+	json? ( dev-libs/qjson )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/PyQt4-4.4.0[X,${PYTHON_USEDEP}]
+		$(add_kdebase_dep pykde4 "${PYTHON_USEDEP}")
+	)
+	qalculate? ( sci-libs/libqalculate )
+	semantic-desktop? (
+		dev-libs/soprano
+		$(add_kdebase_dep kdepimlibs)
+		$(add_kdebase_dep nepomuk-core)
+	)
+"
+DEPEND="${COMMONDEPEND}
+	dev-libs/boost
+	x11-proto/compositeproto
+	x11-proto/damageproto
+	x11-proto/fixesproto
+	x11-proto/renderproto
+"
+RDEPEND="${COMMONDEPEND}
+	$(add_kdebase_dep plasma-runtime)
+"
+
+KMEXTRA="
+	appmenu/
+	ktouchpadenabler/
+	statusnotifierwatcher/
+"
+KMEXTRACTONLY="
+	kcheckpass/
+	krunner/dbus/org.freedesktop.ScreenSaver.xml
+	krunner/dbus/org.kde.krunner.App.xml
+	ksmserver/org.kde.KSMServerInterface.xml
+	ksmserver/screenlocker/
+	libs/kephal/
+	libs/kworkspace/
+	libs/taskmanager/
+	libs/plasmagenericshell/
+	libs/ksysguard/
+	libs/kdm/kgreeterplugin.h
+	ksysguard/
+"
+
+KMLOADLIBS="libkworkspace libplasmaclock libplasmagenericshell libtaskmanager"
+
+PATCHES=( "${FILESDIR}/${PN}-4.10.1-noplasmalock.patch" )
+
+pkg_setup() {
+	if use python ; then
+		python-single-r1_pkg_setup
+	fi
+	kde4-meta_pkg_setup
+}
+
+src_unpack() {
+	if use handbook; then
+		KMEXTRA+=" doc/plasma-desktop"
+	fi
+
+	kde4-meta_src_unpack
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with gps libgps)
+		$(cmake-utils_use_with json QJSON)
+		$(cmake-utils_use_with python PythonLibrary)
+		$(cmake-utils_use_with qalculate)
+		$(cmake-utils_use_with semantic-desktop Akonadi)
+		$(cmake-utils_use_with semantic-desktop KdepimLibs)
+		$(cmake-utils_use_with semantic-desktop NepomukCore)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		-DWITH_Xmms=OFF
+	)
+
+	kde4-meta_src_configure
+}
+
+src_install() {
+	kde4-meta_src_install
+
+	if use python; then
+		python_optimize "${ED}"
+	fi
+}

diff --git a/kde-base/powerdevil/powerdevil-4.11.8.ebuild b/kde-base/powerdevil/powerdevil-4.11.8.ebuild
new file mode 100644
index 0000000..e746969
--- /dev/null
+++ b/kde-base/powerdevil/powerdevil-4.11.8.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="PowerDevil is an utility for KDE4 for Laptop Powermanagement."
+HOMEPAGE="http://solid.kde.org"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug +pm-utils"
+
+DEPEND="
+	$(add_kdebase_dep kactivities)
+	$(add_kdebase_dep libkworkspace)
+	!aqua? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXrandr
+	)
+"
+RDEPEND="${DEPEND}
+	pm-utils? ( sys-power/pm-utils )
+"
+
+KMEXTRACTONLY="
+	krunner/
+	ksmserver/org.kde.KSMServerInterface.xml
+	ksmserver/screenlocker/dbus/org.freedesktop.ScreenSaver.xml
+"

diff --git a/kde-base/qguiplatformplugin_kde/qguiplatformplugin_kde-4.11.8.ebuild b/kde-base/qguiplatformplugin_kde/qguiplatformplugin_kde-4.11.8.ebuild
new file mode 100644
index 0000000..d34e835
--- /dev/null
+++ b/kde-base/qguiplatformplugin_kde/qguiplatformplugin_kde-4.11.8.ebuild
@@ -0,0 +1,12 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+inherit kde4-meta
+
+DESCRIPTION="Helps integration of pure Qt applications with KDE Workspace"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"

diff --git a/kde-base/solid-actions-kcm/solid-actions-kcm-4.11.8.ebuild b/kde-base/solid-actions-kcm/solid-actions-kcm-4.11.8.ebuild
new file mode 100644
index 0000000..3d83541
--- /dev/null
+++ b/kde-base/solid-actions-kcm/solid-actions-kcm-4.11.8.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kde-workspace"
+CPPUNIT_REQUIRED="test"
+inherit kde4-meta
+
+DESCRIPTION="KDE control module for Solid actions"
+HOMEPAGE="http://solid.kde.org"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+RDEPEND="
+	$(add_kdebase_dep solid-runtime)
+	!kde-base/solid:4
+"

diff --git a/kde-base/systemsettings/systemsettings-4.11.8.ebuild b/kde-base/systemsettings/systemsettings-4.11.8.ebuild
new file mode 100644
index 0000000..743af24
--- /dev/null
+++ b/kde-base/systemsettings/systemsettings-4.11.8.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+OPENGL_REQUIRED="optional"
+VIRTUALX_REQUIRED="test"
+VIRTUALDBUS_TEST="true"
+inherit kde4-meta
+
+DESCRIPTION="System settings utility"
+HOMEPAGE+=" http://userbase.kde.org/System_Settings"
+IUSE="debug gtk semantic-desktop +usb"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+
+COMMONDEPEND="
+	app-misc/strigi
+	dev-libs/glib:2
+	$(add_kdebase_dep kwin)
+	$(add_kdebase_dep libkworkspace)
+	media-libs/fontconfig
+	>=media-libs/freetype-2
+	>=x11-libs/libxklavier-3.2
+	x11-libs/libX11
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXi
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	opengl? ( virtual/opengl )
+	usb? ( virtual/libusb:0 )
+"
+DEPEND="${COMMONDEPEND}
+	x11-proto/kbproto
+	x11-proto/xextproto
+"
+RDEPEND="${COMMONDEPEND}
+	sys-libs/timezone-data
+	x11-apps/setxkbmap
+	x11-misc/xkeyboard-config
+	gtk? ( kde-misc/kde-gtk-config )
+	semantic-desktop? ( $(add_kdebase_dep nepomuk) )
+"
+
+KMEXTRA="
+	kcontrol/
+"
+KMEXTRACTONLY="
+	krunner/dbus/org.kde.krunner.App.xml
+	krunner/dbus/org.kde.screensaver.xml
+	ksmserver/screenlocker/dbus/org.kde.screensaver.xml
+	kwin/
+	libs/
+	plasma/
+"
+
+PATCHES=( "${FILESDIR}/${PN}-4.10.1-noplasmalock.patch" )
+
+src_unpack() {
+	if use handbook; then
+		KMEXTRA+="
+			doc/kcontrol
+			doc/kfontview
+		"
+	fi
+
+	kde4-meta_src_unpack
+}
+
+src_prepare() {
+	sed -i -e 's/systemsettingsrc DESTINATION ${SYSCONF_INSTALL_DIR}/systemsettingsrc DESTINATION ${CONFIG_INSTALL_DIR}/' \
+		systemsettings/CMakeLists.txt \
+		|| die "Failed to fix systemsettingsrc install location"
+
+	kde4-meta_src_prepare
+}
+
+# FIXME: is have_openglxvisual found without screensaver
+src_configure() {
+	# Old keyboard-detection code is unmaintained,
+	# so we force the new stuff, using libxklavier.
+	mycmakeargs=(
+		-DUSE_XKLAVIER=ON -DWITH_LibXKlavier=ON
+		-DWITH_GLIB2=ON -DWITH_GObject=ON
+		$(cmake-utils_use_with opengl OpenGL)
+		$(cmake-utils_use_with usb)
+	)
+
+	kde4-meta_src_configure
+}