[gentoo-commits] proj/gnome:master commit in: app-cdr/brasero/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     35fe897a40b432673c0ed00e7c5a26d75af82bbc
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 12 22:41:43 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Thu Dec 12 23:20:46 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=35fe897a

app-cdr/brasero: 3.8.0 → 3.10.0

---
 app-cdr/brasero/brasero-3.10.0.ebuild | 82 +++++++++++++++++++++++++++++++++++
 app-cdr/brasero/brasero-9999.ebuild   | 69 +++++++++++++++--------------
 2 files changed, 118 insertions(+), 33 deletions(-)

diff --git a/app-cdr/brasero/brasero-3.10.0.ebuild b/app-cdr/brasero/brasero-3.10.0.ebuild
new file mode 100644
index 0000000..ca32566
--- /dev/null
+++ b/app-cdr/brasero/brasero-3.10.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="CD/DVD burning application for the GNOME desktop"
+HOMEPAGE="http://projects.gnome.org/brasero/"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0/3.1" # subslot is 3.suffix of libbrasero-burn3
+IUSE="+css +introspection +libburn mp3 nautilus packagekit playlist test tracker"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.29.14:2
+	>=x11-libs/gtk+-3:3[introspection?]
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=dev-libs/libxml2-2.6:2
+	>=x11-libs/libnotify-0.6.1:=
+
+	media-libs/libcanberra[gtk3]
+	x11-libs/libICE
+	x11-libs/libSM
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.3 )
+	libburn? (
+		>=dev-libs/libburn-0.4:=
+		>=dev-libs/libisofs-0.6.4:= )
+	nautilus? ( >=gnome-base/nautilus-2.91.90 )
+	playlist? ( >=dev-libs/totem-pl-parser-2.29.1:= )
+	tracker? ( >=app-misc/tracker-0.12:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	media-libs/gst-plugins-good:1.0
+	media-plugins/gst-plugins-meta:1.0
+	x11-themes/hicolor-icon-theme
+	css? ( media-libs/libdvdcss:1.2 )
+	!libburn? (
+		app-cdr/cdrdao
+		app-cdr/dvd+rw-tools
+		virtual/cdrtools )
+	mp3? (
+		media-libs/gst-plugins-ugly:1.0
+		media-plugins/gst-plugins-mad:1.0 )
+	packagekit? ( app-admin/packagekit-base )
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	dev-util/intltool
+	>=dev-util/gtk-doc-am-1.12
+	gnome-base/gnome-common:3
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( app-text/docbook-xml-dtd:4.3 )
+"
+# eautoreconf deps
+#	app-text/yelp-tools
+#	gnome-base/gnome-common
+
+PDEPEND="gnome-base/gvfs"
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
+	gnome2_src_configure \
+		--disable-caches \
+		$(use_enable !libburn cdrtools) \
+		$(use_enable !libburn cdrkit) \
+		$(use_enable !libburn cdrdao) \
+		$(use_enable !libburn growisofs) \
+		$(use_enable introspection) \
+		$(use_enable libburn libburnia) \
+		$(use_enable nautilus) \
+		$(use_enable playlist) \
+		$(use_enable tracker search) \
+		ITSTOOL=$(type -P true)
+}

diff --git a/app-cdr/brasero/brasero-9999.ebuild b/app-cdr/brasero/brasero-9999.ebuild
index 77a321a..8030853 100644
--- a/app-cdr/brasero/brasero-9999.ebuild
+++ b/app-cdr/brasero/brasero-9999.ebuild
@@ -1,8 +1,8 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
-EAPI="4"
+EAPI="5"
 GCONF_DEBUG="no"
 GNOME2_LA_PUNT="yes"
 
@@ -11,11 +11,11 @@ if [[ ${PV} = 9999 ]]; then
 	inherit gnome2-live
 fi
 
-DESCRIPTION="Brasero (aka Bonfire) is yet another application to burn CD/DVD for the gnome desktop."
+DESCRIPTION="CD/DVD burning application for the GNOME desktop"
 HOMEPAGE="http://projects.gnome.org/brasero/"
 
-LICENSE="GPL-2"
-SLOT="0"
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0/3.1" # subslot is 3.suffix of libbrasero-burn3
 IUSE="+css +introspection +libburn mp3 nautilus packagekit playlist test tracker"
 if [[ ${PV} = 9999 ]]; then
 	IUSE="${IUSE} doc"
@@ -26,11 +26,11 @@ fi
 
 COMMON_DEPEND="
 	>=dev-libs/glib-2.29.14:2
-	>=x11-libs/gtk+-3.0.0:3[introspection?]
+	>=x11-libs/gtk+-3:3[introspection?]
 	media-libs/gstreamer:1.0
 	media-libs/gst-plugins-base:1.0
 	>=dev-libs/libxml2-2.6:2
-	>=x11-libs/libnotify-0.6.1
+	>=x11-libs/libnotify-0.6.1:=
 
 	media-libs/libcanberra[gtk3]
 	x11-libs/libICE
@@ -38,13 +38,15 @@ COMMON_DEPEND="
 
 	introspection? ( >=dev-libs/gobject-introspection-0.6.3 )
 	libburn? (
-		>=dev-libs/libburn-0.4
-		>=dev-libs/libisofs-0.6.4 )
+		>=dev-libs/libburn-0.4:=
+		>=dev-libs/libisofs-0.6.4:= )
 	nautilus? ( >=gnome-base/nautilus-2.91.90 )
-	playlist? ( >=dev-libs/totem-pl-parser-2.29.1 )
-	tracker? ( >=app-misc/tracker-0.12 )"
+	playlist? ( >=dev-libs/totem-pl-parser-2.29.1:= )
+	tracker? ( >=app-misc/tracker-0.12:= )
+"
 RDEPEND="${COMMON_DEPEND}
 	media-libs/gst-plugins-good:1.0
+	media-plugins/gst-plugins-meta:1.0
 	x11-themes/hicolor-icon-theme
 	css? ( media-libs/libdvdcss:1.2 )
 	!libburn? (
@@ -54,7 +56,8 @@ RDEPEND="${COMMON_DEPEND}
 	mp3? (
 		media-libs/gst-plugins-ugly:1.0
 		media-plugins/gst-plugins-mad:1.0 )
-	packagekit? ( app-admin/packagekit-base )"
+	packagekit? ( app-admin/packagekit-base )
+"
 DEPEND="${COMMON_DEPEND}
 	app-text/yelp-tools
 	dev-util/intltool
@@ -62,37 +65,37 @@ DEPEND="${COMMON_DEPEND}
 	gnome-base/gnome-common:3
 	sys-devel/gettext
 	virtual/pkgconfig
-	test? ( app-text/docbook-xml-dtd:4.3 )"
+	test? ( app-text/docbook-xml-dtd:4.3 )
+"
 # eautoreconf deps
+#	app-text/yelp-tools
 #	gnome-base/gnome-common
+
 PDEPEND="gnome-base/gvfs"
 
 if [[ ${PV} = 9999 ]]; then
 	DEPEND="${DEPEND}
+		app-text/yelp-tools
+		gnome-base/gnome-common
 		doc? ( >=dev-util/gtk-doc-1.12 )"
 fi
 
 src_configure() {
-	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
-	G2CONF="${G2CONF}
-		--disable-caches
-		$(use_enable !libburn cdrtools)
-		$(use_enable !libburn cdrkit)
-		$(use_enable !libburn cdrdao)
-		$(use_enable !libburn growisofs)
-		$(use_enable introspection)
-		$(use_enable libburn libburnia)
-		$(use_enable nautilus)
-		$(use_enable playlist)
-		$(use_enable tracker search)"
+	local myconf=""
 
-	gnome2_src_configure
-}
+	[[ ${PV} != 9999 ]] && myconf="${myconf} ITSTOOL=$(type -P true)"
 
-pkg_postinst() {
-	gnome2_pkg_postinst
-
-	echo
-	elog "If ${PN} doesn't handle some music or video format, please check"
-	elog "your USE flags on media-plugins/gst-plugins-meta"
+	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README"
+	gnome2_src_configure \
+		--disable-caches \
+		$(use_enable !libburn cdrtools) \
+		$(use_enable !libburn cdrkit) \
+		$(use_enable !libburn cdrdao) \
+		$(use_enable !libburn growisofs) \
+		$(use_enable introspection) \
+		$(use_enable libburn libburnia) \
+		$(use_enable nautilus) \
+		$(use_enable playlist) \
+		$(use_enable tracker search) \
+		${myconf}
 }