[gentoo-commits] proj/gnome:master commit in: gnome-extra/gnome-user-share/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     105f4022c7da637250c8b2d705be7741d0484a0b
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 13 21:50:03 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Mon Dec  9 23:04:20 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=105f4022

gnome-extra/gnome-user-share: 3.8.3 → 3.10.1

Add USE=bluetooth.

The panel will not start, failing to read a non-existing gsetting.
Reported on Arch and confirmed by checking g-c-c sources.

---
 .../gnome-user-share-3.10.1.ebuild                 | 56 ++++++++++++++++++++++
 gnome-extra/gnome-user-share/metadata.xml          | 10 ++++
 2 files changed, 66 insertions(+)

diff --git a/gnome-extra/gnome-user-share/gnome-user-share-3.10.1.ebuild b/gnome-extra/gnome-user-share/gnome-user-share-3.10.1.ebuild
new file mode 100644
index 0000000..df69c89
--- /dev/null
+++ b/gnome-extra/gnome-user-share/gnome-user-share-3.10.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 multilib
+
+DESCRIPTION="Personal file sharing for the GNOME desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-user-share"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bluetooth"
+
+# FIXME: could libnotify be made optional ?
+# FIXME: selinux automagic support
+RDEPEND="
+	>=dev-libs/glib-2.28:2
+	>=x11-libs/gtk+-3:3
+	>=gnome-base/nautilus-2.91.7
+	media-libs/libcanberra[gtk3]
+	>=www-apache/mod_dnssd-0.6
+	>=www-servers/apache-2.2[apache2_modules_dav,apache2_modules_dav_fs,apache2_modules_authn_file,apache2_modules_auth_digest,apache2_modules_authz_groupfile]
+	>=x11-libs/libnotify-0.7:=
+	bluetooth? (
+		>=app-mobilephone/obex-data-server-0.4
+		>=net-wireless/gnome-bluetooth-3.9.3:2
+		>=net-wireless/bluez-4.18 )
+"
+DEPEND="${RDEPEND}
+	!<gnome-base/gnome-control-center-3.9
+	app-text/yelp-tools
+	app-text/docbook-xml-dtd:4.1.2
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable bluetooth) \
+		ITSTOOL=$(type -P true) \
+		--with-httpd=apache2 \
+		--with-modules-path=/usr/$(get_libdir)/apache2/modules/
+}
+
+src_install() {
+	gnome2_src_install
+
+	# FIXME: looks like upstream forgot about this
+	rm "${D}"/etc/xdg/autostart/gnome-user-share-obexpush.desktop || die
+}

diff --git a/gnome-extra/gnome-user-share/metadata.xml b/gnome-extra/gnome-user-share/metadata.xml
new file mode 100644
index 0000000..b9d6294
--- /dev/null
+++ b/gnome-extra/gnome-user-share/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>gnome</herd>
+  <maintainer>
+    <email>eva@gentoo.org</email>
+	<name>Gilles Dartiguelongue</name>
+	<description>Primary maintainer</description>
+  </maintainer>
+</pkgmetadata>