[gentoo-commits] proj/gnome:master commit in: dev-cpp/gtkmm/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     33726f6a4d0fd33642d62e3692720708d6ae95ea
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Dec  8 18:33:51 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Dec  8 18:33:51 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=33726f6a

dev-cpp/gtkmm: 3.8.1 → 3.10.1

---
 dev-cpp/gtkmm/gtkmm-3.10.1.ebuild | 62 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/dev-cpp/gtkmm/gtkmm-3.10.1.ebuild b/dev-cpp/gtkmm/gtkmm-3.10.1.ebuild
new file mode 100644
index 0000000..907bfa4
--- /dev/null
+++ b/dev-cpp/gtkmm/gtkmm-3.10.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit gnome2
+
+DESCRIPTION="C++ interface for GTK+"
+HOMEPAGE="http://www.gtkmm.org"
+
+LICENSE="LGPL-2.1"
+SLOT="3.0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="aqua doc examples test wayland +X"
+REQUIRED_USE="|| ( aqua wayland X )"
+
+RDEPEND="
+	>=dev-cpp/glibmm-2.38.0:2
+	>=x11-libs/gtk+-3.10.0:3[aqua?,wayland?,X?]
+	>=x11-libs/gdk-pixbuf-2.22.1:2
+	>=dev-cpp/atkmm-2.22.2
+	>=dev-cpp/cairomm-1.9.2.2
+	>=dev-cpp/pangomm-2.27.1:1.4
+	dev-libs/libsigc++:2
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		media-gfx/graphviz
+		dev-libs/libxslt
+		app-doc/doxygen )
+"
+#	dev-cpp/mm-common"
+# eautoreconf needs mm-common
+
+src_prepare() {
+	if ! use test; then
+		# don't waste time building tests
+		sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
+			|| die "sed 1 failed"
+	fi
+
+	if ! use examples; then
+		# don't waste time building tests
+		sed 's/^\(SUBDIRS =.*\)demos\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
+			|| die "sed 2 failed"
+	fi
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog PORTING NEWS README"
+	gnome2_src_configure \
+		--enable-api-atkmm \
+		$(use_enable doc documentation) \
+		$(use_enable aqua quartz-backend) \
+		$(use_enable wayland wayland-backend) \
+		$(use_enable X x11-backend)
+}