[gentoo-commits] proj/gnome:master commit in: dev-libs/libpeas/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     9bb6c5f514c7182e2aa6763f7bef812e625f45b6
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 18 22:36:25 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Mon Nov 25 23:12:35 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=9bb6c5f5

dev-libs/libpeas: 1.8.1 → 1.9.0

---
 dev-libs/libpeas/libpeas-1.9.0.ebuild | 93 +++++++++++++++++++++++++++++++++++
 dev-libs/libpeas/libpeas-9999.ebuild  | 61 +++++++++++++++++------
 2 files changed, 140 insertions(+), 14 deletions(-)

diff --git a/dev-libs/libpeas/libpeas-1.9.0.ebuild b/dev-libs/libpeas/libpeas-1.9.0.ebuild
new file mode 100644
index 0000000..96d5b7e
--- /dev/null
+++ b/dev-libs/libpeas/libpeas-1.9.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+
+inherit eutils gnome2 multilib python-r1 virtualx
+
+DESCRIPTION="A GObject plugins library"
+HOMEPAGE="http://developer.gnome.org/libpeas/stable/"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
+IUSE="gjs +gtk glade +python seed"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/gobject-introspection-0.10.1
+	gjs? ( >=dev-libs/gjs-1.37.1 )
+	glade? ( >=dev-util/glade-3.9.1:3.10 )
+	gtk? ( >=x11-libs/gtk+-3:3[introspection] )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygobject-3.0.0:3[${PYTHON_USEDEP}] )
+	seed? ( >=dev-libs/seed-2.91.91 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.11
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+if_use_python_python_foreach_impl() {
+	if use python; then
+		python_foreach_impl run_in_build_dir "$@"
+	else
+		"$@"
+	fi
+}
+
+src_prepare() {
+	use python && python_copy_sources
+	if_use_python_python_foreach_impl gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf="
+		$(use_enable gjs)
+		$(use_enable glade glade-catalog)
+		$(use_enable gtk)
+		$(use_enable seed)
+		--disable-deprecation
+		--disable-static"
+	# Wtf, --disable-gcov, --enable-gcov=no, --enable-gcov, all enable gcov
+	# What do we do about gdb, valgrind, gcov, etc?
+
+	configuration() {
+		local myconf="$@"
+		[[ ${EPYTHON} == python2* ]] && myconf+=" --enable-python2 --disable-python3 PYTHON2_CONFIG=/usr/bin/python-config-${EPYTHON#python}"
+		[[ ${EPYTHON} == python3* ]] && myconf+=" --enable-python3 --disable-python2 PYTHON3_CONFIG=/usr/bin/python-config-${EPYTHON#python}"
+		gnome2_src_configure ${myconf}
+	}
+
+	if use python; then
+		python_foreach_impl run_in_build_dir configuration ${myconf}
+	else
+		gnome2_src_configure ${myconf}
+	fi
+}
+
+src_compile() {
+	if_use_python_python_foreach_impl gnome2_src_compile
+}
+
+src_install() {
+	if_use_python_python_foreach_impl gnome2_src_install
+}
+
+src_test() {
+	# FIXME: Tests fail because of some bug involving Xvfb and Gtk.IconTheme
+	# DO NOT REPORT UPSTREAM, this is not a libpeas bug.
+	# To reproduce:
+	# >>> from gi.repository import Gtk
+	# >>> Gtk.IconTheme.get_default().has_icon("gtk-about")
+	# This should return True, it returns False for Xvfb
+	if_use_python_python_foreach_impl Xemake check
+}

diff --git a/dev-libs/libpeas/libpeas-9999.ebuild b/dev-libs/libpeas/libpeas-9999.ebuild
index 16a6b5d..13122ab 100644
--- a/dev-libs/libpeas/libpeas-9999.ebuild
+++ b/dev-libs/libpeas/libpeas-9999.ebuild
@@ -1,13 +1,13 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
 EAPI="5"
 GCONF_DEBUG="no"
 GNOME2_LA_PUNT="yes"
-PYTHON_COMPAT=( python{2_6,2_7} )
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
 
-inherit eutils gnome2 multilib python-single-r1 virtualx
+inherit eutils gnome2 multilib python-r1 virtualx
 if [[ ${PV} = 9999 ]]; then
 	inherit gnome2-live
 fi
@@ -18,47 +18,80 @@ HOMEPAGE="http://developer.gnome.org/libpeas/stable/"
 LICENSE="LGPL-2+"
 SLOT="0"
 IUSE="gjs +gtk glade +python seed"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 if [[ ${PV} = 9999 ]]; then
 	IUSE="${IUSE} doc"
 	KEYWORDS=""
 else
-	KEYWORDS="~amd64 ~ppc ~x86 ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
 fi
 
-RDEPEND=">=dev-libs/glib-2.32:2
+RDEPEND="
+	>=dev-libs/glib-2.32:2
 	>=dev-libs/gobject-introspection-0.10.1
-	gjs? ( >=dev-libs/gjs-1.31.11 )
+	gjs? ( >=dev-libs/gjs-1.37.1 )
 	glade? ( >=dev-util/glade-3.9.1:3.10 )
 	gtk? ( >=x11-libs/gtk+-3:3[introspection] )
 	python? (
 		${PYTHON_DEPS}
 		>=dev-python/pygobject-3.0.0:3[${PYTHON_USEDEP}] )
-	seed? ( >=dev-libs/seed-2.91.91 )"
+	seed? ( >=dev-libs/seed-2.91.91 )
+"
 DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.11
 	>=dev-util/intltool-0.40
-	>=sys-devel/gettext-0.17"
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
 
 if [[ ${PV} = 9999 ]]; then
 	DEPEND="${DEPEND} doc? ( >=dev-util/gtk-doc-1.11 )"
 fi
 
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
+if_use_python_python_foreach_impl() {
+	if use python; then
+		python_foreach_impl run_in_build_dir "$@"
+	else
+		"$@"
+	fi
 }
 
 src_prepare() {
-	G2CONF="${G2CONF}
+	use python && python_copy_sources
+	if_use_python_python_foreach_impl gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf="
 		$(use_enable gjs)
 		$(use_enable glade glade-catalog)
 		$(use_enable gtk)
-		$(use_enable python)
 		$(use_enable seed)
 		--disable-deprecation
 		--disable-static"
 	# Wtf, --disable-gcov, --enable-gcov=no, --enable-gcov, all enable gcov
 	# What do we do about gdb, valgrind, gcov, etc?
 
-	gnome2_src_prepare
+	configuration() {
+		local myconf="$@"
+		[[ ${EPYTHON} == python2* ]] && myconf+=" --enable-python2 --disable-python3 PYTHON2_CONFIG=/usr/bin/python-config-${EPYTHON#python}"
+		[[ ${EPYTHON} == python3* ]] && myconf+=" --enable-python3 --disable-python2 PYTHON3_CONFIG=/usr/bin/python-config-${EPYTHON#python}"
+		gnome2_src_configure ${myconf}
+	}
+
+	if use python; then
+		python_foreach_impl run_in_build_dir configuration ${myconf}
+	else
+		gnome2_src_configure ${myconf}
+	fi
+}
+
+src_compile() {
+	if_use_python_python_foreach_impl gnome2_src_compile
+}
+
+src_install() {
+	if_use_python_python_foreach_impl gnome2_src_install
 }
 
 src_test() {
@@ -68,5 +101,5 @@ src_test() {
 	# >>> from gi.repository import Gtk
 	# >>> Gtk.IconTheme.get_default().has_icon("gtk-about")
 	# This should return True, it returns False for Xvfb
-	Xemake check
+	if_use_python_python_foreach_impl Xemake check
 }