[gentoo-commits] proj/gnome:master commit in: dev-util/devhelp/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     68d69586f4d7b412835f4ff36334baf4475ea545
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 13 16:25:41 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Fri Nov 15 00:39:11 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=68d69586

dev-util/devhelp: 3.8.2 → 3.10.0

---
 dev-util/devhelp/devhelp-3.10.0.ebuild | 61 ++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/dev-util/devhelp/devhelp-3.10.0.ebuild b/dev-util/devhelp/devhelp-3.10.0.ebuild
new file mode 100644
index 0000000..12a10bc
--- /dev/null
+++ b/dev-util/devhelp/devhelp-3.10.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+# gedit-3.8 is python3 only, this also per:
+# https://bugzilla.redhat.com/show_bug.cgi?id=979450
+PYTHON_COMPAT=( python{3_2,3_3} )
+
+inherit gnome2 python-single-r1 toolchain-funcs
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="http://live.gnome.org/devhelp"
+
+LICENSE="GPL-2+"
+SLOT="0/3-1" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="gedit"
+REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} )"
+
+# FIXME: automagic python dependency
+COMMON_DEPEND="
+	>=dev-libs/glib-2.37.3:2
+	>=x11-libs/gtk+-3.9.8:3
+	>=net-libs/webkit-gtk-2:3
+"
+RDEPEND="${COMMON_DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		app-editors/gedit[introspection,python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		x11-libs/gtk+[introspection] )
+	gnome-base/gsettings-desktop-schemas
+"
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	>=sys-devel/gettext-0.17
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+"
+pkg_setup() {
+	use gedit && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	if ! use gedit ; then
+		sed -e '/SUBDIRS/ s/gedit-plugin//' -i misc/Makefile.{am,in} || die
+	fi
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+	# ICC is crazy, silence warnings (bug #154010)
+	if [[ $(tc-getCC) == "icc" ]] ; then
+		myconf="--with-compile-warnings=no"
+	fi
+	gnome2_src_configure ${myconf}
+}