[gentoo-commits] proj/gnome:master commit in: gnome-extra/gucharmap/

["Gilles Dartiguelongue" <eva@gentoo.org>]

commit:     639e32aebe70800103d7fbb16c252dcda499a514
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 13 09:48:41 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Oct 13 10:03:58 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=639e32ae

gnome-extra/gucharmap: 3.8.2 → 3.9.99

---
 gnome-extra/gucharmap/gucharmap-3.9.99.ebuild | 61 +++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/gnome-extra/gucharmap/gucharmap-3.9.99.ebuild b/gnome-extra/gucharmap/gucharmap-3.9.99.ebuild
new file mode 100644
index 0000000..9974cec
--- /dev/null
+++ b/gnome-extra/gucharmap/gucharmap-3.9.99.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+VALA_MIN_API_VERSION="0.16"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="Unicode character map viewer and library"
+HOMEPAGE="http://live.gnome.org/Gucharmap"
+
+LICENSE="GPL-3"
+SLOT="2.90"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="cjk +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.32:2
+	>=x11-libs/pango-1.2.1[introspection?]
+	>=x11-libs/gtk+-3.4.0:3[introspection?]
+
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-extra/gucharmap-3:0
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? (	app-text/docbook-xml-dtd:4.1.2 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	# prevent file collisions with slot 0
+	sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
+		-i configure.ac configure || die "sed configure.ac configure failed"
+
+	# avoid autoreconf
+	sed -e 's/-Wall //g' -i configure || die "sed failed"
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Do not add ITSTOOL=$(type -P true); yelp-tools is a true required
+	# dependency here for some LINGUAS.
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable introspection) \
+		$(use_enable cjk unihan) \
+		$(use_enable vala)
+}