[gentoo-commits] proj/kde:master commit in: media-sound/kid3/

["Chris Reffett" <geekboy72@gmail.com>]

commit:     b4196e3c9c0f887712f5e2fc760fea6ab254c358
Author:     Chris Reffett <creffett <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  5 00:39:32 2013 +0000
Commit:     Chris Reffett <geekboy72 <AT> gmail <DOT> com>
CommitDate: Tue Feb  5 00:39:32 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=b4196e3c

[media-sound/kid3] Version bump for testing.

Package-Manager: portage-2.2.0_alpha161

---
 media-sound/kid3/kid3-2.2.1.ebuild |   52 ++++++++++++++++++++++++++++++++++++
 media-sound/kid3/metadata.xml      |   14 +++++++++
 2 files changed, 66 insertions(+), 0 deletions(-)

diff --git a/media-sound/kid3/kid3-2.2.1.ebuild b/media-sound/kid3/kid3-2.2.1.ebuild
new file mode 100644
index 0000000..f21ee24
--- /dev/null
+++ b/media-sound/kid3/kid3-2.2.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/kid3/kid3-2.2.ebuild,v 1.3 2013/01/27 16:16:41 ago Exp $
+
+EAPI=5
+KDE_LINGUAS="cs de es et fi fr it nl pl ru sr sr@ijekavian sr@ijekavianlatin sr@Latn tr zh_TW"
+KDE_REQUIRED="always"
+KDE_HANDBOOK="optional"
+inherit kde4-base
+
+DESCRIPTION="A simple tag editor for KDE"
+HOMEPAGE="http://kid3.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="4"
+KEYWORDS="~amd64 ~x86"
+IUSE="acoustid flac mp3 mp4 +taglib vorbis"
+
+RDEPEND="
+	acoustid? (
+		media-libs/chromaprint
+		virtual/ffmpeg
+	)
+	flac? (
+		media-libs/flac[cxx]
+		media-libs/libvorbis
+	)
+	mp3? ( media-libs/id3lib )
+	mp4? ( media-libs/libmp4v2:0 )
+	taglib? ( media-libs/taglib )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="flac? ( vorbis )"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with acoustid CHROMAPRINT)
+		$(cmake-utils_use_with flac)
+		$(cmake-utils_use_with mp3 ID3LIB)
+		$(cmake-utils_use_with mp4 MP4V2)
+		$(cmake-utils_use_with vorbis)
+		$(cmake-utils_use_with taglib)
+		"-DWITH_KDE=ON"
+		)
+
+	kde4-base_src_configure
+}

diff --git a/media-sound/kid3/metadata.xml b/media-sound/kid3/metadata.xml
new file mode 100644
index 0000000..91b6116
--- /dev/null
+++ b/media-sound/kid3/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>kde</herd>
+  <herd>sound</herd>
+  <use>
+    <flag name='acoustid'>Enable support for acoustic fingerprinting plugin using
+      (<pkg>media-libs/chromaprint</pkg>)</flag>
+  </use>
+  <upstream>
+    <bugs-to>http://sourceforge.net/tracker/?group_id=70849</bugs-to>
+    <remote-id type="sourceforge">kid3</remote-id>
+  </upstream>
+</pkgmetadata>