[gentoo-commits] proj/kde:master commit in: media-gfx/digikam/

["Andreas Hüttel" <dilfridge@gentoo.org>]

commit:     d93270d59b03004cbe704c54c8628aa40aaf4a51
Author:     Andreas K. Huettel (dilfridge) <dilfridge <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 29 15:21:49 2012 +0000
Commit:     Andreas Hüttel <dilfridge <AT> gentoo <DOT> org>
CommitDate: Sat Dec 29 15:21:49 2012 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=d93270d5

[media-gfx/digikam] Version bump

Package-Manager: portage-2.2.0_alpha149

---
 media-gfx/digikam/digikam-3.0.0_rc.ebuild |  154 +++++++++++++++++++++++++++++
 1 files changed, 154 insertions(+), 0 deletions(-)

diff --git a/media-gfx/digikam/digikam-3.0.0_rc.ebuild b/media-gfx/digikam/digikam-3.0.0_rc.ebuild
new file mode 100644
index 0000000..a5c04ed
--- /dev/null
+++ b/media-gfx/digikam/digikam-3.0.0_rc.ebuild
@@ -0,0 +1,154 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/digikam-2.9.0.ebuild,v 1.2 2012/09/04 14:56:27 creffett Exp $
+
+EAPI=4
+
+KDE_LINGUAS="af ar az be bg bn br bs ca cs csb cy da de el en_GB eo es et eu fa fi fo fr fy ga gl ha he hi hr hsb
+hu id is it ja ka kk km ko ku lb lo lt lv mi mk mn ms mt nb nds ne nl nn nso oc pa pl pt pt_BR ro ru
+rw se sk sl sq sr sr@Latn ss sv ta te tg th tr tt uk uz uz@cyrillic ven vi wa xh zh_CN zh_HK zh_TW zu"
+
+KDE_HANDBOOK="optional"
+CMAKE_MIN_VERSION="2.8"
+KDE_MINIMAL="4.9"
+
+KDE_DOC_DIRS="doc-digikam doc-showfoto"
+
+inherit kde4-base
+
+MY_PV=${PV/_/-}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Digital photo management application for KDE"
+HOMEPAGE="http://www.digikam.org/"
+SRC_URI="mirror://kde/unstable/${PN}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2
+	handbook? ( FDL-1.2 )"
+KEYWORDS="~amd64 ~x86"
+SLOT="4"
+IUSE="addressbook debug doc gphoto2 mysql semantic-desktop themedesigner +thumbnails video"
+
+#Keep libf2c blocker until bug 433782 is resolved
+CDEPEND="
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	$(add_kdebase_dep kdebase-kioslaves)
+	$(add_kdebase_dep libkdcraw '' '4.9.80')
+	$(add_kdebase_dep libkexiv2)
+	$(add_kdebase_dep libkipi '' '4.9.80')
+	$(add_kdebase_dep marble plasma)
+	$(add_kdebase_dep solid)
+	media-libs/jasper
+	media-libs/lcms:0
+	media-libs/lensfun
+	media-libs/libkface
+	media-libs/libkgeomap
+	media-libs/liblqr
+	>=media-libs/libpgf-6.12.27
+	media-libs/libpng
+	media-libs/tiff
+	sci-libs/clapack
+	virtual/jpeg
+	x11-libs/qt-gui:4[qt3support]
+	|| ( x11-libs/qt-sql:4[mysql] x11-libs/qt-sql:4[sqlite] )
+	addressbook? ( $(add_kdebase_dep kdepimlibs) )
+	gphoto2? ( media-libs/libgphoto2 )
+	mysql? ( virtual/mysql )
+"
+RDEPEND="${CDEPEND}
+	$(add_kdebase_dep kreadconfig)
+	media-plugins/kipi-plugins
+	video? (
+		|| (
+			$(add_kdebase_dep mplayerthumbs)
+			$(add_kdebase_dep ffmpegthumbs)
+		)
+	)
+"
+DEPEND="${CDEPEND}
+	dev-libs/boost
+	sys-devel/gettext
+	doc? ( app-doc/doxygen )
+"
+
+S="${WORKDIR}/${MY_P}/core"
+
+RESTRICT=test
+# bug 366505
+
+src_prepare() {
+	# just to make absolutely sure
+	rm -rf "${WORKDIR}/${MY_P}/extra" || die
+
+	# prepare the handbook
+	mkdir doc-digikam doc-showfoto || die
+	echo "add_subdirectory( en )" > doc-digikam/CMakeLists.txt || die
+	mv "${WORKDIR}/${MY_P}/doc/${PN}/digikam" doc-digikam/en || die
+	echo "add_subdirectory( en )" > doc-showfoto/CMakeLists.txt || die
+	mv "${WORKDIR}/${MY_P}/doc/${PN}/showfoto" doc-showfoto/en || die
+	sed -i -e 's:../digikam/:../../doc-digikam/en/:g' doc-showfoto/en/index.docbook || die
+
+	# prepare the translations
+	mv "${WORKDIR}/${MY_P}/po" po || die
+	find po -name "*.po" -and -not -name "digikam.po" -exec rm {} +
+
+	echo "find_package(Msgfmt REQUIRED)" >> CMakeLists.txt || die
+	echo "find_package(Gettext REQUIRED)" >> CMakeLists.txt || die
+	echo "add_subdirectory( po )" >> CMakeLists.txt || die
+
+	kde4-base_src_prepare
+
+	if use handbook; then
+		echo "add_subdirectory( doc-digikam )" >> CMakeLists.txt
+		echo "add_subdirectory( doc-showfoto )" >> CMakeLists.txt
+	fi
+}
+
+src_configure() {
+	local backend
+
+	use semantic-desktop && backend="Nepomuk" || backend="None"
+	# LQR = only allows to choose between bundled/external
+	local mycmakeargs=(
+		-DFORCED_UNBUNDLE=ON
+		-DWITH_LQR=ON
+		-DWITH_LENSFUN=ON
+		-DGWENVIEW_SEMANTICINFO_BACKEND=${backend}
+		$(cmake-utils_use_with addressbook KdepimLibs)
+		-DWITH_MarbleWidget=ON
+		$(cmake-utils_use_enable gphoto2 GPHOTO2)
+		$(cmake-utils_use_with gphoto2)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_enable themedesigner)
+		$(cmake-utils_use_enable thumbnails THUMBS_DB)
+		$(cmake-utils_use_enable mysql INTERNALMYSQL)
+		$(cmake-utils_use_enable debug DEBUG_MESSAGES)
+	)
+
+	kde4-base_src_configure
+}
+
+src_compile() {
+	local mytargets="all"
+	use doc && mytargets+=" doc"
+
+	kde4-base_src_compile ${mytargets}
+}
+
+src_install() {
+	kde4-base_src_install
+
+	if use doc; then
+		# install the api documentation
+		insinto /usr/share/doc/${PF}/
+		doins -r ${CMAKE_BUILD_DIR}/api/html
+	fi
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	if use doc; then
+		elog "The digikam api documentation has been installed at /usr/share/doc/${PF}/html"
+	fi
+}