[gentoo-commits] proj/kde:master commit in: dev-libs/libdbusmenu-qt/

["Chris Reffett" <geekboy72@gmail.com>]

commit:     6afbaeb8d1cb1937989b6c4b51ed0b70513202f3
Author:     Chris Reffett <geekboy72 <AT> gmail <DOT> com>
AuthorDate: Tue May 15 14:27:47 2012 +0000
Commit:     Chris Reffett <geekboy72 <AT> gmail <DOT> com>
CommitDate: Tue May 15 14:27:47 2012 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=6afbaeb8

[dev-libs/libdbusmenu-qt] Version bump to 0.9.2, bug 416073

---
 .../libdbusmenu-qt/libdbusmenu-qt-0.9.2.ebuild     |   61 ++++++++++++++++++++
 1 files changed, 61 insertions(+), 0 deletions(-)

diff --git a/dev-libs/libdbusmenu-qt/libdbusmenu-qt-0.9.2.ebuild b/dev-libs/libdbusmenu-qt/libdbusmenu-qt-0.9.2.ebuild
new file mode 100644
index 0000000..31bd12b
--- /dev/null
+++ b/dev-libs/libdbusmenu-qt/libdbusmenu-qt-0.9.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: Exp $
+
+EAPI=4
+
+QT_DEPEND="4.6.3"
+EGIT_REPO_URI="git://gitorious.org/dbusmenu/dbusmenu-qt.git"
+
+[[ ${PV} == 9999* ]] && GIT_ECLASS="git-2"
+inherit cmake-utils virtualx ${GIT_ECLASS}
+
+DESCRIPTION="A library providing Qt implementation of DBusMenu specification"
+HOMEPAGE="https://launchpad.net/libdbusmenu-qt/"
+if [[ ${PV} == 9999* ]] ; then
+	KEYWORDS=""
+else
+	#SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.bz2"
+	# upstream has no permissions to use some kde written code so repack git
+	# repo every time
+	SRC_URI="http://dev.gentoo.org/~creffett/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc"
+
+RDEPEND="
+	>=x11-libs/qt-core-${QT_DEPEND}:4
+	>=x11-libs/qt-gui-${QT_DEPEND}:4[dbus]
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? (
+		dev-libs/qjson
+		>=x11-libs/qt-test-${QT_DEPEND}:4
+	)
+"
+
+DOCS=(NEWS README)
+
+# tests fail due to missing conection to dbus
+RESTRICT="test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_build test TESTS)
+		$(cmake-utils_use_with doc)
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	local builddir=${CMAKE_BUILD_DIR}
+
+	CMAKE_BUILD_DIR=${CMAKE_BUILD_DIR}/tests \
+		VIRTUALX_COMMAND=cmake-utils_src_test virtualmake
+
+	CMAKE_BUILD_DIR=${builddir}
+}