From: "Pacho Ramos (pacho)" <pacho@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in net-wireless/bluez: bluez-5.25.ebuild ChangeLog
Date: Thu, 13 Nov 2014 10:24:29 +0000 (UTC) [thread overview]
Message-ID: <20141113102429.645E21472@oystercatcher.gentoo.org> (raw)
pacho 14/11/13 10:24:29
Modified: ChangeLog
Added: bluez-5.25.ebuild
Log:
Version bump (#529060 by mrueg)
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.224 net-wireless/bluez/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?rev=1.224&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?rev=1.224&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/ChangeLog?r1=1.223&r2=1.224
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v
retrieving revision 1.223
retrieving revision 1.224
diff -u -r1.223 -r1.224
--- ChangeLog 2 Nov 2014 09:36:26 -0000 1.223
+++ ChangeLog 13 Nov 2014 10:24:29 -0000 1.224
@@ -1,6 +1,11 @@
# ChangeLog for net-wireless/bluez
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v 1.223 2014/11/02 09:36:26 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/ChangeLog,v 1.224 2014/11/13 10:24:29 pacho Exp $
+
+*bluez-5.25 (13 Nov 2014)
+
+ 13 Nov 2014; Pacho Ramos <pacho@gentoo.org> +bluez-5.25.ebuild:
+ Version bump (#529060 by mrueg)
02 Nov 2014; Sven Vermeulen <swift@gentoo.org> bluez-5.21-r1.ebuild,
bluez-5.24.ebuild:
1.1 net-wireless/bluez/bluez-5.25.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/bluez-5.25.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/bluez/bluez-5.25.ebuild?rev=1.1&content-type=text/plain
Index: bluez-5.25.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/bluez/bluez-5.25.ebuild,v 1.1 2014/11/13 10:24:29 pacho Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
inherit autotools eutils multilib python-any-r1 readme.gentoo systemd udev user multilib-minimal
DESCRIPTION="Bluetooth Tools and System Daemons for Linux"
HOMEPAGE="http://www.bluez.org"
SRC_URI="mirror://kernel/linux/bluetooth/${P}.tar.xz"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0/3"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
IUSE="cups debug +obex +readline selinux systemd test +udev"
REQUIRED_USE="test? ( ${PYTHON_REQUIRED_USE} )"
CDEPEND="
>=dev-libs/glib-2.28:2
>=sys-apps/dbus-1.6:=
>=sys-apps/hwids-20121202.2
cups? ( net-print/cups:= )
obex? ( dev-libs/libical )
readline? ( sys-libs/readline:= )
systemd? ( sys-apps/systemd )
udev? ( >=virtual/udev-172 )
abi_x86_32? (
!<app-emulation/emul-linux-x86-soundlibs-20140406-r1
!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32]
)
"
DEPEND="${CDEPEND}
virtual/pkgconfig
test? (
${PYTHON_DEPS}
>=dev-python/dbus-python-1
dev-python/pygobject:2
dev-python/pygobject:3
)
"
RDEPEND="${CDEPEND}
selinux? ( sec-policy/selinux-bluetooth )
"
DOC_CONTENTS="
If you want to use rfcomm as a normal user, you need to add the user
to the uucp group.
"
pkg_setup() {
enewgroup plugdev
use test && python-any-r1_pkg_setup
if ! use udev; then
ewarn
ewarn "You are installing ${PN} with USE=-udev. This means various bluetooth"
ewarn "devices and adapters from Apple, Dell, Logitech etc. will not work,"
ewarn "and hid2hci will not be available."
ewarn
fi
}
src_prepare() {
# Use static group "plugdev" if there is no ConsoleKit (or systemd logind)
epatch "${FILESDIR}"/bluez-plugdev.patch
# Fedora patches
# http://www.spinics.net/lists/linux-bluetooth/msg38490.html
epatch "${FILESDIR}"/0001-Allow-using-obexd-without-systemd-in-the-user-sessio.patch
# http://www.spinics.net/lists/linux-bluetooth/msg40136.html
epatch "${FILESDIR}"/0001-obex-Use-GLib-helper-function-to-manipulate-paths.patch
# http://www.spinics.net/lists/linux-bluetooth/msg41264.html
epatch "${FILESDIR}"/0002-autopair-Don-t-handle-the-iCade.patch
# ???
epatch "${FILESDIR}"/0004-agent-Assert-possible-infinite-loop.patch
# Ubuntu workaround for bug #501120
epatch "${FILESDIR}"/0001-work-around-Logitech-diNovo-Edge-keyboard-firmware-i.patch
if use cups; then
sed -i \
-e "s:cupsdir = \$(libdir)/cups:cupsdir = $(cups-config --serverbin):" \
Makefile.{in,tools} || die
fi
eautoreconf
multilib_copy_sources
}
multilib_src_configure() {
local myconf=(
# readline is automagic when client is enabled
# --enable-client always needs readline, bug #504038
ac_cv_header_readline_readline_h=$(multilib_native_usex readline)
)
if ! multilib_is_native_abi; then
myconf+=(
# deps not used for the library
{DBUS,GLIB}_{CFLAGS,LIBS}=' '
)
fi
econf \
--localstatedir=/var \
--disable-android \
--enable-datafiles \
--enable-experimental \
--enable-optimization \
$(use_enable debug) \
--enable-pie \
--enable-threads \
--enable-library \
$(multilib_native_use_enable test) \
--enable-tools \
--enable-manpages \
--enable-monitor \
$(multilib_native_use_enable cups) \
$(multilib_native_use_enable obex) \
$(multilib_native_use_enable readline client) \
$(multilib_native_use_enable systemd) \
$(systemd_with_unitdir) \
$(multilib_native_use_enable udev) \
$(multilib_native_use_enable udev sixaxis)
}
multilib_src_compile() {
if multilib_is_native_abi; then
default
else
emake -f Makefile -f - libs \
<<<'libs: $(lib_LTLIBRARIES)'
fi
}
multilib_src_test() {
multilib_is_native_abi && default
}
multilib_src_install() {
if multilib_is_native_abi; then
emake DESTDIR="${D}" install
# Upstream don't install this, bug #524640
# http://permalink.gmane.org/gmane.linux.bluez.kernel/53115
# http://comments.gmane.org/gmane.linux.bluez.kernel/54564
dobin attrib/gatttool
dobin tools/hex2hcd
# Unittests are not that useful once installed
if use test ; then
rm -r "${ED}"/usr/$(get_libdir)/bluez/test || die
fi
else
emake DESTDIR="${D}" \
install-includeHEADERS \
install-libLTLIBRARIES \
install-pkgconfigDATA
fi
}
multilib_src_install_all() {
prune_libtool_files --modules
keepdir /var/lib/bluetooth
# Upstream don't want people to play with them
# But we keep installing them due 'historical' reasons
insinto /etc/bluetooth
local d
for d in input network proximity; do
doins profiles/${d}/${d}.conf
done
doins src/main.conf
doins src/bluetooth.conf
# FIXME:
# Looks like upstream installs it only for systemd, probably not needed
# insinto /usr/share/dbus-1/system-services
# doins src/org.bluez.service
newinitd "${FILESDIR}"/bluetooth-init.d-r3 bluetooth
newinitd "${FILESDIR}"/rfcomm-init.d-r2 rfcomm
einstalldocs
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
use udev && udev_reload
has_version net-dialup/ppp || elog "To use dial up networking you must install net-dialup/ppp."
if ! has_version sys-auth/consolekit && ! has_version sys-apps/systemd; then
elog "Since you don't have sys-auth/consolekit neither sys-apps/systemd, you will only"
elog "be able to run bluetooth clients as root. If you want to be able to run bluetooth clients as"
elog "a regular user, you need to add the user to the plugdev group."
fi
}
next reply other threads:[~2014-11-13 10:24 UTC|newest]
Thread overview: 6+ messages / expand[flat|nested] mbox.gz Atom feed top
2014-11-13 10:24 Pacho Ramos (pacho) [this message]
-- strict thread matches above, loose matches on Subject: below --
2014-11-25 17:06 [gentoo-commits] gentoo-x86 commit in net-wireless/bluez: bluez-5.25.ebuild ChangeLog Pacho Ramos (pacho)
2014-11-26 10:40 Agostino Sarubbo (ago)
2014-12-03 9:45 Agostino Sarubbo (ago)
2014-12-04 8:37 Agostino Sarubbo (ago)
2014-12-05 10:14 Agostino Sarubbo (ago)
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20141113102429.645E21472@oystercatcher.gentoo.org \
--to=pacho@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox