From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: sci-astronomy/siril/
Date: Fri, 04 Jul 2025 18:37:01 +0000 (UTC) [thread overview]
Message-ID: <1751654154.c3dd1dbea1f6d957ae6c797d890eb3c6d4dcad14.sam@gentoo> (raw)
commit: c3dd1dbea1f6d957ae6c797d890eb3c6d4dcad14
Author: Mario Haustein <mario.haustein <AT> hrz <DOT> tu-chemnitz <DOT> de>
AuthorDate: Mon Jun 30 21:48:29 2025 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jul 4 18:35:54 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c3dd1dbe
sci-astronomy/siril: require features2d use flag for media-libs/opencv
Closes: https://bugs.gentoo.org/958150
Signed-off-by: Mario Haustein <mario.haustein <AT> hrz.tu-chemnitz.de>
Part-of: https://github.com/gentoo/gentoo/pull/42819
Signed-off-by: Sam James <sam <AT> gentoo.org>
sci-astronomy/siril/siril-1.2.6-r1.ebuild | 94 +++++++++++++++++++++++++++++++
1 file changed, 94 insertions(+)
diff --git a/sci-astronomy/siril/siril-1.2.6-r1.ebuild b/sci-astronomy/siril/siril-1.2.6-r1.ebuild
new file mode 100644
index 000000000000..2219abe8ee82
--- /dev/null
+++ b/sci-astronomy/siril/siril-1.2.6-r1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature toolchain-funcs xdg
+
+DESCRIPTION="A free astronomical image processing software"
+HOMEPAGE="https://siril.org/"
+
+if [[ ${PV} == "9999" ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://gitlab.com/free-astro/${PN}.git"
+else
+ SRC_URI="https://gitlab.com/free-astro/siril/-/archive/${PV/_/-}/${PN}-${PV/_/-}.tar.bz2"
+ KEYWORDS="amd64 ~x86"
+ S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+LICENSE="GPL-3+ Boost-1.0"
+SLOT="0"
+IUSE="curl exif ffmpeg heif jpeg libconfig openmp png raw tiff wcs"
+
+DEPEND="
+ >=dev-libs/glib-2.56.0:2
+ >=dev-libs/json-glib-1.2.6
+ media-libs/librtprocess
+ >=media-libs/opencv-4.4.0:=[features2d]
+ sci-libs/cfitsio:=
+ sci-libs/fftw:3.0=
+ sci-libs/gsl:=
+ x11-libs/gdk-pixbuf:2
+ x11-libs/cairo
+ x11-libs/pango
+ >=x11-libs/gtk+-3.20.0:3
+ curl? ( net-misc/curl )
+ exif? ( >=media-gfx/exiv2-0.25:= )
+ ffmpeg? ( media-video/ffmpeg:= )
+ heif? ( media-libs/libheif:= )
+ jpeg? ( media-libs/libjpeg-turbo:= )
+ libconfig? ( >=dev-libs/libconfig-1.4:=[cxx] )
+ png? ( >=media-libs/libpng-1.6.0:= )
+ raw? ( media-libs/libraw:= )
+ tiff? ( media-libs/tiff:= )
+ wcs? ( >=sci-astronomy/wcslib-7.7:= )
+"
+RDEPEND="
+ ${DEPEND}
+"
+BDEPEND="dev-build/cmake
+ x11-base/xorg-proto"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-docfiles.patch"
+ "${FILESDIR}/${PN}-1.2-fseek64-musl.patch"
+ "${FILESDIR}/${PN}-1.2.1-options.patch"
+ "${FILESDIR}/${PN}-1.2.6-linkage.patch"
+)
+
+DOCS=( README.md NEWS ChangeLog AUTHORS )
+
+pkg_pretend() {
+ [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+ [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dffms2=false
+ -Dcriterion=false
+ $(meson_use exif exiv2)
+ $(meson_use ffmpeg)
+ $(meson_use heif libheif)
+ $(meson_use jpeg libjpeg)
+ $(meson_use libconfig)
+ $(meson_use openmp)
+ $(meson_use png libpng)
+ $(meson_use raw libraw)
+ $(meson_use tiff libtiff)
+ $(meson_use wcs wcslib)
+ $(usex curl -Denable-libcurl=yes -Denable-libcurl=no)
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+ optfeature "gnuplot support" sci-visualization/gnuplot
+}
next reply other threads:[~2025-07-04 18:37 UTC|newest]
Thread overview: 38+ messages / expand[flat|nested] mbox.gz Atom feed top
2025-07-04 18:37 Sam James [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-07-04 18:37 [gentoo-commits] repo/gentoo:master commit in: sci-astronomy/siril/ Sam James
2025-07-04 18:37 Sam James
2025-03-27 11:03 Sam James
2025-02-19 11:13 Sam James
2025-02-19 11:13 Sam James
2025-01-31 8:02 Joonas Niilola
2024-12-19 16:09 Joonas Niilola
2024-12-19 16:09 Joonas Niilola
2024-11-23 7:52 Joonas Niilola
2024-10-13 0:56 Jason Zaman
2024-08-06 1:46 Sam James
2024-07-05 22:37 Jason Zaman
2024-07-04 9:29 Jakov Smolić
2024-04-23 9:28 Sam James
2024-03-16 9:47 Joonas Niilola
2023-10-19 6:32 Joonas Niilola
2023-09-18 7:40 Sam James
2023-08-22 6:10 Joonas Niilola
2023-06-27 11:06 Sam James
2023-06-13 6:32 Viorel Munteanu
2023-03-08 16:33 Joonas Niilola
2023-02-09 8:50 Joonas Niilola
2023-02-07 17:51 Sam James
2022-12-18 8:32 Sam James
2022-12-16 4:30 Sam James
2022-12-16 1:40 Sam James
2022-11-10 16:15 Joonas Niilola
2022-11-10 16:15 Joonas Niilola
2022-11-10 16:15 Joonas Niilola
2022-11-03 8:08 Agostino Sarubbo
2022-11-02 23:14 Sam James
2022-10-27 8:12 Joonas Niilola
2022-10-07 20:19 Sam James
2022-07-16 7:16 Joonas Niilola
2022-05-16 5:41 Sam James
2022-05-16 5:41 Sam James
2022-05-16 5:26 Sam James
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1751654154.c3dd1dbea1f6d957ae6c797d890eb3c6d4dcad14.sam@gentoo \
--to=sam@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox