From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-sound/gogglesmm/
Date: Sat, 26 Apr 2025 01:17:41 +0000 (UTC) [thread overview]
Message-ID: <1745630110.70d74ebb9250524877692d31389751567643eb32.sam@gentoo> (raw)
commit: 70d74ebb9250524877692d31389751567643eb32
Author: Nicolas PARLANT <nicolas.parlant <AT> parhuet <DOT> fr>
AuthorDate: Tue Apr 1 14:03:43 2025 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Apr 26 01:15:10 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=70d74ebb
media-sound/gogglesmm: fix conflict with libgap.so
Don't build gap as shared-lib to avoid a conflict with libgap.so from
sci-mathematics/gap. No package links against libgap.so in tree.
Set explicit X for media-libs/libepoxy :
> src/gmdefs.h:32:10:
> fatal error: epoxy/glx.h: No such file or directory
> 32 | #include <epoxy/glx.h>
Clean an old bug from 1.2.1
Bug: https://bugs.gentoo.org/951983
Closes: https://bugs.gentoo.org/917025
Signed-off-by: Nicolas PARLANT <nicolas.parlant <AT> parhuet.fr>
Part-of: https://github.com/gentoo/gentoo/pull/41416
Closes: https://github.com/gentoo/gentoo/pull/41416
Signed-off-by: Sam James <sam <AT> gentoo.org>
media-sound/gogglesmm/gogglesmm-1.2.5-r1.ebuild | 103 ++++++++++++++++++++++++
1 file changed, 103 insertions(+)
diff --git a/media-sound/gogglesmm/gogglesmm-1.2.5-r1.ebuild b/media-sound/gogglesmm/gogglesmm-1.2.5-r1.ebuild
new file mode 100644
index 000000000000..0be0cdb2f151
--- /dev/null
+++ b/media-sound/gogglesmm/gogglesmm-1.2.5-r1.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Fast and light music player"
+HOMEPAGE="https://gogglesmm.dev/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="a52 +aac alsa +dbus dca +flac jack libsamplerate +mad nls +opengl +opus"
+IUSE+=" +pulseaudio sndio stream tremor +vorbis"
+REQUIRED_USE="?? ( tremor vorbis )"
+
+RDEPEND="
+ dev-db/sqlite:3
+ dev-libs/expat
+ media-libs/taglib:=
+ >=x11-libs/fox-1.7.80:1.7
+ x11-libs/libICE
+ x11-libs/libSM
+ x11-libs/libX11
+ a52? ( media-libs/a52dec )
+ aac? ( media-libs/faad2 )
+ alsa? ( media-libs/alsa-lib )
+ dbus? ( sys-apps/dbus )
+ dca? ( media-libs/libdca )
+ flac? ( media-libs/flac:= )
+ jack? ( virtual/jack )
+ libsamplerate? ( media-libs/libsamplerate )
+ mad? ( media-libs/libmad )
+ nls? ( virtual/libintl )
+ opengl? (
+ media-libs/libepoxy[X]
+ virtual/glu
+ )
+ opus? (
+ media-libs/libogg
+ media-libs/opus
+ )
+ pulseaudio? ( media-libs/libpulse )
+ sndio? ( media-sound/sndio:= )
+ stream? (
+ dev-libs/libgcrypt:=
+ sys-libs/zlib
+ )
+ tremor? (
+ media-libs/libogg
+ media-libs/tremor
+ )
+ vorbis? (
+ media-libs/libogg
+ media-libs/libvorbis
+ )
+"
+DEPEND="${RDEPEND}
+ x11-base/xorg-proto
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+ # https://github.com/gogglesmm/gogglesmm/pull/120
+ "${FILESDIR}"/${PN}-1.2.5-libsamplerate.patch
+)
+
+src_configure() {
+ local mycmakeargs=(
+ -DCMAKE_SKIP_RPATH=ON
+ # prevent confict with libgap.so from sci-mathematics/gap
+ -DBUILD_GAP_SHARED_LIB=OFF
+ -DWITH_A52="$(usex a52)"
+ -DWITH_ALSA="$(usex alsa)"
+ # disable bundled fox
+ -DWITH_CFOX=OFF
+ -DWITH_DBUS="$(usex dbus)"
+ -DWITH_DCA="$(usex dca)"
+ -DWITH_FAAD="$(usex aac)"
+ -DWITH_FLAC="$(usex flac)"
+ -DWITH_GCRYPT="$(usex stream)"
+ -DWITH_GNUTLS=OFF
+ -DWITH_JACK="$(usex jack)"
+ -DWITH_LIBSAMPLERATE="$(usex libsamplerate)"
+ -DWITH_MAD="$(usex mad)"
+ -DWITH_NLS="$(usex nls)"
+ # only relevant if associate with tremor, vorbis or opus
+ -DWITH_OGG=ON
+ -DWITH_OPENGL="$(usex opengl)"
+ -DWITH_OPENSSL=OFF
+ -DWITH_OPUS="$(usex opus)"
+ -DWITH_PULSE="$(usex pulseaudio)"
+ # X11 session by default as x11-libs/fox is X11 only
+ -DWITH_SESSION=ON
+ -DWITH_SNDIO="$(usex sndio)"
+ -DWITH_TREMOR="$(usex tremor)"
+ -DWITH_VORBIS="$(usex vorbis)"
+ -DWITH_ZLIB="$(usex stream)"
+ )
+ cmake_src_configure
+}
next reply other threads:[~2025-04-26 1:17 UTC|newest]
Thread overview: 14+ messages / expand[flat|nested] mbox.gz Atom feed top
2025-04-26 1:17 Sam James [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-03-09 23:04 [gentoo-commits] repo/gentoo:master commit in: media-sound/gogglesmm/ Sam James
2025-03-09 23:01 Sam James
2022-09-10 8:41 Sam James
2021-07-04 22:17 Sam James
2021-07-04 22:17 Sam James
2020-09-06 9:53 Miroslav Šulc
2020-09-05 17:30 Miroslav Šulc
2019-12-28 8:46 Jason A. Donenfeld
2019-06-05 14:31 Jason A. Donenfeld
2017-06-10 3:06 Jason Donenfeld
2016-09-30 2:21 Jason Donenfeld
2016-09-21 6:25 Patrick Lauer
2016-09-21 1:01 Jason Donenfeld
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1745630110.70d74ebb9250524877692d31389751567643eb32.sam@gentoo \
--to=sam@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox