From: "Pacho Ramos" <pacho@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/gnome-builder/
Date: Sat, 9 Nov 2024 10:40:02 +0000 (UTC) [thread overview]
Message-ID: <1731148787.71153e67ba05acf8ae5fd3f4187b4c42e94b8043.pacho@gentoo> (raw)
commit: 71153e67ba05acf8ae5fd3f4187b4c42e94b8043
Author: Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri May 10 13:19:32 2024 +0000
Commit: Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Nov 9 10:39:47 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=71153e67
dev-util/gnome-builder: Bump to 46.3
Closes: https://bugs.gentoo.org/884067
Closes: https://bugs.gentoo.org/914751
Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>
dev-util/gnome-builder/Manifest | 1 +
dev-util/gnome-builder/gnome-builder-46.3.ebuild | 274 +++++++++++++++++++++++
2 files changed, 275 insertions(+)
diff --git a/dev-util/gnome-builder/Manifest b/dev-util/gnome-builder/Manifest
index 42d2ecf2959c..71997b031cf0 100644
--- a/dev-util/gnome-builder/Manifest
+++ b/dev-util/gnome-builder/Manifest
@@ -1 +1,2 @@
DIST gnome-builder-44.2.tar.xz 9788192 BLAKE2B 3e31997a840ea288db37d942aa5b5ff92dce6754a9fe5984e9e20334c7e0323835d279bee0744277cbe2f111076a932efa692d3e0e229230da3c0d782faa7442 SHA512 0e0bdf57b1467789b6fe221e484e2cce5e37dae0fe3c190db51ec0f150a0ced1eca574bebceefe4ca33d31b4f09f472a0853fce24b1ef3f5de82256fa01f6090
+DIST gnome-builder-46.3.tar.xz 9102324 BLAKE2B 3c03eab7e60e4e8a4f10e165b5ae8bbc764fb102df3b594160def47720b94787f6b8d25479e0148c5369b7cf3256d5c8455cf54cf0f42c78424a5e1e17028682 SHA512 1d765f9a4da17d6c1cda688c0590d34b9fc8da8c2d427e4fde57e35b4b78b13905792da065d630d1b351d90ca25a276cc7a680c3b02fd9d5ba4c236a150325cc
diff --git a/dev-util/gnome-builder/gnome-builder-46.3.ebuild b/dev-util/gnome-builder/gnome-builder-46.3.ebuild
new file mode 100644
index 000000000000..93d8191878af
--- /dev/null
+++ b/dev-util/gnome-builder/gnome-builder-46.3.ebuild
@@ -0,0 +1,274 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..13} )
+DISABLE_AUTOFORMATTING=1
+FORCE_PRINT_ELOG=1
+
+inherit gnome.org gnome2-utils llvm meson optfeature python-single-r1 readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="An IDE for writing GNOME-based software"
+HOMEPAGE="https://apps.gnome.org/Builder/ https://gitlab.gnome.org/GNOME/gnome-builder"
+
+# FIXME: Review licenses at some point
+LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="clang doc +d-spy flatpak +git gtk-doc spell +sysprof test +webkit"
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ flatpak? ( git )
+"
+
+# When bumping, pay attention to all the included plugins/*/meson.build (and other) build files and the requirements within.
+# `grep -rI dependency * --include='meson.build'` can give a good initial idea for external deps and their double checking.
+# The listed RDEPEND order should roughly match that output as well, with toplevel one first then sorted by file path.
+# Most plugins have no extra requirements and default to enabled; we need to handle the ones with extra requirements. Many of
+# them have optional runtime dependencies, for which we try to at least notify the user via DOC_CONTENTS (but not all small
+# things); `grep -rI -e 'command-pattern.*=' -e 'push_arg'` can give a (spammy) idea, plus python imports in try/except.
+
+# Editorconfig needs old pcre, with vte migrating away, might want it optional or ported to pcre2?
+# An introspection USE flag of a dep is required if any introspection based language plugin wants to use it (grep for gi.repository). Last full check at 3.28.4
+
+# TODO: Handle llvm slots via llvm.eclass; see plugins/clang/meson.build
+RDEPEND="
+ >=dev-libs/glib-2.75:2
+ >=gui-libs/gtk-4.10:4[introspection]
+ >=gui-libs/libadwaita-1.5_alpha:1
+ >=gui-libs/libpanel-1.5.0:1
+ >=gui-libs/gtksourceview-5.8:5[introspection]
+ >=dev-libs/json-glib-1.2.0
+ >=dev-libs/jsonrpc-glib-3.43.0:=
+ >=dev-libs/libdex-0.2:=
+ >=dev-libs/libpeas-1.99.0:2[python,${PYTHON_SINGLE_USEDEP}]
+ dev-libs/libportal:=[gtk,introspection]
+ >=dev-libs/template-glib-3.36.1:=[introspection]
+ >=gui-libs/vte-0.76.0:2.91-gtk4[introspection]
+ >=dev-libs/libxml2-2.9.0
+ webkit? ( >=net-libs/webkit-gtk-2.38.0:6=[introspection] )
+ >=app-text/cmark-0.29.0:0=
+ d-spy? ( >=dev-debug/d-spy-1.4.0:1 )
+ app-text/editorconfig-core-c
+ flatpak? (
+ dev-util/ostree
+ >=net-libs/libsoup-3:3.0
+ >=sys-apps/flatpak-1.10.2
+ )
+ git? (
+ dev-libs/libgit2:=[ssh,threads]
+ >=dev-libs/libgit2-glib-1.1.0[ssh]
+ )
+
+ >=dev-libs/gobject-introspection-1.74.0:=
+ ${PYTHON_DEPS}
+ clang? ( sys-devel/clang:= )
+ spell? (
+ app-text/enchant:2
+ dev-libs/icu:=
+ )
+ sysprof? (
+ >=dev-util/sysprof-45.0[gtk]
+ )
+"
+DEPEND="${RDEPEND}"
+# TODO: runtime ctags path finding..
+
+# desktop-file-utils required for tests, but we have it in deptree for xdg update-desktop-database anyway, so be explicit and unconditional
+# appstream-glib needed for validation with appstream-util with FEATURES=test
+BDEPEND="
+ doc? (
+ $(python_gen_cond_dep '
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+ ')
+ )
+ gtk-doc? (
+ dev-util/gi-docgen
+ app-text/docbook-xml-dtd:4.3
+ )
+ test? (
+ dev-libs/appstream-glib
+ sys-apps/dbus
+ )
+ dev-util/desktop-file-utils
+ dev-util/glib-utils
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+"
+
+DOC_CONTENTS='gnome-builder can use various other dependencies on runtime to provide
+extra capabilities beyond these expressed via USE flags. Some of these
+that are currently available with packages include:
+
+* dev-util/ctags with exuberant-ctags selected via "eselect ctags" for
+ C, C++, Python, JavaScript, CSS, HTML and Ruby autocompletion, semantic
+ highlighting and symbol resolving support.
+* dev-python/python-lsp-server for more accurate Python
+ autocompletion support.
+* dev-util/valgrind for integration with valgrind.
+* dev-util/meson for integration with the Meson build system.
+* virtual/rust for integration with the Rust Cargo build system.
+* dev-util/cmake for integration with the CMake build system.
+* net-libs/nodejs[npm] for integration with the NPM package system.
+'
+# FIXME: Package codespell and mention here
+# FIXME: Package gnome-code-assistance and mention here, or maybe USE flag and default enable because it's rather important
+# eslint for additional diagnostics in JavaScript files (what package has this? At least something via NPM..)
+# jhbuild support
+# rust support via rust-analyzer; Go via go-langserver
+# autotools stuff for autotools plugin; gtkmm/autoconf-archive for C++ template
+# gjs/gettext/mono/PHPize stuff, but most of these are probably installed for other reasons anyways, when needed inside IDE
+# stylelint for stylesheet (CSS and co) linting
+# gvls for vala language-server integration
+
+llvm_check_deps() {
+ has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+ use clang && llvm_pkg_setup
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dchannel=other
+
+ -Ddevelopment=false
+ -Dtracing=false
+ -Dprofiling=false # not passing -pg to CFLAGS
+ -Dtcmalloc=false
+ -Dwith_safe_path=''
+ -Dgnome_sdk_version=master
+ $(meson_use doc help)
+ $(meson_use gtk-doc docs)
+ -Dnetwork_tests=false
+ -Dctags_path=''
+ $(meson_feature webkit)
+
+ -Dplugin_autotools=true
+ -Dplugin_bash_language_server=true
+ -Dplugin_blueprint=true
+ -Dplugin_buildstream=true
+ -Dplugin_c_pack=true
+ -Dplugin_cargo=true
+ $(meson_use clang plugin_clang)
+ $(meson_use clang plugin_clangd)
+ $(meson_use clang plugin_clang_format)
+ -Dplugin_cmake=true
+ -Dplugin_codesearch=true
+ -Dplugin_codeshot=true
+ -Dplugin_codespell=true
+ -Dplugin_code_index=true
+ -Dplugin_copyright=true
+ -Dplugin_ctags=true
+ -Dplugin_deviced=false # libdeviced not packaged?
+ $(meson_use d-spy plugin_dspy)
+ -Dplugin_dub=true
+ -Dplugin_editorconfig=true
+ -Dplugin_elixir_ls=true
+ -Dplugin_eslint=true
+ -Dplugin_file_search=true
+ $(meson_use flatpak plugin_flatpak)
+ -Dplugin_flake8=true
+ -Dplugin_gdb=true
+ -Dplugin_gdiagnose=true
+ -Dplugin_gettext=true
+ $(meson_use git plugin_git)
+ -Dplugin_glsl_language_server=true
+ -Dplugin_golang=true
+ -Dplugin_gopls=true
+ -Dplugin_gradle=true
+ -Dplugin_grep=true
+ -Dplugin_hadolint=true
+ -Dplugin_html_completion=true
+ $(meson_use webkit plugin_html_preview)
+ -Dplugin_intelephense=true
+ -Dplugin_jdtls=true
+ -Dplugin_jedi_language_server=false
+ -Dplugin_jhbuild=true
+ -Dplugin_lua_language_server=true
+ -Dplugin_make=true
+ -Dplugin_make_templates=true
+ $(meson_use webkit plugin_markdown_preview)
+ $(meson_use webkit plugin_markdown_indenter)
+ -Dplugin_maven=true
+ -Dplugin_meson=true
+ -Dplugin_meson_templates=true
+ -Dplugin_modelines=true
+ -Dplugin_mono=true
+ -Dplugin_newcomers=true
+ -Dplugin_notification=true
+ -Dplugin_npm=true
+ -Dplugin_phpize=true
+ -Dplugin_podman=true
+ -Dplugin_pygi=true
+ -Dplugin_python_lsp_server=true
+ -Dplugin_qemu=true
+ -Dplugin_quick_highlight=true
+ -Dplugin_retab=true
+ -Dplugin_rstcheck=true
+ -Dplugin_rubocop=true
+ -Dplugin_rust_analyzer=false # rust-analyzer not packaged
+ -Dplugin_serve_d=true
+ -Dplugin_shellcheck=true
+ -Dplugin_shellcmd=true
+ -Dplugin_sourcekit_lsp=true
+ $(meson_use spell plugin_spellcheck)
+ $(meson_use webkit plugin_sphinx_preview)
+ -Dplugin_stylelint=true
+ -Dplugin_swift=true
+ -Dplugin_swift_mesonlsp=true
+ -Dplugin_swiftformat=true
+ -Dplugin_swiftlint=true
+ $(meson_use sysprof plugin_sysprof)
+ -Dplugin_todo=true
+ -Dplugin_ts_language_server=true
+ -Dplugin_update_manager=true
+ -Dplugin_valac=true
+ -Dplugin_vala_indenter=true
+ -Dplugin_vala_language_server=true
+ -Dplugin_valgrind=true
+ -Dplugin_waf=true
+ -Dplugin_words=true
+ -Dplugin_xml_pack=true
+ -Dplugin_zls=true
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ python_optimize
+ if use doc; then
+ rm "${ED}"/usr/share/doc/gnome-builder/en/.buildinfo || die
+ rm "${ED}"/usr/share/doc/gnome-builder/en/objects.inv || die
+ # custom docdir in build system, blocked by https://github.com/mesonbuild/meson/issues/825
+ mv "${ED}"/usr/share/doc/gnome-builder/en "${ED}"/usr/share/doc/${PF}/html || die
+ # _sources subdir left in on purpose, as HTML links to the rst files as "View page source". Additionally default docompress exclusion of /html/ already ensures they aren't compressed, thus linkable as-is.
+ rmdir "${ED}"/usr/share/doc/gnome-builder/ || die
+ fi
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+ readme.gentoo_print_elog
+
+ optfeature_header "Language support"
+ optfeature "Rust's Cargo build system" virtual/rust
+ optfeature "CMake" dev-util/cmake
+ optfeature "Java Maven build system" dev-java/maven-bin
+ optfeature "Meson Build system" dev-util/meson
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
+
+src_test() {
+ virtx dbus-run-session meson test -C "${BUILD_DIR}"
+}
next reply other threads:[~2024-11-09 10:40 UTC|newest]
Thread overview: 58+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-11-09 10:40 Pacho Ramos [this message]
-- strict thread matches above, loose matches on Subject: below --
2025-10-18 15:13 [gentoo-commits] repo/gentoo:master commit in: dev-util/gnome-builder/ Sam James
2025-10-18 15:13 Sam James
2025-10-18 15:13 Sam James
2025-10-13 3:02 Sam James
2025-08-05 10:37 Pacho Ramos
2025-08-05 10:37 Pacho Ramos
2025-07-29 11:43 Pacho Ramos
2025-06-29 9:37 Sam James
2025-02-20 10:20 Michał Górny
2025-01-16 16:55 Pacho Ramos
2025-01-16 16:55 Pacho Ramos
2024-11-09 10:40 Pacho Ramos
2024-05-10 7:20 Mart Raudsepp
2023-11-04 23:03 Mart Raudsepp
2023-11-04 23:03 Mart Raudsepp
2023-10-29 22:23 Mart Raudsepp
2023-05-05 9:01 Arthur Zamarin
2023-04-28 16:35 Matt Turner
2023-02-06 2:40 Matt Turner
2023-02-03 16:41 Matt Turner
2023-01-27 11:52 Mart Raudsepp
2022-12-16 20:37 Arthur Zamarin
2022-12-02 14:35 Matt Turner
2022-11-16 21:17 Matt Turner
2022-11-16 16:56 Matt Turner
2022-05-08 4:22 Matt Turner
2021-10-17 21:07 Mart Raudsepp
2021-05-06 6:09 Matt Turner
2021-05-06 6:09 Matt Turner
2021-04-30 16:39 Matt Turner
2021-04-29 1:02 Matt Turner
2021-04-19 0:46 Matt Turner
2021-04-12 22:16 Matt Turner
2021-02-06 9:59 Mart Raudsepp
2020-12-08 15:41 Mart Raudsepp
2020-08-14 20:45 Mart Raudsepp
2020-08-14 20:45 Mart Raudsepp
2020-07-28 6:52 Mart Raudsepp
2020-06-27 11:48 Mart Raudsepp
2020-06-18 11:27 Mart Raudsepp
2020-05-19 7:24 Mart Raudsepp
2020-04-17 19:50 Mart Raudsepp
2020-04-13 16:12 Agostino Sarubbo
2020-04-13 14:48 Agostino Sarubbo
2020-03-14 21:08 Mart Raudsepp
2020-02-29 21:22 Mart Raudsepp
2020-02-16 10:35 Mart Raudsepp
2020-02-11 13:00 Mart Raudsepp
2020-02-05 15:00 Mart Raudsepp
2019-03-30 16:30 Mart Raudsepp
2019-01-13 17:19 Mart Raudsepp
2018-12-17 15:08 Mart Raudsepp
2018-09-24 20:13 Mart Raudsepp
2018-09-12 14:39 Thomas Deutschmann
2018-04-29 0:08 Mart Raudsepp
2018-04-26 22:32 Aaron Bauman
2018-04-26 17:15 Thomas Deutschmann
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1731148787.71153e67ba05acf8ae5fd3f4187b4c42e94b8043.pacho@gentoo \
--to=pacho@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox