[gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Arthur Zamarin" <arthurzam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/
Date: Mon, 17 Jun 2024 19:42:32 +0000 (UTC)	[thread overview]
Message-ID: <1718653343.94526d04f15770a1724fcebc136f8929f0937fc1.arthurzam@gentoo> (raw)

commit:     94526d04f15770a1724fcebc136f8929f0937fc1
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 17 19:42:05 2024 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Mon Jun 17 19:42:23 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=94526d04

media-video/qmplay2: add 24.06.16

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 media-video/qmplay2/Manifest                |   1 +
 media-video/qmplay2/qmplay2-24.06.16.ebuild | 138 ++++++++++++++++++++++++++++
 2 files changed, 139 insertions(+)

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index d823df439911..bbcfe75897f2 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,2 +1,3 @@
 DIST QMPlay2-src-24.04.07.tar.xz 2042608 BLAKE2B 234d21478c090566210f48e62247a22c11f68d7491938d3c59aa201999eb5e0dd54cb9040cf75c655ca0b2337003b7edbe9574e45fb5ca1293e505d0e9824884 SHA512 998929c825db6c92f8a4fa22e998e51ba2aa6d6742d678aef0c380e9131f4de4a9e49c7008b73f8c19b1c8048f17288dd895fc3cade12becb729e5d981e90eac
 DIST QMPlay2-src-24.05.23.tar.xz 2040496 BLAKE2B 98842880382629c0a014d048fa55308809a980c097867d9240321ca21733278439cedebc7a381793d8605f2c29108de6fa4c4ef8daf6261db9ea4248cf0d501b SHA512 a09419fb7f59c30923e51a0673aa219bfb9e9b461775d17c3ac0d683ab145e71f8ecabecee6ace9deb1e0681ea94b8c71682a014bb49d4ee85452e7bce53b390
+DIST QMPlay2-src-24.06.16.tar.xz 2042180 BLAKE2B ba076fc7cb6c77f16529d082690c4d994e53c62cdf994c1e35afdb5255b203d0ccc72db1195730be60471d5fff48deca47e1348b0b41f22e898818206f8c53bb SHA512 3a8a7b99c7861318cfe0a6e096a27bb86f64cfafacf4ec52bdc4e955dd320d6e0f369dcb466dfd9bb73f8d173a2fc768848e7356f03590e429ae30270daf176b

diff --git a/media-video/qmplay2/qmplay2-24.06.16.ebuild b/media-video/qmplay2/qmplay2-24.06.16.ebuild
new file mode 100644
index 000000000000..1bb22871659a
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-24.06.16.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio qt6 sid
+	shaders +taglib vaapi videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )
+"
+
+RDEPEND="
+	media-video/ffmpeg:=[vaapi?]
+	!qt6? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5[X(-),vulkan?]
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+		extensions? ( dev-qt/qtdeclarative:5 )
+		videofilters? ( dev-qt/qtconcurrent:5 )
+	)
+	qt6? (
+		dev-qt/qtbase:6[concurrent,dbus,gui,network,opengl?,ssl,vulkan?,widgets]
+		dev-qt/qt5compat:6
+		dev-qt/qtsvg:6
+		extensions? ( dev-qt/qtdeclarative:6 )
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? ( media-libs/libva[X] )
+	vulkan? ( >=media-libs/vulkan-loader-1.2.133 )
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	!qt6? ( dev-qt/linguist-tools:5 )
+	qt6? ( dev-qt/qttools:6[linguist] )
+"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=$(usex qt6)
+		# core
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_PM=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}

next             reply	other threads:[~2024-06-17 19:42 UTC|newest]

Thread overview: 79+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2024-06-17 19:42 Arthur Zamarin [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-09-12 13:40 [gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/ Arthur Zamarin
2025-09-05  8:10 Arthur Zamarin
2025-08-18 14:08 Sam James
2025-06-28  6:24 Arthur Zamarin
2025-06-28  6:24 Arthur Zamarin
2025-06-26  3:11 Sam James
2025-06-13  7:34 Arthur Zamarin
2025-06-13  7:34 Arthur Zamarin
2025-02-18 22:10 Sam James
2025-01-22 17:40 Arthur Zamarin
2025-01-22 17:34 Arthur Zamarin
2025-01-08 20:43 Sam James
2024-12-30 20:02 Arthur Zamarin
2024-12-28 18:18 Arthur Zamarin
2024-12-28  0:05 Andreas Sturmlechner
2024-12-25 19:51 Arthur Zamarin
2024-12-13 10:15 Arthur Zamarin
2024-07-20 12:38 Arthur Zamarin
2024-07-20 11:14 Arthur Zamarin
2024-07-20 10:58 Arthur Zamarin
2024-06-25 22:03 Sam James
2024-05-25  5:05 Arthur Zamarin
2024-05-25  5:05 Arthur Zamarin
2024-05-24  6:18 Arthur Zamarin
2024-04-19  6:08 Arthur Zamarin
2024-04-08 19:52 Arthur Zamarin
2024-04-08 15:30 Arthur Zamarin
2024-04-04 16:32 Arthur Zamarin
2024-04-03  9:23 Arthur Zamarin
2024-03-16 16:33 Arthur Zamarin
2024-03-08 11:33 Arthur Zamarin
2024-02-20 14:30 Arthur Zamarin
2024-02-15 13:04 Ionen Wolkens
2023-12-05  7:53 Arthur Zamarin
2023-11-04 20:14 Arthur Zamarin
2023-10-23  8:26 Arthur Zamarin
2023-09-07 17:40 Arthur Zamarin
2023-09-07 17:40 Arthur Zamarin
2023-08-22 19:48 Arthur Zamarin
2023-08-22 19:48 Arthur Zamarin
2023-08-09 17:21 Arthur Zamarin
2023-08-09 17:21 Arthur Zamarin
2023-06-28 18:30 Arthur Zamarin
2023-06-17 19:32 Arthur Zamarin
2023-06-09 14:42 Arthur Zamarin
2023-06-04 17:03 Arthur Zamarin
2023-05-30 19:39 Andreas Sturmlechner
2023-05-23  2:52 Sam James
2023-02-18 13:23 Arthur Zamarin
2023-02-17 19:08 Arthur Zamarin
2023-02-17 19:08 Arthur Zamarin
2022-10-17 17:32 Arthur Zamarin
2022-08-26 18:52 Arthur Zamarin
2022-07-29 10:52 Arthur Zamarin
2022-06-17  6:20 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2021-08-22 19:10 Arthur Zamarin
2021-08-22 18:49 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-04-06 21:17 Sam James
2021-03-31 11:09 Joonas Niilola
2021-03-31 11:09 Joonas Niilola
2021-03-20  8:48 Joonas Niilola
2020-08-05 12:19 Joonas Niilola
2020-06-23  8:36 Joonas Niilola
2020-05-06 11:51 Joonas Niilola
2020-03-14 12:07 Joonas Niilola
2020-01-19 23:53 Andreas Sturmlechner
2020-01-19 23:53 Andreas Sturmlechner
2019-12-22 17:21 Joonas Niilola
2019-12-22 16:59 Joonas Niilola

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:d823df43991 dfblob:bbcfe75897f dfblob:1bb22871659 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1718653343.94526d04f15770a1724fcebc136f8929f0937fc1.arthurzam@gentoo \
    --to=arthurzam@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox