[gentoo-commits] repo/gentoo:master commit in: app-i18n/scim/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Arthur Zamarin" <arthurzam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: app-i18n/scim/
Date: Fri, 31 May 2024 11:59:08 +0000 (UTC)	[thread overview]
Message-ID: <1717156732.8fb5c71aadf6bcc5951f7e92883bb6853534f33c.arthurzam@gentoo> (raw)

commit:     8fb5c71aadf6bcc5951f7e92883bb6853534f33c
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri May 31 11:57:41 2024 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri May 31 11:58:52 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8fb5c71a

app-i18n/scim: EAPI=8, deps fixes, enable tests

Closes: https://bugs.gentoo.org/891457
Closes: https://bugs.gentoo.org/865485
Closes: https://bugs.gentoo.org/841593
Closes: https://bugs.gentoo.org/836019
Closes: https://bugs.gentoo.org/574234
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 app-i18n/scim/scim-1.4.18-r1.ebuild | 129 ++++++++++++++++++++++++++++++++++++
 1 file changed, 129 insertions(+)

diff --git a/app-i18n/scim/scim-1.4.18-r1.ebuild b/app-i18n/scim/scim-1.4.18-r1.ebuild
new file mode 100644
index 000000000000..17444be79e05
--- /dev/null
+++ b/app-i18n/scim/scim-1.4.18-r1.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic gnome2-utils
+
+DESCRIPTION="Smart Common Input Method (SCIM) is an Input Method (IM) development platform"
+HOMEPAGE="https://github.com/scim-im/scim"
+SRC_URI="https://github.com/scim-im/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc gtk3 static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-accessibility/at-spi2-core:2
+	dev-libs/glib:2
+	dev-libs/libltdl
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libX11
+	>=x11-libs/pango-1
+	gtk3? ( x11-libs/gtk+:3[X] )
+	!gtk3? ( x11-libs/gtk+:2 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	>=dev-util/intltool-0.33
+	dev-build/libtool
+	doc? (
+		app-text/doxygen
+		>=app-text/docbook-xsl-stylesheets-1.73.1
+	)
+"
+
+DOCS=( README AUTHORS ChangeLog docs/developers docs/scim.cfg )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.4.18-slibtool.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug #83625
+	filter-flags -fvisibility-inlines-hidden -fvisibility=hidden
+
+	local myeconfargs=(
+		--enable-ld-version-script
+		$(usex gtk3 --with-gtk-version={3,2})
+		$(usex !gtk3 --disable-gtk3-immodule)
+		--disable-qt3-immodule
+		--disable-qt4-immodule
+		--without-included-libltdl
+		$(use_enable static-libs static)
+		$(use_enable test tests)
+		$(use_with doc doxygen)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+	use doc && emake docs
+}
+
+src_test() {
+	./tests/testlang || die "testlang failed"
+	./tests/testiconvert || die "testiconvert failed"
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${S}/docs/html/" )
+	default
+	if ! use static-libs; then
+		find "${ED}" -name '*.la' -delete || die
+	fi
+
+	sed -e "s:@EPREFIX@:${EPREFIX}:" "${FILESDIR}/xinput-${PN}" > "${T}/${PN}.conf" || die
+	insinto /etc/X11/xinit/xinput.d
+	doins "${T}/${PN}.conf"
+}
+
+pkg_postinst() {
+	elog
+	elog "To use SCIM with both GTK and XIM, you should use the following"
+	elog "in your user startup scripts such as .gnomerc or .xinitrc:"
+	elog
+	elog "LANG='your_language' scim -d"
+	elog "export XMODIFIERS=@im=SCIM"
+	elog "export GTK_IM_MODULE=\"scim\""
+	elog "export QT_IM_MODULE=\"scim\""
+	elog
+	elog "where 'your_language' can be zh_CN, zh_TW, ja_JP.eucJP or any other"
+	elog "UTF-8 locale such as en_US.UTF-8 or ja_JP.UTF-8"
+	elog
+	elog "To use Chinese input methods:"
+	elog "	# emerge app-i18n/scim-tables app-i18n/scim-pinyin"
+	elog "To use Korean input methods:"
+	elog "	# emerge app-i18n/scim-hangul"
+	elog "To use Japanese input methods:"
+	elog "	# emerge app-i18n/scim-anthy"
+	elog "To use various input methods (more than 30 languages):"
+	elog "	# emerge app-i18n/scim-m17n"
+	elog
+	elog "Please modify ${EPREFIX}/etc/scim/global and add your UTF-8 locale to"
+	elog "/SupportedUnicodeLocales entry."
+	elog
+	ewarn
+	ewarn "If you upgraded from scim-1.2.x or scim-1.0.x, you should remerge all SCIM modules."
+	ewarn
+
+	gnome2_query_immodules_gtk2
+}
+
+pkg_postrm() {
+	gnome2_query_immodules_gtk2
+}

next             reply	other threads:[~2024-05-31 11:59 UTC|newest]

Thread overview: 38+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2024-05-31 11:59 Arthur Zamarin [this message]
  -- strict thread matches above, loose matches on Subject: below --
2024-06-17 15:36 [gentoo-commits] repo/gentoo:master commit in: app-i18n/scim/ Arthur Zamarin
2024-06-17 15:35 Arthur Zamarin
2024-06-15 14:14 James Le Cuirot
2024-06-15 13:16 David Seifert
2024-06-13 19:44 Arthur Zamarin
2024-06-13 18:59 Arthur Zamarin
2024-06-13 18:53 Arthur Zamarin
2024-06-13 18:52 Arthur Zamarin
2024-06-13 18:52 Arthur Zamarin
2024-06-13 18:52 Arthur Zamarin
2021-07-28  3:00 Yixun Lan
2020-10-23 12:34 Andreas Sturmlechner
2020-05-23  8:27 Andreas Sturmlechner
2020-02-09 12:24 Mart Raudsepp
2019-05-28  2:35 Aaron Bauman
2019-03-11 18:44 Matt Turner
2019-03-02 23:28 Andreas Sturmlechner
2019-02-04 19:41 Sergei Trofimovich
2018-08-25 20:37 Michał Górny
2018-07-08 10:48 Markus Meier
2018-06-23 14:01 Mikle Kolyada
2018-06-19 19:13 Sergei Trofimovich
2018-06-19 12:55 Thomas Deutschmann
2018-04-16 18:29 Mike Gilbert
2018-03-21  5:55 Markus Meier
2018-03-08 19:33 Mike Gilbert
2018-03-08 19:33 Mike Gilbert
2018-02-06 18:36 Thomas Deutschmann
2018-01-29  8:22 Tobias Klausmann
2018-01-05  6:55 Benda XU
2018-01-05  6:49 Benda XU
2017-12-28 11:58 Sergei Trofimovich
2017-12-16 17:24 Tobias Klausmann
2017-12-03 10:34 Sergei Trofimovich
2017-12-02 21:42 Sergei Trofimovich
2016-06-02  1:43 Benda XU
2016-05-11  3:13 Benda XU

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:17444be79e0 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: app-i18n/scim/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1717156732.8fb5c71aadf6bcc5951f7e92883bb6853534f33c.arthurzam@gentoo \
    --to=arthurzam@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox