[gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Arthur Zamarin" <arthurzam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/
Date: Sat, 16 Mar 2024 16:33:51 +0000 (UTC)	[thread overview]
Message-ID: <1710606824.2fdb4c33f07daab690bc18c498dfde1b1e29944a.arthurzam@gentoo> (raw)

commit:     2fdb4c33f07daab690bc18c498dfde1b1e29944a
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 16 16:33:23 2024 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sat Mar 16 16:33:44 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2fdb4c33

media-video/qmplay2: add 24.03.16

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 media-video/qmplay2/Manifest                |   1 +
 media-video/qmplay2/qmplay2-24.03.16.ebuild | 140 ++++++++++++++++++++++++++++
 2 files changed, 141 insertions(+)

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 4d3b159c6549..0a043972956f 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1 +1,2 @@
 DIST QMPlay2-src-23.10.22.tar.xz 1442072 BLAKE2B 605c446c976d523df82f1cce70b4efff5ef630149acc61d453521dbe82af407612f9950d14e62295f325fcd8aa7c0fe3e46e0aa2193fa81123118d8fe14f081e SHA512 a32ee5e2c952777c21a28927d96fdaca9026c6b3f0586bb6d5d9c45b73604e5f7f505c0d076f611504e4ff20b339fde4997cfdb8c217940f1a7b414e1530381f
+DIST QMPlay2-src-24.03.16.tar.xz 2013280 BLAKE2B bb241c56a6988659c3810c2d3a922e87f0a7bf324a58d36b4e2efaf5f452c2dbb7aa5a34ff909edc30675f566a2e0c92b1fc1d2524288302cb10fe0a75bfface SHA512 166c4acd2c79cd43693b0c3f8a4802a9b277f519d042a3eabe551d8d277f3f8ec41c74b830c36f0897fe5f247e306e9374eb982441f5a825d355af60b3660495

diff --git a/media-video/qmplay2/qmplay2-24.03.16.ebuild b/media-video/qmplay2/qmplay2-24.03.16.ebuild
new file mode 100644
index 000000000000..90c70de03992
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-24.03.16.ebuild
@@ -0,0 +1,140 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio qt6 sid
+	shaders +taglib vaapi vdpau videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )
+"
+
+RDEPEND="
+	media-video/ffmpeg:=[vaapi?,vdpau?]
+	!qt6? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5[X(-),vulkan?]
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+		extensions? ( dev-qt/qtdeclarative:5 )
+		videofilters? ( dev-qt/qtconcurrent:5 )
+	)
+	qt6? (
+		dev-qt/qtbase:6[concurrent,dbus,gui,network,opengl?,ssl,vulkan?,widgets]
+		dev-qt/qt5compat:6
+		dev-qt/qtsvg:6
+		extensions? ( dev-qt/qtdeclarative:6 )
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? ( media-libs/libva[X] )
+	vulkan? ( >=media-libs/vulkan-loader-1.2.133 )
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	!qt6? ( dev-qt/linguist-tools:5 )
+	qt6? ( dev-qt/qttools:6[linguist] )
+"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=$(usex qt6)
+		# core
+		-DUSE_LINK_TIME_OPTIMIZATION=false
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_SUSPEND=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+		-DUSE_FFMPEG_VDPAU=$(usex vdpau)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}

next             reply	other threads:[~2024-03-16 16:33 UTC|newest]

Thread overview: 80+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2024-03-16 16:33 Arthur Zamarin [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-10-25  1:07 [gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/ Sam James
2025-09-12 13:40 Arthur Zamarin
2025-09-05  8:10 Arthur Zamarin
2025-08-18 14:08 Sam James
2025-06-28  6:24 Arthur Zamarin
2025-06-28  6:24 Arthur Zamarin
2025-06-26  3:11 Sam James
2025-06-13  7:34 Arthur Zamarin
2025-06-13  7:34 Arthur Zamarin
2025-02-18 22:10 Sam James
2025-01-22 17:40 Arthur Zamarin
2025-01-22 17:34 Arthur Zamarin
2025-01-08 20:43 Sam James
2024-12-30 20:02 Arthur Zamarin
2024-12-28 18:18 Arthur Zamarin
2024-12-28  0:05 Andreas Sturmlechner
2024-12-25 19:51 Arthur Zamarin
2024-12-13 10:15 Arthur Zamarin
2024-07-20 12:38 Arthur Zamarin
2024-07-20 11:14 Arthur Zamarin
2024-07-20 10:58 Arthur Zamarin
2024-06-25 22:03 Sam James
2024-06-17 19:42 Arthur Zamarin
2024-05-25  5:05 Arthur Zamarin
2024-05-25  5:05 Arthur Zamarin
2024-05-24  6:18 Arthur Zamarin
2024-04-19  6:08 Arthur Zamarin
2024-04-08 19:52 Arthur Zamarin
2024-04-08 15:30 Arthur Zamarin
2024-04-04 16:32 Arthur Zamarin
2024-04-03  9:23 Arthur Zamarin
2024-03-08 11:33 Arthur Zamarin
2024-02-20 14:30 Arthur Zamarin
2024-02-15 13:04 Ionen Wolkens
2023-12-05  7:53 Arthur Zamarin
2023-11-04 20:14 Arthur Zamarin
2023-10-23  8:26 Arthur Zamarin
2023-09-07 17:40 Arthur Zamarin
2023-09-07 17:40 Arthur Zamarin
2023-08-22 19:48 Arthur Zamarin
2023-08-22 19:48 Arthur Zamarin
2023-08-09 17:21 Arthur Zamarin
2023-08-09 17:21 Arthur Zamarin
2023-06-28 18:30 Arthur Zamarin
2023-06-17 19:32 Arthur Zamarin
2023-06-09 14:42 Arthur Zamarin
2023-06-04 17:03 Arthur Zamarin
2023-05-30 19:39 Andreas Sturmlechner
2023-05-23  2:52 Sam James
2023-02-18 13:23 Arthur Zamarin
2023-02-17 19:08 Arthur Zamarin
2023-02-17 19:08 Arthur Zamarin
2022-10-17 17:32 Arthur Zamarin
2022-08-26 18:52 Arthur Zamarin
2022-07-29 10:52 Arthur Zamarin
2022-06-17  6:20 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-04-19  5:51 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2022-01-29  9:13 Arthur Zamarin
2021-08-22 19:10 Arthur Zamarin
2021-08-22 18:49 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-08-22 17:42 Arthur Zamarin
2021-04-06 21:17 Sam James
2021-03-31 11:09 Joonas Niilola
2021-03-31 11:09 Joonas Niilola
2021-03-20  8:48 Joonas Niilola
2020-08-05 12:19 Joonas Niilola
2020-06-23  8:36 Joonas Niilola
2020-05-06 11:51 Joonas Niilola
2020-03-14 12:07 Joonas Niilola
2020-01-19 23:53 Andreas Sturmlechner
2020-01-19 23:53 Andreas Sturmlechner
2019-12-22 17:21 Joonas Niilola
2019-12-22 16:59 Joonas Niilola

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:4d3b159c654 dfblob:0a043972956 dfblob:90c70de0399 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: media-video/qmplay2/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1710606824.2fdb4c33f07daab690bc18c498dfde1b1e29944a.arthurzam@gentoo \
    --to=arthurzam@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox