[gentoo-commits] repo/gentoo:master commit in: media-gfx/renderdoc/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Matthew Smith" <matthew@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-gfx/renderdoc/
Date: Wed, 13 Mar 2024 16:27:37 +0000 (UTC)	[thread overview]
Message-ID: <1710347240.cc392d2312c7deca87163d85c2b2c6ae6af66af1.matthew@gentoo> (raw)

commit:     cc392d2312c7deca87163d85c2b2c6ae6af66af1
Author:     Matthew Smith <matthew <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 13 16:27:20 2024 +0000
Commit:     Matthew Smith <matthew <AT> gentoo <DOT> org>
CommitDate: Wed Mar 13 16:27:20 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cc392d23

media-gfx/renderdoc: drop 1.30-r1

Closes: https://bugs.gentoo.org/926549
Signed-off-by: Matthew Smith <matthew <AT> gentoo.org>

 media-gfx/renderdoc/renderdoc-1.30-r1.ebuild | 194 ---------------------------
 1 file changed, 194 deletions(-)

diff --git a/media-gfx/renderdoc/renderdoc-1.30-r1.ebuild b/media-gfx/renderdoc/renderdoc-1.30-r1.ebuild
deleted file mode 100644
index 2ee9da15af0d..000000000000
--- a/media-gfx/renderdoc/renderdoc-1.30-r1.ebuild
+++ /dev/null
@@ -1,194 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# The swig fork is required for compatibility with both provided and
-# 3rd-party Python scripts.  Required patch was sent to upstream in
-# 2014: https://github.com/swig/swig/pull/251
-MY_SWIG_VER=7
-MY_SWIG=swig-${PN}-${MY_SWIG_VER}
-
-AUTOTOOLS_AUTO_DEPEND="no"
-DOCS_BUILDER="sphinx"
-DOCS_DIR="docs"
-PYTHON_COMPAT=( python3_{9..11} )
-inherit autotools cmake flag-o-matic optfeature python-single-r1 docs qmake-utils verify-sig xdg
-
-DESCRIPTION="A stand-alone graphics debugging tool"
-HOMEPAGE="https://renderdoc.org https://github.com/baldurk/renderdoc"
-SRC_URI="
-	https://github.com/baldurk/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
-	qt5? ( https://github.com/baldurk/swig/archive/${PN}-modified-${MY_SWIG_VER}.tar.gz -> ${MY_SWIG}.tar.gz )
-	verify-sig? ( https://github.com/baldurk/renderdoc/releases/download/v${PV}/v${PV}.tar.gz.asc -> ${P}.tar.gz.asc )
-"
-
-# renderdoc: MIT
-#   + cmdline: BSD (not compatible with upstream lib)
-#   + farm fresh icons: CC-BY-3.0
-#   + half: MIT (not compatible with system dev-libs/half)
-#   + include-bin ZLIB (upstream doesn't exist anymore, maintained in tree)
-#   + md5: public-domain
-#   + plthook: BSD-2
-#   + pugixml: MIT
-#   + radeon gpu analyzer: MIT
-#   + source code pro: OFL-1.1
-#   + stb: public-domain
-#   + tinyfiledialogs: ZLIB
-#   + glslang: BSD
-#   + docs? ( sphinx.paramlinks: MIT )
-# swig: GPL-3+ BSD BSD-2
-LICENSE="BSD BSD-2 CC-BY-3.0 GPL-3+ MIT OFL-1.1 public-domain ZLIB"
-SLOT="0"
-KEYWORDS="amd64"
-IUSE="pyside2 qt5"
-REQUIRED_USE="doc? ( qt5 ) pyside2? ( qt5 ) qt5? ( ${PYTHON_REQUIRED_USE} )"
-
-RDEPEND="
-	app-arch/lz4:=
-	app-arch/zstd:=
-	dev-libs/miniz:=
-	x11-libs/libX11
-	x11-libs/libxcb:=
-	x11-libs/xcb-util-keysyms
-	virtual/opengl
-	pyside2? (
-		$(python_gen_cond_dep '
-			dev-python/pyside2[${PYTHON_USEDEP}]
-		')
-	)
-	qt5? (
-		${PYTHON_DEPS}
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtnetwork:5[ssl]
-		dev-qt/qtsvg:5
-		dev-qt/qtwidgets:5
-		dev-qt/qtx11extras:5
-	)
-"
-DEPEND="${RDEPEND}"
-# qtcore provides qmake, which is required to build the qrenderdoc gui.
-BDEPEND="
-	x11-base/xorg-proto
-	virtual/pkgconfig
-	qt5? (
-		${AUTOTOOLS_DEPEND}
-		${PYTHON_DEPS}
-		dev-libs/libpcre
-		dev-qt/qtcore:5
-		app-alternatives/yacc
-	)
-	verify-sig? ( sec-keys/openpgp-keys-baldurkarlsson )
-"
-
-PATCHES=(
-	# The analytics seem very reasonable, and even without this patch
-	# they are NOT sent before the user accepts.  But default the
-	# selection to off, just in case.
-	"${FILESDIR}"/${PN}-1.18-analytics-off.patch
-
-	# Only search for PySide2 if pyside2 USE flag is set.
-	# Bug #833627
-	"${FILESDIR}"/${PN}-1.18-conditional-pyside.patch
-
-	# Pass CXXFLAGS and LDFLAGS through to qmake when qrenderdoc is
-	# built.
-	"${FILESDIR}"/${PN}-1.18-system-flags.patch
-
-	# Needed to prevent sandbox violations during build.
-	"${FILESDIR}"/${PN}-1.27-env-home.patch
-
-	"${FILESDIR}"/${PN}-1.30-r1-system-compress.patch
-)
-
-DOCS=( util/LINUX_DIST_README )
-
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/baldurkarlsson.gpg
-
-pkg_setup() {
-	use qt5 && python-single-r1_pkg_setup
-}
-
-src_unpack() {
-	if use verify-sig; then
-	   verify-sig_verify_detached "${DISTDIR}"/${P}.tar.gz{,.asc}
-	fi
-
-	# Do not unpack the swig sources here.  CMake will do that if
-	# required.
-	unpack ${P}.tar.gz
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	# Remove the calls to install the documentation files.  Instead,
-	# install them with einstalldocs.
-	sed -i '/share\/doc\/renderdoc/d' \
-		"${S}"/CMakeLists.txt "${S}"/qrenderdoc/CMakeLists.txt \
-		|| die 'sed remove doc install failed'
-
-	# Assumes that the build directory is "${S}"/build, which it is not.
-	sed -i "s|../build/lib|${BUILD_DIR}/lib|" \
-		"${S}"/docs/conf.py \
-		|| die 'sed patch doc sys.path failed'
-
-	# Bug #836235
-	sed -i '/#include <stdarg/i #include <time.h>' \
-		"${S}"/renderdoc/os/os_specific.h \
-		|| die 'sed include time.h failed'
-}
-
-src_configure() {
-	local mycmakeargs=(
-		# Build system does not know that this is a tagged release, as
-		# we just have the tarball and not the git repository.
-		-DBUILD_VERSION_STABLE=ON
-
-		-DENABLE_EGL=ON
-		-DENABLE_GL=ON
-		-DENABLE_GLES=ON
-		-DENABLE_PYRENDERDOC=$(usex qt5)
-		-DENABLE_QRENDERDOC=$(usex qt5)
-		-DENABLE_VULKAN=ON
-
-		# Upstream says that this option is unsupported and should not
-		# be used yet.
-		-DENABLE_UNSUPPORTED_EXPERIMENTAL_POSSIBLY_BROKEN_WAYLAND=OFF
-
-		-DENABLE_XCB=ON
-		-DENABLE_XLIB=ON
-
-		# renderdoc_capture.json is installed here
-		-DVULKAN_LAYER_FOLDER="${EPREFIX}"/etc/vulkan/implicit_layer.d
-	)
-
-	use qt5 && mycmakeargs+=(
-		-DPython3_EXECUTABLE="${PYTHON}"
-		-DRENDERDOC_SWIG_PACKAGE="${DISTDIR}"/${MY_SWIG}.tar.gz
-
-		# Needed after qtchooser removal, bug #836474.
-		-DQMAKE_QT5_COMMAND="$(qt5_get_bindir)"/qmake
-
-		-DQRENDERDOC_ENABLE_PYSIDE2=$(usex pyside2)
-	)
-
-	use pyside2 && mycmakeargs+=( -DPYTHON_CONFIG_SUFFIX=-${EPYTHON} )
-
-	# Lots of type mismatch issues.
-	filter-lto
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-	docs_compile
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-	optfeature "android remote contexts" dev-util/android-tools
-	optfeature "vulkan contexts" media-libs/vulkan-loader
-}

next             reply	other threads:[~2024-03-13 16:27 UTC|newest]

Thread overview: 36+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2024-03-13 16:27 Matthew Smith [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-08-17 19:22 [gentoo-commits] repo/gentoo:master commit in: media-gfx/renderdoc/ Andreas Sturmlechner
2025-05-01 20:29 Andreas Sturmlechner
2024-12-31  9:08 Andreas Sturmlechner
2024-11-23 18:02 Arthur Zamarin
2024-07-31 17:51 Matthew Smith
2024-04-07 10:40 Matthew Smith
2024-03-24 16:24 Matthew Smith
2024-03-13 15:13 Arthur Zamarin
2024-03-13 13:05 Matthew Smith
2024-03-03 19:21 Matthew Smith
2024-03-03 19:04 Michał Górny
2023-12-09 10:08 Matthew Smith
2023-11-12  7:52 Matthew Smith
2023-08-11  7:37 Matthew Smith
2023-06-10  4:35 Sam James
2023-02-26 17:31 Matthew Smith
2023-02-26 17:21 Arthur Zamarin
2023-02-26 12:43 Matthew Smith
2022-12-03 14:43 Arthur Zamarin
2022-10-25 12:50 Sam James
2022-09-25  8:47 Matthew Smith
2022-09-10  7:03 Matthew Smith
2022-09-09 22:26 Jakov Smolić
2022-08-08 18:08 Matthew Smith
2022-07-10  8:40 Matthew Smith
2022-07-03  8:59 Agostino Sarubbo
2022-06-09 19:33 Matthew Smith
2022-05-21 17:35 Jakov Smolić
2022-04-15  9:48 Matthew Smith
2022-04-15  9:48 Matthew Smith
2022-04-04  6:37 Agostino Sarubbo
2022-04-02 13:20 Matthew Smith
2022-03-27  9:25 Matthew Smith
2022-03-16  8:13 Jakov Smolić
2022-03-08 19:54 Matthew Smith

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:2ee9da15af0 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: media-gfx/renderdoc/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1710347240.cc392d2312c7deca87163d85c2b2c6ae6af66af1.matthew@gentoo \
    --to=matthew@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox