[gentoo-commits] repo/gentoo:master commit in: media-gfx/imv/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Ionen Wolkens" <ionen@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: media-gfx/imv/
Date: Tue, 20 Feb 2024 23:21:05 +0000 (UTC)	[thread overview]
Message-ID: <1708471255.7316b165cdd3a49a8781f21a5fe7dd893ebc0302.ionen@gentoo> (raw)

commit:     7316b165cdd3a49a8781f21a5fe7dd893ebc0302
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 20 23:03:33 2024 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Feb 20 23:20:55 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7316b165

media-gfx/imv: add 4.5.0

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-gfx/imv/Manifest         |  1 +
 media-gfx/imv/imv-4.5.0.ebuild | 88 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 89 insertions(+)

diff --git a/media-gfx/imv/Manifest b/media-gfx/imv/Manifest
index e0446825429c..34f402d633b0 100644
--- a/media-gfx/imv/Manifest
+++ b/media-gfx/imv/Manifest
@@ -1 +1,2 @@
 DIST imv-4.4.0.tar.gz 80360 BLAKE2B c598bb270ed57562f1c1b9a56f42676a7c8390c976ed74405228da572b000a85bf69e51f1bbfa6d554a481debc092995fe5222ba1e8b0b029b72395a8b8f329b SHA512 ddc0740022183a5467a0815ca623d2204b26449fee14b00c3468d06dbba3b5c3314b04a582bbac6075205f8d58cc24f157e283ce1ce3d34ecf0a9bdc497ab7f1
+DIST imv-4.5.0.tar.gz 82559 BLAKE2B 100174071049ee711a868832ea297cc7fd43450145db9e71a631afb97d7d77574f37501b749734f47b3f2699d159ed05e5159fd9060c6f0a5de18b92708d9e9c SHA512 5a192e1721b4752ba98de23e4a709904f43cce6954d1bc4a8feb5fb4921b46d497915fb7b2885cf87a65983fe2727c856d6c0c8b0cca2906e4b069e4a4f9c417

diff --git a/media-gfx/imv/imv-4.5.0.ebuild b/media-gfx/imv/imv-4.5.0.ebuild
new file mode 100644
index 000000000000..51d558ef4fe1
--- /dev/null
+++ b/media-gfx/imv/imv-4.5.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="Minimal image viewer designed for tiling window manager users"
+HOMEPAGE="https://sr.ht/~exec64/imv/"
+SRC_URI="https://git.sr.ht/~exec64/imv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S=${WORKDIR}/${PN}-v${PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+X +freeimage gif heif icu jpeg jpegxl png svg test tiff wayland"
+REQUIRED_USE="|| ( X wayland )"
+RESTRICT="!test? ( test )"
+
+# bug #922496 wrt nsgif, kept for now but USE can be masked if old nsgif
+# removal is wanted (freeimage still allows non-animated gif display)
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/inih
+	media-libs/libglvnd[X?]
+	x11-libs/cairo
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb:=
+	)
+	freeimage? ( media-libs/freeimage )
+	gif? ( <media-libs/libnsgif-1:= )
+	heif? ( media-libs/libheif:= )
+	icu? ( dev-libs/icu:= )
+	!icu? ( >=dev-libs/libgrapheme-2:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( media-libs/libjxl:= )
+	png? ( media-libs/libpng:= )
+	svg? ( >=gnome-base/librsvg-2.44:2 )
+	tiff? ( media-libs/tiff:= )
+	wayland? ( dev-libs/wayland )
+	!sys-apps/renameutils
+"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	test? ( dev-util/cmocka )
+"
+BDEPEND="
+	app-text/asciidoc
+	wayland? ( dev-util/wayland-scanner )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.3.1_p20211221-animated-gif.patch
+)
+
+src_prepare() {
+	default
+
+	# if wayland-only, don't automagic on libGL and force libOpenGL
+	if use !X; then
+		sed -i "/dependency('gl'/{s/'gl'/'opengl'/;s/false/true/}" meson.build || die
+	fi
+
+	# glu isn't used by anything
+	sed -i "/dependency('glu')/d" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature freeimage)
+		$(meson_feature gif libnsgif)
+		$(meson_feature heif libheif)
+		$(meson_feature jpeg libjpeg)
+		$(meson_feature jpegxl libjxl)
+		$(meson_feature png libpng)
+		$(meson_feature svg librsvg)
+		$(meson_feature test)
+		$(meson_feature tiff libtiff)
+		-Dunicode=$(usex icu{,} grapheme)
+		-Dwindows=$(usex X $(usex wayland all x11) wayland)
+	)
+
+	meson_src_configure
+}

next             reply	other threads:[~2024-02-20 23:21 UTC|newest]

Thread overview: 52+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2024-02-20 23:21 Ionen Wolkens [this message]
  -- strict thread matches above, loose matches on Subject: below --
2024-11-02  2:16 [gentoo-commits] repo/gentoo:master commit in: media-gfx/imv/ Michael Orlitzky
2024-03-20  7:17 Ionen Wolkens
2024-03-13 19:38 Arthur Zamarin
2024-03-13 19:38 Arthur Zamarin
2024-03-13 15:03 Arthur Zamarin
2024-01-29 17:17 Sam James
2024-01-19 20:07 Ionen Wolkens
2024-01-19 20:07 Ionen Wolkens
2023-01-26 15:13 Ionen Wolkens
2023-01-20 22:48 Ionen Wolkens
2023-01-20 22:48 Ionen Wolkens
2023-01-19  5:48 Ionen Wolkens
2023-01-19  5:48 Ionen Wolkens
2022-12-19  7:23 Ionen Wolkens
2022-12-16  2:40 Ionen Wolkens
2022-11-01 20:39 Ionen Wolkens
2022-10-07  0:56 Ionen Wolkens
2022-08-14 19:33 Ionen Wolkens
2022-06-30 19:44 Ionen Wolkens
2021-12-23  1:03 Ionen Wolkens
2021-12-16 19:11 Ionen Wolkens
2021-12-15 10:48 Ionen Wolkens
2021-12-15 10:48 Ionen Wolkens
2021-12-03 15:13 Ionen Wolkens
2021-08-06  1:36 Ionen Wolkens
2021-08-06  1:36 Ionen Wolkens
2021-03-26 15:55 Sam James
2021-03-26 15:55 Sam James
2021-03-26 15:55 Sam James
2021-02-16 12:16 Joonas Niilola
2021-02-16 12:16 Joonas Niilola
2021-02-16 12:16 Joonas Niilola
2021-02-16 12:16 Joonas Niilola
2020-08-16 18:01 Jeroen Roovers
2020-01-19 19:37 Jeroen Roovers
2020-01-05 13:03 Jeroen Roovers
2020-01-05 13:01 Jeroen Roovers
2020-01-05 13:01 Jeroen Roovers
2020-01-05 13:01 Jeroen Roovers
2020-01-05 13:01 Jeroen Roovers
2020-01-05 13:01 Jeroen Roovers
2019-12-22 11:01 Jeroen Roovers
2019-12-16 10:02 Jeroen Roovers
2019-12-16 10:02 Jeroen Roovers
2019-12-16 10:02 Jeroen Roovers
2017-12-08 23:48 Jonas Stein
2017-01-06  8:01 David Seifert
2016-06-04 13:43 Göktürk Yüksek
2016-05-27 14:17 Patrice Clement
2016-04-29  5:46 Ian Delaney
2016-04-26  8:49 Ian Delaney

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:e0446825429 dfblob:34f402d633b dfblob:51d558ef4fe )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: media-gfx/imv/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1708471255.7316b165cdd3a49a8781f21a5fe7dd893ebc0302.ionen@gentoo \
    --to=ionen@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox