[gentoo-commits] repo/gentoo:master commit in: dev-util/poke/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Arsen Arsenović" <arsen@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/poke/
Date: Mon, 22 Jan 2024 14:04:27 +0000 (UTC)	[thread overview]
Message-ID: <1705932220.7251eb47638c126422d8014b1ffb6472e25e2cde.arsen@gentoo> (raw)

commit:     7251eb47638c126422d8014b1ffb6472e25e2cde
Author:     Arsen Arsenović <arsen <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 22 14:03:07 2024 +0000
Commit:     Arsen Arsenović <arsen <AT> gentoo <DOT> org>
CommitDate: Mon Jan 22 14:03:40 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7251eb47

dev-util/poke: add 3.90.1

Signed-off-by: Arsen Arsenović <arsen <AT> gentoo.org>

 dev-util/poke/Manifest           |   1 +
 dev-util/poke/poke-3.90.1.ebuild | 126 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 127 insertions(+)

diff --git a/dev-util/poke/Manifest b/dev-util/poke/Manifest
index df3108263b42..f7044d41c5d8 100644
--- a/dev-util/poke/Manifest
+++ b/dev-util/poke/Manifest
@@ -5,3 +5,4 @@ DIST poke-3.1.tar.gz 7562582 BLAKE2B c348973185e7f33d670a9dccab60c02e8ccc247c5aa
 DIST poke-3.2.tar.gz 7559660 BLAKE2B c1d5739a1a497fb3daadec53fe812b65ec787dd268030a6517764541497c82451f4df391f3c434ef7729bc8e3762c31852ef3ce41aa83928e7646c40bde557dd SHA512 bd3651a2962165b318cc59c53604199eb6278ee3be45c18c36864612b0926d78a06f0e1338fdcc1fcd1cd48e2792bb3cd36a2bb5383143a66dc3aab023c0019c
 DIST poke-3.3.tar.gz 7553544 BLAKE2B 1e98f77937f9c45daa80591be603a74857b1bbd230cb931e59d7e9753c1687d5a4c96837bb6aca76615feca71cbeabd3be7ad234260657288d060ff63d59c040 SHA512 b00dca38d27bddee6ea131d45988aaead1d11d29b757c048f3b2be8013575cedc591844d4d99870f90964fd4f517d500cbb42aae5aff57e9fe07aac8273aa236
 DIST poke-3.90.0.tar.gz 7971780 BLAKE2B ef4a5e0a25f1851e4f44314cc9e3b62c6eeb7458d5c4b3da1d7ea798c7b58b57c4ba113e3dac221e757b0d52d8b609c9cd1910a82f36d9aafe0393a1a1fa6a02 SHA512 34b2baee4317582d4ca68001b9f1bd540277c6ef133ebec49de6d45db0d564815da376b4f9761369e80976570c4bbd05272b215e78391b0a818390e613e21b1a
+DIST poke-3.90.1.tar.gz 7953029 BLAKE2B f098fe68316d172e700a896fdc588c6ae5d352eca21b5230940902e51adca8b57d19093d406b6fd66391e79025d79604cf3db63ef3f7783b65cd39788a727c76 SHA512 0d4d4b63ed5448427a72ecee182065bc6fb86eb460f9a05daef2d40d5678a5352a568d0f403cce17e6711c7a82875c91d0e00890162ac85636edbf6e277d1f3e

diff --git a/dev-util/poke/poke-3.90.1.ebuild b/dev-util/poke/poke-3.90.1.ebuild
new file mode 100644
index 000000000000..1aadadd1833d
--- /dev/null
+++ b/dev-util/poke/poke-3.90.1.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp-common flag-o-matic toolchain-funcs
+
+DESCRIPTION="Extensible editor for structured binary data"
+HOMEPAGE="https://www.jemarch.net/poke"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/poke.git"
+	REGEN_BDEPEND="
+		>=dev-build/autoconf-2.62
+		>=dev-build/automake-1.16
+		sys-apps/gawk
+		sys-apps/help2man
+		sys-apps/texinfo
+		app-alternatives/yacc
+		app-alternatives/lex
+	"
+elif [[ $(ver_cut 2) -ge 90 || $(ver_cut 3) -ge 90 ]]; then
+	SRC_URI="https://alpha.gnu.org/gnu/poke/${P}.tar.gz"
+	REGEN_BDEPEND=""
+else
+	SRC_URI="mirror://gnu/poke/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	REGEN_BDEPEND=""
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="emacs pvm-profiling nbd nls test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boehm-gc:=
+	dev-libs/libatomic_ops
+	sys-devel/gettext
+	sys-libs/readline:=
+	emacs? ( >=app-editors/emacs-23.1:* )
+	nbd? ( sys-libs/libnbd )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( nbd? ( sys-libs/libnbd[uri-support(+)] ) )
+"
+BDEPEND="
+	${REGEN_BDEPEND}
+	virtual/pkgconfig
+	pvm-profiling? ( sys-devel/gcc )
+	emacs? ( >=app-editors/emacs-23.1:* )
+	test? (
+		dev-util/dejagnu
+		nbd? ( sys-block/nbdkit )
+	)
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_pretend() {
+	if use pvm-profiling && ! tc-is-gcc; then
+		die "USE=pvm-profiling requires GCC"
+	fi
+}
+
+pkg_setup() {
+	use emacs && elisp-check-emacs-version
+}
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999 ]]; then
+		./bootstrap || die
+	fi
+}
+
+src_configure() {
+	# See bug 858461.
+	# Upstream support might happen one day.  For context, only one file needs
+	# LTO to be disabled (since it's an autogenerated bytecode interpreter),
+	# others do not.  The build system will handle this at some point in the
+	# future.  Until then, just filter out LTO.
+	filter-lto
+
+	local myconf=(
+		--with-lispdir="${EPREFIX}/${SITELISP}/${PN}"
+		--enable-hserver
+		$(use_enable nbd libnbd)
+		$(use_enable pvm-profiling)
+		$(use_enable nls)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	default
+
+	if use emacs; then
+		cd etc || die
+		elisp-compile *.el
+	fi
+}
+
+src_install() {
+	default
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+		cd etc || die
+		elisp-install "${PN}" *.el *.elc
+	fi
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}

next             reply	other threads:[~2024-01-22 14:04 UTC|newest]

Thread overview: 47+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2024-01-22 14:04 Arsen Arsenović [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-03-12 14:06 [gentoo-commits] repo/gentoo:master commit in: dev-util/poke/ Arsen Arsenović
2025-01-07 22:44 Sam James
2024-06-14 14:42 Arthur Zamarin
2024-06-14 13:36 Arsen Arsenović
2024-04-02 11:55 Arsen Arsenović
2024-04-02 11:55 Arsen Arsenović
2024-02-11 13:23 Arsen Arsenović
2024-01-20 15:56 Arsen Arsenović
2023-11-23 19:53 Sam James
2023-11-21 19:37 Arsen Arsenović
2023-08-20 16:31 Arsen Arsenović
2023-05-14 16:42 Arsen Arsenović
2023-05-14  9:32 Arsen Arsenović
2023-04-18  0:22 Arsen Arsenović
2023-04-01 16:30 Arthur Zamarin
2023-01-25 21:10 Arsen Arsenović
2023-01-25  0:29 Arsen Arsenović
2023-01-25  0:29 Arsen Arsenović
2023-01-24 23:46 Arsen Arsenović
2023-01-24 23:46 Arsen Arsenović
2023-01-24 23:46 Arsen Arsenović
2023-01-21 18:00 Arsen Arsenović
2023-01-21 18:00 Arsen Arsenović
2022-12-05 19:00 Arthur Zamarin
2022-12-04 21:15 Sam James
2022-12-03 11:06 Sam James
2022-11-22  8:11 Sam James
2022-09-17 14:34 Sam James
2022-09-17 14:34 Sam James
2022-04-17 19:00 Sam James
2022-04-10 15:12 Florian Schmaus
2022-04-10 15:12 Florian Schmaus
2022-04-10 15:12 Florian Schmaus
2022-02-23  4:05 Sam James
2022-02-23  4:05 Sam James
2021-07-30  8:55 Sergei Trofimovich
2021-06-12 10:07 Sergei Trofimovich
2021-06-06  9:20 Sergei Trofimovich
2021-04-24 12:37 Sergei Trofimovich
2021-04-19 23:41 Sergei Trofimovich
2021-04-02  9:54 Sergei Trofimovich
2021-03-27 22:18 Sergei Trofimovich
2021-03-25 20:31 Sergei Trofimovich
2021-02-26 22:38 Sergei Trofimovich
2021-02-26 22:01 Sergei Trofimovich
2021-02-26 19:59 Sergei Trofimovich

find likely ancestor, descendant, or conflicting patches for this message:
( dfblob:df3108263b4 dfblob:f7044d41c5d dfblob:1aadadd1833 )
 OR (
bs:"[gentoo-commits] repo/gentoo:master commit in: dev-util/poke/" )
	(help)

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1705932220.7251eb47638c126422d8014b1ffb6472e25e2cde.arsen@gentoo \
    --to=arsen@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox